DOS Interrupt in masm x86 assembly crashing

Question

I've just begun learning some x86 assembly on win32, and I've used masm with visual studio 2008 using the custom build rule that comes with the ide for .asm files. I've been trying to use the DOS interrupt to print to the console, but instead I receive the message: "Unhandled exception at 0x00401004 in ASMTest.exe: 0xC0000005: Access violation reading location 0xffffffff." on the 8th line. I'm trying to output the single ascii character 'A' (41h) Here is the masm code:

.386
.MODEL flat, stdcall

.CODE
start:
    mov dl, 41h
    mov ah, 2
    int 21h
    ret
end start

When I use debug.exe, and use the 'a' command to input all .CODE instructions, and run it ('g'), it works fine.

Can anyone enlighten me on how to use the DOS interrupt correctly? Thanks!

EDIT: When programming on win32, Managu is right that you should use a windows api call like WriteConsoleA instead of using the DOS interrupt. This was a helpful resource. In case anyone is looking for the code to do this (like I was), here it is:

.386
.MODEL flat, stdcall

; Windows API prototypes
GetStdHandle proto :dword
WriteConsoleA proto :dword, :dword, :dword, :dword, :dword
ExitProcess proto :dword

STD_OUTPUT_HANDLE equ -11

.DATA
HelloWorldString db "hello, world", 10, 0

.CODE

strlen proc asciiData:dword
    ; EAX used as count, EBX as ascii char pointer, EDX (DL) as ascii char
    mov eax, -1
    mov ebx, asciiData
    mov edx, 0

    BeginLoop:
    inc eax       ; ++count (init is -1)
    mov dl, [ebx] ; *dl = *asciiptr
    inc ebx       ; ++asciiptr
    cmp dl, 0     ; if (*dl == '\0')
    jne BeginLoop ; Goto the beginning of loop

    ret
strlen endp

main proc
    invoke GetStdHandle, STD_OUTPUT_HANDLE
    mov ecx, eax
    invoke strlen, addr HelloWorldString
    invoke WriteConsoleA, ecx, addr HelloWorldString, eax, 0, 0
    ret
main endp

end

(Set the entry point to main)

Answer 1

When you use debug.exe to input this code, you're assembling a 16-bit (8086 architecture, "real mode") dos program. The semantics you specify are correct for such a program. However, when you assemble the program you've got here with MASM, and then link it, you're trying to create a 32-bit (i386 architecture, "protected mode") Windows program. I could be mistaken, but I don't think you can legally even invoke int 21h in the latter case.

Answer 2

If we start a 16 bit DOS-*.com application, then DOS fill the opcode of an "int 20" instruction inside of our PSP at offset 0 and additional DOS push a word with zero on our stack before DOS let our application execute. So we can place a simple "ret" instruction at the end of our code. But we have to make sure that our stackpointer is not corrupted and our codesegment is not changed.

For to link a 16 bit application using MASM 6+ we need a 16 bit linker.

ftp://ftp.microsoft.com/softlib/mslfiles/lnk563.exe

Dirk

Answer 3

It's possible that it occurs because of your 'ret' instruction. Where are you returning to? Some unknown place in memory, I imagine.

Instead, try using int 20h. That will exit "gracefully."

It works in debug (probably) because that's a more "managed" environment.