Adding the current directory to Windows path perma

Question

I am trying to add the current directory (from a command-line) to Windows path permanently, but I am having serious problems implementing this.

My initial attempt was:

set PATH=%PATH%;%cd%

However, this only works in the current session; as soon as I close the command-line window, the PATH environment variable retains its previous value.

Next, I tried:

setx PATH=%PATH%;%cd%

This might work in Windows 7 and 8 according to some of the answers that I found here, but in Windows 10, the setx command has three ways of working:

Syntax 1:
    SETX [/S system [/U [domain\]user [/P [password]]]] var value [/M]

Syntax 2:
    SETX [/S system [/U [domain\]user [/P [password]]]] var /K regpath [/M]

Syntax 3:
    SETX [/S system [/U [domain\]user [/P [password]]]]
         /F file {var {/A x,y | /R x,y string}[/M] | /X} [/D delimiters]

Long story short, I am unable to get it to work:

ERROR: Invalid syntax. Default option is not allowed more than '2' time(s).

Can somebody please suggest how to complete my goal the easiest way?

If there's a different syntax per Windows version, then I'd be happy to get this info as well.

Thank you very much!!!

Answer 1

Simple solution:

The syntax of setx is slightly different than the syntax of set.

With set, I would do:

set PATH=%PATH%;%cd%

With setx, I needed to do:

setx PATH "%cd"

The first argument specifies the name of the environment variable.

The second argument specifies the value to add to this variable.

The double-quotes are required for when the second argument contains spaces.

This might also be the case with set, by the way.

Answer 2

As described in detail in answer on Why are other folder paths also added to system PATH with SetX and not only the specified folder path? it is not good to modify system or user PATH from within a batch file by simply overwriting or appending a folder path to PATH stored in registry using the local PATH.

One solution for this task to add current directory path to user PATH is using this code on Windows Vista or later versions of Windows:

@echo off
setlocal EnableExtensions DisableDelayedExpansion
:GetUserPath
for /F "skip=2 tokens=1,2*" %%N in ('%SystemRoot%\System32\reg.exe query "HKEY_CURRENT_USER\Environment" /v "Path" 2^>nul') do (
    if /I "%%N" == "Path" (
        set "UserPath=%%P"
        goto CheckPath
    )
)
%SystemRoot%\System32\setx.exe Path "%CD%" >nul
endlocal
goto :EOF

:CheckPath
setlocal EnableDelayedExpansion
set "Separator="
if not "!UserPath:~-1!" == ";" set "Separator=;"
set "PathCheck=!UserPath!%Separator%"
if "!PathCheck:%CD%;=!" == "!PathCheck!" (
    %SystemRoot%\System32\setx.exe Path "!UserPath!%Separator%%CD%" >nul
)
endlocal
endlocal

The disadvantage of this solution is a user PATH being finally for example C:\Temp;C:\Temp\Other Folder;C:\Temp\One More Folder when current directory is first C:\Temp, on next run of the batch file C:\Temp\Other Folder and C:\Temp\One More Folder on third execution of the batch file.

The solution to avoid this is defining an application specific environment variable called in next batch file MyAppPath which is always overwritten on execution of the batch file. To the user PATH is added only the reference of the environment variable MyAppPath.

@echo off
setlocal EnableExtensions DisableDelayedExpansion
%SystemRoot%\System32\setx.exe MyAppPath "%CD%" >nul

:GetUserPath
for /F "skip=2 tokens=1,2*" %%N in ('%SystemRoot%\System32\reg.exe query "HKEY_CURRENT_USER\Environment" /v "Path" 2^>nul') do (
    if /I "%%N" == "Path" (
        set "UserPath=%%P"
        goto CheckPath
    )
)
%SystemRoot%\System32\setx.exe Path "%%MyAppPath%%" >nul
endlocal
goto :EOF

:CheckPath
setlocal EnableDelayedExpansion
set "Separator="
if not "!UserPath:~-1!" == ";" set "Separator=;"
if "!UserPath:%%MyAppPath%%=!" == "!UserPath!" (
    %SystemRoot%\System32\setx.exe Path "!UserPath!%Separator%%%MyAppPath%%" >nul
)
endlocal
endlocal

In this case user PATH as stored in registry contains always just %MyAppPath% and registry value is of type REG_EXPAND_SZ, but the value of environment variable MyAppPath also stored in registry, but of type REG_SZ, is updated to current directory path on each execution of the batch file. So the user PATH in registry does not get longer and longer on each execution of a batch file from a different folder than before.

In general an application or application suite is not good coded if its application folder or one of its subfolder must be in local PATH on execution of the application or any application from the suite to work properly at all. The application or application suite can store its installation path also somewhere else in registry like App Paths or in a file in a subfolder of %APPDATA% (user account related standard application data path) from which it can be read on next run. An installer package should modify user or system PATH only if this application is most likely executed mainly from within a command prompt window by a user.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• reg /?
• reg query /?
• set /?
• setlocal /?
• setx /?

Following should be also read:

• Wikipedia article about Windows Environment Variables.
• Microsoft article about Using Command Redirection Operators explaining >nul.
• Answer on Where is “START” searching for executables? with details about App Paths.
• Answer on What is the reason for '…' is not recognized as an internal or external command, operable program or batch file? with details about local, system and user PATH.
• Answer on How to set PATH environment variable in batch file only once on Windows?
• Answer on How can I use a .bat file to remove specific tokens from the PATH environment variable?