How to move first N elements to the end of the lis

Question

I am wondering how can I move first N elements from a list and put them at the end. For example:

[1,2,3,4] and I want to move first 2 elements , so the result will be [3,4,1,2].

rule(List1,N,List2) :- length(List1,Y), ...

I don't know how to start, any advice ?

Answer 1

You could opt to adopt a more general perspective on the task. If you think about it, taking the first N elements of a list and appending them at the end can be seen as a rotation to the left by N steps (just imagine the list elements arranged in a circle). The predicate name rotate/3 in @Willem Van Onsem's answer also indicates this perspective. You can actually define such a predicate as a true relation, that is making it work in all directions. Additionally it would be desirable to abstain from imposing unnecessary restrictions on the arguments while retaining nice termination properties. To reflect the relational nature of the predicate, let's choose a descriptive name. As the third argument is the left rotation by N steps of the list that is the first argument, let's maybe call it list_n_lrot/3 and define it like so:

:- use_module(library(lists)).
:- use_module(library(clpfd)).

list_n_lrot([],0,[]).                 % <- special case
list_n_lrot(L,N,LR) :-
   list_list_samelength(L,LR,Len),    % <- structural constraint
   NMod #= N mod Len,
   list_n_heads_tail(L,NMod,H,T),
   append(T,H,LR).

list_list_samelength([],[],0).
list_list_samelength([_X|Xs],[_Y|Ys],N1) :-
   N1 #> 0,
   N0 #= N1-1,
   list_list_samelength(Xs,Ys,N0).

