Remove nil values from a map?

Question

I have a Clojure map that may contain values that are nil and I'm trying to write a function to remove them, without much success (I'm new to this).

E.g.:

(def record {:a 1 :b 2 :c nil})
(merge (for [[k v] record :when (not (nil? v))] {k v}))

This results in a sequence of maps, which isn't what I expected from merge:

({:a 1} {:b 2})

I would like to have:

{:a 1, :b 2}

Answer 1

Jürgen Hötzel solution refined to fix the nil/false issue

(into {} (filter #(not (nil? (val %))) {:a true :b false :c nil}))

A bit shorter version of @thnetos solution

(into {} (remove #(nil? (val %)) {:a true :b false :c nil}))

Answer 2

Here's one that works on maps and vectors:

(defn compact
  [coll]
  (cond
    (vector? coll) (into [] (filter (complement nil?) coll))
    (map? coll) (into {} (filter (comp not nil? second) coll))))

Answer 3

Here is one that works on nested maps:

(defn remove-nils
  [m]
  (let [f (fn [[k v]] (when v [k v]))]
    (postwalk (fn [x] (if (map? x) (into {} (map f x)) x)) m)))