How to do a powerset in DrRacket?

Question

I'm using the beginning language with list abbreviations for DrRacket and want to make a powerset recursively but cannot figure out how to do it. I currently have this much

(define
  (powerset aL)
  (cond
    [(empty? aL) (list)]

any help would be good.

Answer 1

Here's yet another implementation, after a couple of tests it appears to be faster than Chris' answer for larger lists. It was tested using standard Racket:

(define (powerset aL)
  (if (empty? aL)
      '(())
      (let ((rst (powerset (rest aL))))
        (append (map (lambda (x) (cons (first aL) x))
                     rst)
                rst))))

Answer 2

            What's in a powerset? A set's subsets. 
            An empty set is any set's subset,
            so powerset of empty set's not empty. 
            Its only element it is an empty set:

(define
  (powerset aL)
  (cond
    [(empty? aL) (list empty)]
    [else

            As for non-empty sets, there is a choice,
            for each set's element, whether to be
            or not to be included in subset
            which is a member of a powerset. 

            We thus proceed along the input list, combining 
            each element with a resulting set, 
            that, which we get recursively applying 
            our procedure to the rest of input:

       (add-into (powerset (rest aL))
                 (first aL))]))

(define
  (add-into r a)                  ; `r` is recursive result, `a` is first element
  (cond
    [(empty? r)  empty]           ; nothing to add `a` to
    [else
      (cons (cons a (first r))    ; either add `a`,
            (cons (first r)       ;   or not, to the first in `r`
                  (add-into       ; and recursively proceed
                      (rest r)    ;   to add `a` into the rest of `r`
                      a )))]))

            "There are no answers, only choices". Rather, 
            the choices made, are what the answer's made of.

Answer 3

Here's my implementation of power set (though I only tested it using standard Racket language, not Beginning Student):

(define (powerset lst)
  (if (null? lst)
      '(())
      (append-map (lambda (x)
                    (list x (cons (car lst) x)))
                  (powerset (cdr lst)))))

(Thanks to samth for reminding me that flatmap is called append-map in Racket!)

Answer 4

In Racket,

#lang racket

(define (power-set xs)
  (cond
    [(empty? xs) (list empty)]                 ; the empty set has only empty as subset
    [(cons? xs)  (define x  (first xs))        ; a constructed list has a first element
                 (define ys (rest  xs))        ; and a list of the remaining elements
                 ;; There are two types of subsets of xs, thouse that
                 ;; contain x and those without x.
                 (define with-out-x            ; the power sets without x
                   (power-set ys))                 
                 (define with-x                ; to get the power sets with x we 
                   (cons-all x with-out-x))    ; we add x to the power sets without x
                 (append with-out-x with-x)])) ; Now both kind of subsets are returned.

(define (cons-all x xss)
  ; xss is a list of lists
  ; cons x onto all the lists in xss
  (cond
    [(empty? xss) empty]
    [(cons?  xss) (cons (cons     x (first xss))    ; cons x to the first sublist
                        (cons-all x (rest xss)))])) ; and to the rest of the sublists

To test:

(power-set '(a b c))