Preserve SQL Indexes While Altering Column Datatyp

Question

I have a smalldatetime column that I need to alter to be a datetime column. This is something that will be part of an install process, so it cannot be a manual procedure. Unfortunately, the column has a few indexes and a not null constraint on it. The indexes are performance related and would need to be retained only using the new data type. Is it possible to write a statement that will allow me to retain the relevant information while still altering the column datatype? If so, how can this be done?

Answer 1

The best thing to do is to create a procedure that returns the index script of a given table / column. So you can remove the indexes just from the column being altered and not all indexes from the table, whereas creating indices can be somewhat expensive.

1. Stores the result of the procedure in a datatable
2. Delete the indices of the column
3. Modify your column

4. Rebuild the indexes stored in the datatable

   -- objective   : Generates indices scripting using specified column
   -- Parameters : 
   --     @Tabela  -> Name of the table that the column belongs to 
   --     @Coluna -> Name of the column that will be searched for the indices to generate the script
   --Use: proc_ScriptIndexColumn 'TableName', 'CollumnName'
   
   SET ANSI_NULLS ON
   GO
   SET QUOTED_IDENTIFIER ON
   GO
   Create Proc proc_ScriptIndexColumn (@Tabela VARCHAR(4000), @Coluna VARCHAR(4000)) 
   AS 
   BEGIN     
        DECLARE @isql_key VARCHAR(4000), 
            @isql_incl VARCHAR(4000), 
            @tableid INT, 
            @indexid INT         
    DECLARE @tablename VARCHAR(4000), 
            @indexname VARCHAR(4000)         
    DECLARE @isunique INT, 
            @isclustered INT, 
            @indexfillfactor INT         
    DECLARE @srsql VARCHAR(MAX)        
    DECLARE @ScriptsRetorno TABLE 
            (Script VARCHAR(MAX))        
    DECLARE index_cursor CURSOR  
      FOR 
        SELECT tablename = OBJECT_NAME(i.[object_id]), 
               tableid       = i.[object_id], 
               indexid       = i.index_id, 
               indexname     = i.name, 
               isunique      = i.is_unique, 
               CASE I.type_desc 
                    WHEN 'CLUSTERED' THEN 1 
                    ELSE 0 
               END                     AS isclustered, 
               indexfillfactor = i.fill_factor                  
        FROM   sys.indexes             AS i 
               INNER JOIN SYSOBJECTS   AS O 
                    ON  I.[object_id] = O.ID 
               INNER JOIN sys.index_columns AS ic 
                    ON  (ic.column_id > 0 
                            AND (ic.key_ordinal > 0 
                                    OR ic.partition_ordinal = 0 
                                    OR ic.is_included_column != 0 
                                )) 
                    AND (   ic.index_id = CAST(i.index_id AS INT) 
                            AND ic.object_id = i.[object_id] 
                        ) 
               INNER JOIN sys.columns  AS sc 
                       ON  sc.object_id = ic.object_id 
                    AND sc.column_id = ic.column_id 
        WHERE  O.XTYPE = 'U' 
               AND i.typE = 2 /*Non clustered*/ 
               AND i.is_unique = 0 
               AND i.is_hypothetical = 0 
               AND UPPER(OBJECT_NAME(i.[object_id])) = UPPER(@Tabela) 
               AND UPPER(sc.name) = UPPER(@Coluna)       
   
    OPEN index_cursor  
    FETCH NEXT FROM index_cursor INTO @tablename,@tableid, @indexid,@indexname ,  
    @isunique ,@isclustered , @indexfillfactor       
    WHILE @@fetch_status <> -1 
    BEGIN 
        SELECT @isql_key = '', 
               @isql_incl = ''           
        SELECT @isql_key = CASE ic.is_included_column 
                                WHEN 0 THEN CASE ic.is_descending_key 
                                                 WHEN 1 THEN @isql_key +COALESCE(sc.name, '') + 
                                                      ' DESC, ' 
                                                 ELSE @isql_key + COALESCE(sc.name, '')  
                                                      + ' ASC, ' 
                                            END 
                                ELSE @isql_key 
                            END, 
               --include column  
               @isql_incl = CASE ic.is_included_column 
                                 WHEN 1 THEN CASE ic.is_descending_key 
                                                  WHEN 1 THEN @isql_incl + 
                                                       COALESCE(sc.name, '') + 
                                                       ', ' 
                                                  ELSE @isql_incl + COALESCE(sc.name, '')  
                                                       + ', ' 
                                             END 
                                 ELSE @isql_incl 
                            END 
        FROM   sysindexes i 
               INNER JOIN sys.index_columns AS ic 
                    ON  ( 
                            ic.column_id > 0 
                            AND ( 
                                    ic.key_ordinal > 0 
                                    OR ic.partition_ordinal = 0 
                                    OR ic.is_included_column != 0 
                                ) 
                        ) 
                    AND (ic.index_id = CAST(i.indid AS INT) AND ic.object_id = i.id) 
               INNER JOIN sys.columns AS sc 
                      ON  sc.object_id = ic.object_id 
                    AND sc.column_id = ic.column_id 
        WHERE  i.indid > 0 
               AND i.indid < 255 
               AND (i.status & 64) = 0 
               AND i.id = @tableid 
               AND i.indid = @indexid 
        ORDER BY 
               i.name, 
               CASE ic.is_included_column 
                    WHEN 1 THEN ic.index_column_id 
                    ELSE ic.key_ordinal 
               END           
        IF LEN(@isql_key) > 1 
            SET @isql_key = LEFT(@isql_key, LEN(@isql_key) -1)  
   
        IF LEN(@isql_incl) > 1 
            SET @isql_incl = LEFT(@isql_incl, LEN(@isql_incl) -1)            
        SET @srsql = 'CREATE ' + 'INDEX [' + @indexname + ']' + ' ON [' + @tablename 
            + '] '           
        SET @srsql = @srsql + '(' + @isql_key + ')'              
        IF (@isql_incl <> '') 
            SET @srsql = @srsql + ' INCLUDE(' + @isql_incl + ')'             
        IF (@indexfillfactor <> 0) 
             SET @srsql = @srsql + ' WITH ( FILLFACTOR = ' + CONVERT(VARCHAR(10), @indexfillfactor) 
                + ')'            
        FETCH NEXT FROM index_cursor INTO @tablename,@tableid,@indexid,@indexname,  
        @isunique ,@isclustered , @indexfillfactor           
        INSERT INTO @ScriptsRetorno 
        VALUES 
          (@srsql) 
    END  
    CLOSE index_cursor  
    DEALLOCATE index_cursor   
    SELECT * 
    FROM   @ScriptsRetorno 
   RETURN @@ERROR 
   END 
   

