Random Number Generation to Memory from a Distribu

Question

I want to generate random numbers from a selected distribution in VBA (Excel 2007). I'm currently using the Analysis Toolpak with the following code:

     Application.Run "ATPVBAEN.XLAM!Random", "", A, B, C, D, E, F

Where

A = how many variables that are to be randomly generated 
B = number of random numbers generated per variable 
C = number corresponding to a distribution
         1= Uniform
         2= Normal
         3= Bernoulli
         4= Binomial
         5= Poisson
         6= Patterned
         7= Discrete 
D = random number seed
E = parameter of distribution (mu, lambda, etc.) depends on choice for C
(F) = additional parameter of distribution (sigma, etc.) depends on choice for C

But I want to have the random numbers be generated into an array, and NOT onto a sheet. I understand that where the "" is designates where the random numbers should be printed to, but I don't know the syntax for assigning the random numbers to an array, or some other form of memory storage instead of to a sheet.

I've tried following the syntax discussed at this Analysis Toolpak site, but have had no success.

I realize that VBA is not the ideal place to generate random numbers, but I need to do this in VBA. Any help is much appreciated! Thanks!

Answer 1

Using the inbuilt functions is the key. There is a corresponding version for each of these functions but Poisson. In my presented solution I am using an algorithm presented by Knuth to generate a random number from the Poisson Distribution.

For Discrete or Patterned you obviously have to write your custom algorithm.

Regarding the seed you can place a Randomize [seed] before filling your array.

Function RandomNumber(distribution As Integer, Optional param1 = 0, Optional param2 = 0)

    Select Case distribution
    Case 1 'Uniform
        RandomNumber = Rnd()
    Case 2 'Normal
        RandomNumber = Application.WorksheetFunction.NormInv(Rnd(), param1, param2)
    Case 3 'Bernoulli
        RandomNumber = IIf(Rnd() > param1, 1, 0)
    Case 4 'Binomial
        RandomNumber = Application.WorksheetFunction.Binom_Inv(param1, param2, Rnd())
    Case 5 'Poisson
        RandomNumber = RandomPoisson(param1)
    Case 6 'Patterned
        RandomNumber = 0
    Case 7 'Discrete
        RandomNumber = 0
    End Select

End Function

Function RandomPoisson(ByVal lambda As Integer)   'Algorithm by Knuth

    l = Exp(-lambda)
    k = 0
    p = 1

    Do
         k = k + 1
         p = p * Rnd()
    Loop While p > l

    RandomPoisson = k - 1

End Function

Answer 2

Why not use the inbuilt functions?

1. Uniform = rnd
2. Normal = WorksheetFunction.NormInv
3. Bernoulli = iif(rnd()<p,0,1)
4. Binomial = WorksheetFunction.Binomdist
5. Poisson = WorksheetFunction.poisson
6. Patterned = for ... next
7. Discrete =

-

select case rnd()
    case <0.1
       'choice 1
    case 0.1 to 0.4
       'choice 2
    case >0.4
       'choice 3
end select