How do you concatenate string in cmake

Question

Is there a way to concatenate strings in cmake?

I have a folder that only contains .cpp files with main methods. I thought this would be easy by just using a foreach through all src files. This is what I've got this far:

project(opengl-tutorial)
cmake_minimum_required(VERSION 2.8)

aux_source_directory(. SRC_LIST)

add_definitions(
    --std=c++11
)

foreach (src ${SRC_LIST})
    # name = ${src} + ".out"
    add_executable(${name} ${src})
    target_link_libraries(${name} GL GLU GLEW glfw)
endforeach(src ${SRC_LIST})

How can I do what's described in the comment?

Answer 1

if you just want to deal with a string value see @nonexplosive's answer.

However if you wish to have a Cmake variable in your CMakeLists.txt and set that variable to some value do use either: [string()] for Cmake 3.0+ (https://cmake.org/cmake/help/v3.0/command/string.html) or set() for Cmake 2.0+.

The reason you have two options is because older cmake doesn't support the CONCAT feature.

Example CMakeLists.txt:

cmake_minimum_required(VERSION 2.8.11)
project(Hello)
string(CONCAT x "hello" "goodbye")
set(y "hellogoodbye")
message(STATUS "DEBUG: x=${x}")
message(STATUS "DEBUG: y=${y}")

Full stdout:

-- DEBUG: x=hellogoodbye
-- DEBUG: y=hellogoodbye
-- Configuring done
-- Generating done
-- Build files have been written to: /home/_______/testing/_______

Answer 2

Three typical CMake string concatenation methods

While the answer to this particular question will be best handled via set or string, there is a third possibility which is list if you want to join strings with an arbitrary character.

set()

Just combine strings like in bash

set(FILE file)
set(FILE_TXT ${FILE}.txt)
message(STATUS "FILE_TXT: ${FILE_TXT}")

string(CONCAT)

Concatenate all the input arguments together and store the result in the named output variable.

string(CONCAT [...])

string(CONCAT MULTI "xxxx" "YYYY" "xxxx")
message(STATUS "MULTI: ${MULTI}")

list(APPEND)

Appends elements to the list.

list(APPEND [ ...])

When it comes to things like compiler flags, this is the tool of choice. Lists in CMake are just semicolon separated strings and when you quote them, you get the list joined with semicolons. Then you can just string replace the semicolon.

set(FLAGS "")
list(APPEND FLAGS "-D option1")
list(APPEND FLAGS "-D option2")
list(APPEND FLAGS "-D option3")
string( REPLACE ";" " " FLAGS "${FLAGS}" )
message(STATUS "FLAGS:" ${FLAGS})

Answer 3

"${src}.out" should work fine, so you can write set(NAME "${src}.out") and use ${NAME} wherever you need to.

Answer 4

This is only sort of related, but I found this answer when looking for how do you concatenate paths so that you don't get double or duplicate slashes if one ends in a slash and the other begins with one?

if SOME_VAR="/foo/" and SOME_OTHER_VAR="/bar/"

FILE(TO_CMAKE_PATH "${SOME_VAR}/${SOME_OTHER_VAR}") 

will give you /foo/bar/

if you want it to give you native path delimiters (i.e. backslashes in windows), then use TO_NATIVE_PATH instead of TO_CMAKE_PATH