Answer 2

You can not change the datatype from smalldatetime to datetime with the indexes, unique constraints, foreign key constraints or check constraints in place. You will have to drop them all prior to changing the type. Then:

alter table T alter column TestDate datetime not null

Then recreate the constraints and indexes that still apply.

---

Some different approaches for generating the drop and creates:

1) If you have given explicit names to all indexes and constraints then your installer can run a static script in each environment (dev, test, user acceptance testing, performance testing, etc, production.)

To generate this explicit script you can: a) Use SSMS (or with SQL Server 2000, enterprise manager) to script the create and drop statements. b) Work from you source code repository to discover the names and definitions of the dependent objects and put together the appropriate static script. c) Attempt to run the alter statement. See what it fails on. Look up the definitions and hand write the drop and create. (Personally, this would be great for writing the drop, not so good at the create.)

2) If you have not given explicit names to all indexes and constraints, then your installer will have to query the data dictionary for the appropriate names and use dynamic SQL to run the drops, in the correct order, prior to the alter column statement and then the creates, in the correct order, after the alter column.

This will be simpler if you know that there are no constraints, and just indexes.

There may be tools or libraries that already know how to do this.

Also, if this is a packaged application, you may not be assured that the local DBAs have not added indexes.

NOTE: If there is a unique constraint, it will have built an index, which you will not be able to drop with DROP INDEX.

Answer 3

If you are just changing the size, the Index will still remain on the table.

If you are changing the data type, then you will get an error message stating that objects depend on the column that you are trying to change and therefore you will not be able to change it.

You can script out the indexes in question manually or via script. In SSMS, right click the table and script out the object in question.

If you want programatic index scripting, here is a stored proc that I have been using that I got from an ex colleague of mine.

