Applescript Droplet - Export Image Resolution of A

Question

I'm probably making a simple error but I can't seem to get my code to work properly. Figure I'd ask the geniuses on this site for help. I'm a novice scripter, more like code piecer. This is my first post, please be gentle.

What I'm trying to do... I have a folder (and subfolders) full of images. I'd like to have a applescript droplet that I can drag this folder on this droplet to get a text file report of the resolution and path of that image. This way I can insure my files are all the same and correct resolution prior to sending to my end vendor. And if the file isn't the correct resolution, I have the path to which file needs to be adjusted. I was able to create a droplet that could handle individual files, but once I drag a folder of images and sub-folders, I just get a blank text document.

This is what my initial results look like in a text file for files:

72.0 dpi /Users/chewbacca/Desktop/untitled folder/pixels-300x232 copy 2.png
72.0 dpi /Users/chewbacca/Desktop/untitled folder/pixels-300x232 copy 3.png
72.0 dpi /Users/chewbacca/Desktop/untitled folder/pixels-300x232 copy 4.png

Here's my attempt at getting the folder/sub-folder droplet to work:

on open (rawList)

set outFile to (choose file name with prompt "Output file:" default name "ResolutionReport.txt")
open for access outFile with write permission

set fileList to every file of rawList
repeat with i from 1 to number of items in fileList

    tell application "Image Events"
        launch
        set thisImage to open file (oneFile as string)
        copy the resolution of thisImage to {H_res, V_res}
        close thisImage
    end tell

    write (H_res as string) & " dpi " & (POSIX path of oneFile) & return to outFile
end repeat
close access outFile

end open

I realize that this could be more simple in perl, but I'd like to keep this pure Applescript for now since I'm starting to grasp how this language is used.

Answer 1

Really helpful are the templates (menu File) and code-snippets (CTRL-Click into a script).

The template Droplets->Recursive Image File Processing Droplet provides everything. Here an edited version that does what you want:

(* 
Disclaimer: IMPORTANT: This Apple software is supplied to you by Apple Inc. ("Apple") in consideration of your agreement to the following terms, and your use, installation, modification or redistribution of this Apple software constitutes acceptance of these terms. If you do not agree with these terms, please do not use, install, modify or redistribute this Apple software.

In consideration of your agreement to abide by the following terms, and subject to these terms, Apple grants you a personal, non-exclusive license, under Apple's copyrights in this original Apple software ( the "Apple Software" ), to use, reproduce, modify and redistribute the Apple Software, with or without modifications, in source and / or binary forms; provided that if you redistribute the Apple Software in its entirety and without modifications, you must retain this notice and the following text and disclaimers in all such redistributions of the Apple Software. Neither the name, trademarks, service marks or logos of Apple Inc. may be used to endorse or promote products derived from the Apple Software without specific prior written permission from Apple. Except as expressly stated in this notice, no other rights or licenses, express or implied, are granted by Apple herein, including but not limited to any patent rights that may be infringed by your derivative works or by other works in which the Apple Software may be incorporated.

The Apple Software is provided by Apple on an "AS IS" basis. APPLE MAKES NO WARRANTIES, EXPRESS OR IMPLIED, INCLUDING WITHOUT LIMITATION THE IMPLIED WARRANTIES OF NON - INFRINGEMENT, MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE, REGARDING THE APPLE SOFTWARE OR ITS USE AND OPERATION ALONE OR IN COMBINATION WITH YOUR PRODUCTS.

IN NO EVENT SHALL APPLE BE LIABLE FOR ANY SPECIAL, INDIRECT, INCIDENTAL OR CONSEQUENTIAL DAMAGES ( INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION ) ARISING IN ANY WAY OUT OF THE USE, REPRODUCTION, MODIFICATION AND / OR DISTRIBUTION OF THE APPLE SOFTWARE, HOWEVER CAUSED AND WHETHER UNDER THEORY OF CONTRACT, TORT ( INCLUDING NEGLIGENCE ), STRICT LIABILITY OR OTHERWISE, EVEN IF APPLE HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

Copyright ( C ) 2011 Apple Inc. All Rights Reserved.
*)

