Make an XSLT result document be processed by a “pa

2019-05-14 15:35发布

站内问答 / 移动开发
382 2 2

I have document grandchild.xml whose result after being processed with granchild.xsl must be forwarded to child.xsl, then it must be finally processed and output by parent.xsl.

I have tried adding an xml-stylesheet element to the result document, expecting it to processed using by the referenced XSL stylesheet, but nothing happened.

What is the correct declaration to accomplish this task? I have searched a lot on Internet, with no results.

标签： xml xslt
举报
2条回答
Explosion°爆炸
2楼-- · 2019-05-14 16:05

Unless anybody knows any better, I believe the ability to recursively process XSLT output on a browser is impossible.

To prove it, I have just tried the following in IE8, FF14 and Chrome...

level1.xml

<?xml version="1.0" encoding="utf-8" ?> 
<?xml-stylesheet title="XSL_formatting" type="text/xsl" href="level1.xsl"?>
<data>
  <id>Level 1 data</id>
</data>

level1.xsl

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:template match="/">
     <?xml-stylesheet title="XSL_formatting" type="text/xsl" href="level2.xsl"?>
     <data2>
       <id2>Level 2: <xsl:value-of select="/data/id"/></id2>
     </data2>
   </xsl:template>   
</xsl:stylesheet>

level2.xsl

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:template match="/">
     <html>
       <body>
         <b>Level 3:</b> <xsl:value-of select="/data2/id2"/>
       </body>
     </html>
   </xsl:template>   
</xsl:stylesheet>

The result from all 3 browsers is simply to display Level 2: Level 1 Data.

查看更多
0人赞 添加讨论(0) 举报
Fickle 薄情
3楼-- · 2019-05-14 16:07

Here is an example of multi-pass transformation within a browser:

Let us have this source XML document:

<?xml-stylesheet title="XSL_formatting"
  type="text/xsl" href="MultiPassBrowser.xsl"?>
<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

Let us have these two XSLT transformations:

MultiPassBrowser1.xsl

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="num/text()">
  <xsl:value-of select=". *2"/>
 </xsl:template>
</xsl:stylesheet>

and

MultiPassBrowser2.xsl

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*" mode="pass2">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*" mode="pass2"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="num" mode="pass2">
  <p><xsl:value-of select=". +1"/></p>
 </xsl:template>
</xsl:stylesheet>

The first transformation copies the XML document "as-is", but with the string value of every num element multiplied by 2.

The second transformation copies the XML document "as-is", but with the string value of every num element incremented.

If the second transformation is applied on the result of the first, the final values, obtained from the initial num elements must be 3, 5, 7, ..., 21.

Here is the transformation that glues these two together:

MultiPassBrowser.xsl

<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
 exclude-result-prefixes="ext msxsl">
 <xsl:import href="file:///C:/Temp/delete/MultiPassBrowser1.xsl"/>
 <xsl:import href="file:///C:/Temp/delete/MultiPassBrowser2.xsl"/>
 <xsl:output method="html"/>
 <xsl:strip-space elements="*"/>

 <msxsl:script language="JScript" implements-prefix="ext">
     this['node-set'] =  function (x) {
      return x;
      }
 </msxsl:script>

 <xsl:template match="/">
  <html>
      <xsl:variable name="vrtfPass1">
        <xsl:apply-templates select="/*"/>
      </xsl:variable>

      <xsl:apply-templates select="ext:node-set($vrtfPass1)/*/*"
                           mode="pass2"/>
  </html>
 </xsl:template>
</xsl:stylesheet>

The result, when the XML file is opened with both IE, Firefox, Safari and Opera, is the correct, expected one:

<html>
   <p>3</p>
   <p>5</p>
   <p>7</p>
   <p>9</p>
   <p>11</p>
   <p>13</p>
   <p>15</p>
   <p>17</p>
   <p>19</p>
   <p>21</p>
</html>

Explanation:

  1. The primary stylesheet module (the one referenced in the XML document PI) imports the two stylesheet modules that contain the separate transformations.

  2. The result of the first transformation is captured in the variavle $vrtfPass1.

  3. In XSLT 1.0 such variable is of the infamous "RTF" (Result Tree Fragment) type and cannot be operated directly (only copying and the string() function can be used on an RTF). Here we use a portable variant of the xxx:node-set() extension function, that works both in IE and in the other four major browsers. This portable extension was first proposed by @DavidCarlisle and the original can be found in his blog.

  4. Templates in mode "pass2" are then applied on the node-set, to which we converted, in the step above, the RTF variable. All templates in the second imported stylesheet module are in mode "pass2", thus they are selected for execution.

  5. The final result is produced.

查看更多
0人赞 添加讨论(0) 举报
登录 后发表回答
相关问题
查看全部
相关文章
查看全部
收藏的人(2)