Drop Proc ScriptIndex
GO
Create Proc ScriptIndex
    @TableName      VarChar (Max),
    @IndexScript    VarChar (Max) OUTPUT
AS

-- Get all existing indexes, EXCEPT the primary keys
DECLARE cIX CURSOR FOR
SELECT OBJECT_NAME(SI.Object_ID), SI.Object_ID, SI.Name, SI.Index_ID
FROM Sys.Indexes SI 
    LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS TC 
        ON SI.Name = TC.CONSTRAINT_NAME 
        AND OBJECT_NAME(SI.Object_ID) = TC.TABLE_NAME
WHERE 1=1
    AND OBJECT_NAME(SI.Object_ID) = @TableName
    AND TC.CONSTRAINT_NAME IS NULL
    AND OBJECTPROPERTY(SI.Object_ID, 'IsUserTable') = 1
ORDER BY OBJECT_NAME(SI.Object_ID), SI.Index_ID

DECLARE @IxTable SYSNAME
DECLARE @IxTableID INT
DECLARE @IxName SYSNAME
DECLARE @IxID INT

-- Loop through all indexes
OPEN cIX
FETCH NEXT FROM cIX INTO @IxTable, @IxTableID, @IxName, @IxID
WHILE (@@FETCH_STATUS = 0)
BEGIN
   DECLARE @IXSQL NVARCHAR(4000) 
   DECLARE @PKSQL NVARCHAR(4000) 
   SET @PKSQL = ''
   SET @IXSQL = 'CREATE '

   -- Check if the index is unique
   IF (INDEXPROPERTY(@IxTableID, @IxName, 'IsUnique') = 1)
      SET @IXSQL = @IXSQL + 'UNIQUE '
   -- Check if the index is clustered
   IF (INDEXPROPERTY(@IxTableID, @IxName, 'IsClustered') = 1)
      SET @IXSQL = @IXSQL + 'CLUSTERED '

   SET @IXSQL = @IXSQL + 'INDEX ' + @IxName + ' ON ' + @IxTable + '('

   -- Get all columns of the index
   DECLARE cIxColumn CURSOR FOR 
      SELECT SC.Name
      FROM Sys.Index_Columns IC
         JOIN Sys.Columns SC ON IC.Object_ID = SC.Object_ID AND IC.Column_ID = SC.Column_ID
      WHERE IC.Object_ID = @IxTableID AND Index_ID = @IxID
      ORDER BY IC.Index_Column_ID

   DECLARE @IxColumn SYSNAME
   DECLARE @IxFirstColumn BIT SET @IxFirstColumn = 1

   -- Loop throug all columns of the index and append them to the CREATE statement
   OPEN cIxColumn
   FETCH NEXT FROM cIxColumn INTO @IxColumn
   WHILE (@@FETCH_STATUS = 0)
   BEGIN
      IF (@IxFirstColumn = 1)
         SET @IxFirstColumn = 0
      ELSE
         SET @IXSQL = @IXSQL + ', '

      SET @IXSQL = @IXSQL + @IxColumn

      FETCH NEXT FROM cIxColumn INTO @IxColumn
   END
   CLOSE cIxColumn
   DEALLOCATE cIxColumn

   SET @IXSQL = @IXSQL + ')'
   -- Print out the CREATE statement for the index
   PRINT @IXSQL

   FETCH NEXT FROM cIX INTO @IxTable, @IxTableID, @IxName, @IxID
END

CLOSE cIX
DEALLOCATE cIX

GO
Declare @TableName VarChar (Max), @IndexScript VarChar (Max)

Exec ScriptIndex 'Client', @IndexScript OUTPUT
Print @IndexScript

Answer 4

EDIT: It depends on the original and changed datatype. If you try to alter a column from varchar to nvarchar, it will fail. Whereas, if you alter column from varchar(16) to varchar(32), it will succeed.

--Disable Index
ALTER INDEX MyIndex ON MyTable DISABLE
GO

-- Change column datatype

--Enable Index
ALTER INDEX MyIndex ON MyTable REBUILD
GO

If you change the type of a column, then all indexes that use that column will have to be rebuilt.

But unless you have huge volumes of data (or run 24/7), rebuilding indexes is no big deal. Just schedule a maintenance window.