list_n_heads_tail(L,N,H,T) :-
   if_(N=0,(L=T,H=[]),
           (N0#=N-1,L=[X|Xs],H=[X|Ys],list_n_heads_tail(Xs,N0,Ys,T))).

Now let's step through the definition and observe some of its effects by example. The first rule of list_n_lrot/3 is only included to deal with the special case of empty lists:

?- list_n_lrot([],N,R).
N = 0,
R = [] ;
false.

?- list_n_lrot(L,N,[]).
L = [],
N = 0 ;
false.

?- list_n_lrot(L,N,R).
L = R, R = [],
N = 0 ;
...

If you don't want to include these cases in your solution just omit that rule. Throughout the predicates CLP(FD) is used for arithmetic constraints, so the second argument of list_n_lrot/3 can be variable without leading to instantiation errors. The goal list_list_samelength/2 is a structural constraint to ensure the two lists are of same length. This helps avoiding an infinite loop after producing all answers in the case that only the third argument is ground (to see this, remove the first two goals of list_n_lrot/3 and replace the third with list_n_heads_tail(L,N,H,T) and then try the query ?- list_n_lrot(L,N,[1,2,3]).). It's also the reason why the most general query is listing the solutions in a fair order, that is producing all possibilities for every list length instead of only listing the rotation by 0 steps:

?- list_n_lrot(L,N,R).
...                                   % <- first solutions
L = R, R = [_G2142, _G2145, _G2148],  % <- length 3, rotation by 0 steps
N mod 3#=0 ;
L = [_G2502, _G2505, _G2508],         % <- length 3, rotation by 1 step
R = [_G2505, _G2508, _G2502],
N mod 3#=1 ;
L = [_G2865, _G2868, _G2871],         % <- length 3, rotation by 2 steps
R = [_G2871, _G2865, _G2868],
N mod 3#=2 ;
...                                   % <- further solutions

Finally, it also describes the actual length of the two lists, which is used in the next goal to determine the remainder of N modulo the length of the list. Consider the following: If you rotate a list of length N by N steps you arrive at the initial list again. So a rotation by N+1 steps yields the same list as a rotation by 1 step. Algebraically speaking, this goal is exploiting the fact that congruence modulo N is partitioning the infinite set of integers into a finite number of residue classes. So for a list of length N it is sufficient to produce the N rotations that correspond to the N residue classes in order to cover all possible rotations (see the query above for N=3). On the other hand, a given N > list length can be easily computed by taking the smallest non-negative member of its residue class. For example, given a list with three elements, a rotation by 2 or 5 steps respectively yields the same result:

?- list_n_lrot([1,2,3],2,R).
R = [3, 1, 2].

?- list_n_lrot([1,2,3],5,R).
R = [3, 1, 2].

And of course you could also left rotate the list by a negative number of steps, that is rotating it in the other direction:

?- list_n_lrot([1,2,3],-1,R).
R = [3, 1, 2].

On a side note: Since this constitutes rotation to the right, you could easily define right rotation by simply writing:

list_n_rrot(L,N,R) :-
   list_n_lrot(L,-N,R).

?- list_n_rrot([1,2,3],1,R).
R = [3, 1, 2].

The predicate list_n_heads_tail/4 is quite similar to splitAt/4 in Willem's post. However, due to the use of if_/3 the predicate succeeds deterministically (no need to hit ; after the only answer since no unnecessary choicepoints are left open), if one of the lists and the second argument of list_n_lrot/3 are ground:

?- list_n_lrot2([a,b,c,d,e],2,R).
R = [c, d, e, a, b].

?- list_n_lrot2(L,2,[c,d,e,a,b]).
L = [a, b, c, d, e].

You can observe another nice effect of using CLP(FD) with the second solution of the most general query:

?- list_n_lrot(L,N,R).
L = R, R = [],
N = 0 ;
L = R, R = [_G125],       % <- here
N in inf..sup ;           % <- here
...

This answer states, that for a list with one element any rotation by an arbitrary number of steps yields the very same list again. So in principle, this single general answer summarizes an infinite number of concrete answers. Furthermore, you can also ask questions like: What lists are there with regard to a rotation by 2 steps?

?- list_n_lrot2(L,2,R).
L = R, R = [_G19] ;
L = R, R = [_G19, _G54] ;
L = [_G19, _G54, _G22],
R = [_G22, _G19, _G54] ;
...

To finally come back to the example in your question:

?- list_n_lrot([1,2,3,4],2,R).
R = [3, 4, 1, 2].

Note how this more general approach to define arbitrary rotations on lists subsumes your use case of relocating the first N elements to the end of the list.

Answer 2

Since we are speaking of predicates - i.e. true relations among arguments - and Prolog library builtins are written with efficiency and generality in mind, you should know that - for instance - length/2 can generate a list, as well as 'measuring' its length, and append/3 can also split a list in two. Then, your task could be

'move first N elements to the end of the list'(L,N,R) :-
 length(-,-),
 append(-,-,-),
 append(-,-,-).

Replace each dash with an appropriate variable, and you'll get

?- 'move first N elements to the end of the list'([1,2,3,4],2,R).
R = [3, 4, 1, 2].

Answer 3

Try this

despI([C|B],R):-append(B,[C|[]],R).
desp(A,0,A).
desp([C|B],N,R):-N1 is N - 1, despI([C|B],R1), desp(R1,N1,R),!.

The first predicate moves one element to the end of the list, then the only thing I do is "repeat" that N times.

?-de([1,2,3,4],2,R).
R = [3, 4, 1, 2].

?- de([1,2,3,4,5,6,7],4,R).
R = [5, 6, 7, 1, 2, 3, 4].

Answer 4

We can do this with a predicate that works in two phases:

• a collect phase: we collect the first N items of the list; and
• an emit phase: we construct a list where we add these elements at the tail.

Let is construct the two phases with separate predicate. For the collect phase, we could use the following predicate:

% splitAt(L,N,L1,L2).

splitAt(L,0,[],L).
splitAt([H|T],N,[H|T1],L2) :-
    N > 0,
    N1 is N-1,
    splitAt(T,N1,T1,L2).

Now for the emit phase, we could use append/3. So then the full predicate is:

rotate(L,N,R) :-
    splitAt(L,N,L1,L2),
    append(L2,L1,R).

This gives:

?- rotate([1,2,3,4],0,R).
R = [1, 2, 3, 4] .

?- rotate([1,2,3,4],1,R).
R = [2, 3, 4, 1] .

?- rotate([1,2,3,4],2,R).
R = [3, 4, 1, 2] .

?- rotate([1,2,3,4],3,R).
R = [4, 1, 2, 3] .

?- rotate([1,2,3,4],4,R).
R = [1, 2, 3, 4].

The algorithm works in O(n).