ApplyUpdates on REST with Firedac

Question

My project uses a REST server with FireDac.

I have a generic function that makes all my Selects but when I try to ApplyUpdates if does nothings. No message, no crash, it just keeps going and the data is not reflected to the database.

My Code:

function TServerMethods.ApplyUpdates(banco, tabela : String; const DeltaList: TFDJSONDeltas; var Mensagem : String) : Boolean; 
var 
  LApply : IFDJSONDeltasApplyUpdates; 
  Query : TFDQuery; 
begin 
  mensagem := ''; 
  result := false; 
  try 
    try 
      LApply := TFDJSONDeltasApplyUpdates.Create(DeltaList); 
      Query := CriaQuery(banco,Tabela); 
      Query.Open(); 
      LApply.ApplyUpdates(banco + '.' + tabela, Query.Command); 
      if LApply.Errors.Count > 0 then 
        raise Exception.Create(LApply.Errors.Strings.ToString); 
      result := true; 
    except 
      on E:Exception do 
      begin 
        mensagem := 'Ocorreu um Erro na atualização: ' + #13#10 + E.Message; 
      end; 
    end; 
  finally 

  end; 

end; 

The GetDeltas function (the function that generates the DeltaList):

function GetDeltas(Banco, Tabela : String; MemTable : TFDMemTable) : TFDJSONDeltas;
begin
  if MemTable.State in [dsInsert, dsEdit] then
    MemTable.Post;
  result := TFDJSONDeltas.Create;
  TFDJSONDeltasWriter.ListAdd(result, MemTable);
end;

My "CriaQuery" Function:

function TServerMethods.CriaQuery(Database : String; Tabela : String = '') : TFDQuery;
var
  FieldName : Boolean;
  i : Integer;
begin
  result := TFDQuery.Create(self);
  result.Connection := Connection;
  result.FetchOptions.AutoFetchAll := afAll;
  result.name := 'Qry' + Database + tabela;
  result.SQL.Clear;
  FieldName := false;
  if Trim(Tabela) <> '' then
  begin
    result.SQL := MontaSQL(database + '.' + tabela);
    result.SQL.Add(' and 1 = 0');
    result.Open();
    QryCampos.First;
    result.IndexFieldNames := result.Fields[1].FieldName;
    for i := 0 to result.Fields.Count-1 do
    begin
      if (UPPERCASE(Copy(result.Fields[i].FieldName, Length(result.Fields[i].FieldName)-1,2)) = 'ID') and
         (not FieldName) then
      begin
        result.Fields[i].ProviderFlags := [pfInUpdate, pfInWhere, pfInKey];
        FieldName := true;
      end
      else
        result.Fields[i].ProviderFlags := [pfInUpdate];
    end;
    result.Close;
    result.SQL.Delete(result.SQL.Count-1);
  end;
end;

Function that generates the bindings of the components:

procedure LinkaComponente(Campo : TField; Dono : TFmxObject; Classe : String);
var
  BindSource : TBindSourceDB;
  BindingList : TBindingsList;
  Link : TLinkControlToField;
begin
  if Dono is TForm then
  begin
    BindSource := TBindSourceDB.Create(Dono);
  end
  else
  begin
    BindSource := TBindSourceDB.Create(Dono.Owner);
  end;
  BindingList := TBindingsList.Create(BindSource.Owner);
  Link := TLinkControlToField.Create(BindSource.Owner);
  BindSource.DataSet := Campo.DataSet;

  if Classe = 'TCheckBox' then
  begin
    Link.Control := Dono.FindComponent(Campo.FieldName);
    Link.CustomFormat := 'ToStr(%s) <> "N"';
    Link.CustomParse  := 'IfThen(%s,"S","N")';
  end
  else if Classe = 'TFrameF2' then
  begin
    Link.Control := (Dono.FindComponent('Frame' + Campo.FieldName) as TFrameF2).edtFK;
  end
  else
    Link.Control := Dono.FindComponent(Campo.FieldName);
  Link.DataSource := BindSource;
  Link.FieldName := Campo.FieldName;
  Link.Active := true;
end;

the moment I call the applyUpdates function:

procedure TDMPadrao.DMApplyUpdates;
var
  Deltas : TFDJSONDeltas;
  Mensagem : String;
begin
  //repetir esses comando para todas as MemTables do DM na sua ordem de dependencia
  //       tabelas pai antes de tabelas filhas...
  try
    Deltas := GetDeltas(banco, tabela, FDMemTable);
  except
    on E:Exception do
    begin
      FDMemTable.Edit;
      MostraMensagemBasica('Ocorreu um Erro na atualização:' + #13#10 + E.Message);
      abort;
    end;
  end;
  if not DMClient.ServerMethodsClient.ApplyUpdates(banco, tabela, Deltas, Mensagem) then
  begin
    FDMemTable.Edit;
    MostraMensagemBasica(Mensagem);
    abort;
  end;
end;

Everything works fine when I'm reading. I Only get a problem when I call the ApplyUpdates function

Thanks.

Answer 1

I had similar problem and I got it resolved passing the table name to Query.UpdateOptions.UpdateTableName before ApplyUpdates.

• Are you doing it inside "CriaQuery"?
• What is your Delphi Version?

Here is my working code, I have tested it in Delphi XE7 e XE7 Update 1:

procedure TDBDM.ApplyDeltas(const ADeltaList: TFDJSONDeltas; const TableName: string);
var
  JSONDeltas: IFDJSONDeltasApplyUpdates;
  Query: TFDQuery;
begin
  JSONDeltas := TFDJSONDeltasApplyUpdates.Create(ADeltaList);
  Query := CreateQuery(TableName);
  try
    Query.UpdateOptions.UpdateTableName := TableName;
    JSONDeltas.ApplyUpdates(0, Query.Command);

    if JSONDeltas.Errors.Count > 0 then
    begin
      raise Exception.Create(JSONDeltas.Errors.Strings.Text);
    end;
  finally
    Query.Free;
  end;
end;

Notes

• different from your code, Query.Open is not called.
• TFDMemTable.CachedUpdates must be True

Edit: Added the client side code to applyUpdates

I call this method in TFDMemTable.AfterPost event.

    const
      CustomerTableName = 'CUSTOMER';

    procedure TCustomersDataModuleClient.ApplyUpdates;
    var
      Deltas: TFDJSONDeltas;
    begin
      Deltas := TFDJSONDeltas.Create;
      TFDJSONDeltasWriter.ListAdd(Deltas, CustomerTableName, CustomersMemTable);
      RestClientModule.CustomersMethodsClient.ApplyUpdates(Deltas);
      CustomersMemTable.CommitUpdates;
    end;