(* INSTRUCTIONS
This droplet is designed to process one or more files, or folders containing files, whose icons are dragged onto the droplet icon.
The droplet processes recursively, and will examine the contents of every folder and every sub-folder within those folders, to find and process any appropriate files found.
To use, replace the example processing code in the process_item sub-routine with your code. Save as an application.
*)

(* TO FILTER FOR IMAGE FILES, LOOK FOR QUICKTIME SUPPORTED IMAGE FORMATS *)
property type_list : {"JPEG", "TIFF", "PNGf", "8BPS", "BMPf", "GIFf", "PDF ", "PICT"}
property extension_list : {"jpg", "jpeg", "tif", "tiff", "png", "psd", "bmp", "gif", "jp2", "pdf", "pict", "pct", "sgi", "tga"}
property typeIDs_list : {"public.jpeg", "public.tiff", "public.png", "com.adobe.photoshop-image", "com.microsoft.bmp", "com.compuserve.gif", "public.jpeg-2000", "com.adobe.pdf", "com.apple.pict", "com.sgi.sgi-image", "com.truevision.tga-image"}


global outFile




-- This droplet processes files dropped onto the applet 
on open these_items


    set outFile to (choose file name with prompt "Output file:" default name "ResolutionReport.txt")
    open for access outFile with write permission


    -- FILTER THE DRAGGED-ON ITEMS BY CHECKING THEIR PROPERTIES AGAINST THE LISTS ABOVE
    repeat with i from 1 to the count of these_items
        set this_item to item i of these_items
        set the item_info to info for this_item without size
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try
            if (folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                -- THE ITEM IS AN IMAGE FILE AND CAN BE PROCESSED
                process_item(this_item)
            end if
        end if
    end repeat


    close access outFile

end open

-- this sub-routine processes folders 
on process_folder(this_folder)
    set these_items to list folder this_folder without invisibles
    repeat with i from 1 to the count of these_items
        set this_item to alias ((this_folder as Unicode text) & (item i of these_items))
        set the item_info to info for this_item without size
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try
            if (folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                -- THE ITEM IS AN IMAGE FILE AND CAN BE PROCESSED
                process_item(this_item)
            end if
        end if
    end repeat
end process_folder

-- this sub-routine processes files 
on process_item(this_item)
    -- NOTE that the variable this_item is a file reference in alias format 

    set H_res to 0
    set V_res to 0

    try
        tell application "Image Events"

            -- start the Image Events application
            launch

            -- open the image file
            set this_image to open this_item

            -- perform action
            copy the resolution of this_image to {H_res, V_res}

            set outString to ""

            if H_res > 0 and V_res > 0 then
                set outString to (H_res as string) & " dpi " & (POSIX path of this_item)
            else
                set outString to "#### ERROR #### " & (POSIX path of this_item)
            end if


            try
                write outString & return to outFile

            on error the error_message number the error_number
                close access outFile
                beep
                tell me to activate
                display dialog "Error: " & the error_number & ". " & the error_message buttons {"OK"} default button 1
            end try

            -- purge the open image data
            close this_image
        end tell

    on error error_message number error_number
        display alert "PROCESSING ERROR " & error_number message error_message as warning buttons {"Cancel"} cancel button "Cancel"
    end try

end process_item

Answer 2

You can try something along the lines of:

on open of theFolder
    set outFile to POSIX path of (choose file name with prompt "Output file:" default name "ResolutionReport.txt")
    set folderPath to POSIX path of (first item of theFolder)
    do shell script "find " & quoted form of folderPath & " -type f -flags nohidden \\! -name \".*\" -exec sips -g dpiHeight {} + | sed 'N;s/\\n//' > " & quoted form of outFile
end open