How to use a dll written for VB.Net in C#

Question

I have question to ask.

I have a dll file written for reading&writing data on USB. To use dll in VB.Net, one needs to integrate a .vb file which interface to that dll file to use its functions, properties etc..

What I need is to use this dll in a C# project. is this possible? if it's, how can I achieve it?

The Code in form Class:

Public Class frmUSB
    ' vendor and product IDs
    Private Const VendorID As Integer = &H1234    'Replace with your device's
    Private Const ProductID As Integer = &H1234      'product and vendor IDs

    ' read and write buffers
    Private Const BufferInSize As Integer = 1 'Size of the data buffer coming IN to the PC
    Private Const BufferOutSize As Integer = 1    'Size of the data buffer going OUT from the PC
    Dim BufferIn(BufferInSize) As Byte          'Received data will be stored here - the first byte in the array is unused
    Dim BufferOut(BufferOutSize) As Byte    'Transmitted data is stored here - the first item in the array must be 0

    ' ****************************************************************
    ' when the form loads, connect to the HID controller - pass
    ' the form window handle so that you can receive notification
    ' events...
    '*****************************************************************
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        ' do not remove!
        ConnectToHID(Me)
    End Sub

    '*****************************************************************
    ' disconnect from the HID controller...
    '*****************************************************************
    Private Sub Form1_FormClosed(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
        DisconnectFromHID()
    End Sub

    '*****************************************************************
    ' a HID device has been plugged in...
    '*****************************************************************
    Public Sub OnPlugged(ByVal pHandle As Integer)
        If hidGetVendorID(pHandle) = VendorID And hidGetProductID(pHandle) = ProductID Then
            ' ** YOUR CODE HERE **
        End If
    End Sub

    '*****************************************************************
    ' a HID device has been unplugged...
    '*****************************************************************
    Public Sub OnUnplugged(ByVal pHandle As Integer)
        If hidGetVendorID(pHandle) = VendorID And hidGetProductID(pHandle) = ProductID Then
            hidSetReadNotify(hidGetHandle(VendorID, ProductID), False)
            ' ** YOUR CODE HERE **
        End If
    End Sub

    '*****************************************************************
    ' controller changed notification - called
    ' after ALL HID devices are plugged or unplugged
    '*****************************************************************
    Public Sub OnChanged()
        ' get the handle of the device we are interested in, then set
        ' its read notify flag to true - this ensures you get a read
        ' notification message when there is some data to read...
        Dim pHandle As Integer
        pHandle = hidGetHandle(VendorID, ProductID)
        hidSetReadNotify(hidGetHandle(VendorID, ProductID), True)
    End Sub

    '*****************************************************************
    ' on read event...
    '*****************************************************************
    Public Sub OnRead(ByVal pHandle As Integer)
        ' read the data (don't forget, pass the whole array)...
        If hidRead(pHandle, BufferIn(0)) Then

            TextBox1.Text = Str(BufferIn(1))
            ' ** YOUR CODE HERE **
            ' first byte is the report ID, e.g. BufferIn(0)
            ' the other bytes are the data from the microcontroller...
        End If
    End Sub

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

        BufferOut(1) = Val(TextBox2.Text)
        hidWriteEx(VendorID, ProductID, BufferOut(0))

    End Sub
End Class

What can I use to send an instance of my form to HIDDLLInterface (Equvalent for Me Keyword)?

And the interface class code is given below:

Imports System Imports System.Threading Imports System.Runtime.InteropServices

Module HIDDLLInterface
    ' this is the interface to the HID controller DLL - you should not
    ' normally need to change anything in this file.
    '
    ' WinProc() calls your main form 'event' procedures - these are currently
    ' set to..
    '
    ' MainForm.OnPlugged(ByVal pHandle as long)
    ' MainForm.OnUnplugged(ByVal pHandle as long)
    ' MainForm.OnChanged()
    ' MainForm.OnRead(ByVal pHandle as long)


    ' HID interface API declarations...
    Declare Function hidConnect Lib "mcHID.dll" Alias "Connect" (ByVal pHostWin As Integer) As Boolean
    Declare Function hidDisconnect Lib "mcHID.dll" Alias "Disconnect" () As Boolean
    Declare Function hidGetItem Lib "mcHID.dll" Alias "GetItem" (ByVal pIndex As Integer) As Integer
    Declare Function hidGetItemCount Lib "mcHID.dll" Alias "GetItemCount" () As Integer
    Declare Function hidRead Lib "mcHID.dll" Alias "Read" (ByVal pHandle As Integer, ByRef pData As Byte) As Boolean
    Declare Function hidWrite Lib "mcHID.dll" Alias "Write" (ByVal pHandle As Integer, ByRef pData As Byte) As Boolean
    Declare Function hidReadEx Lib "mcHID.dll" Alias "ReadEx" (ByVal pVendorID As Integer, ByVal pProductID As Integer, ByRef pData As Byte) As Boolean
    Declare Function hidWriteEx Lib "mcHID.dll" Alias "WriteEx" (ByVal pVendorID As Integer, ByVal pProductID As Integer, ByRef pData As Byte) As Boolean
    Declare Function hidGetHandle Lib "mcHID.dll" Alias "GetHandle" (ByVal pVendoID As Integer, ByVal pProductID As Integer) As Integer
    Declare Function hidGetVendorID Lib "mcHID.dll" Alias "GetVendorID" (ByVal pHandle As Integer) As Integer
    Declare Function hidGetProductID Lib "mcHID.dll" Alias "GetProductID" (ByVal pHandle As Integer) As Integer
    Declare Function hidGetVersion Lib "mcHID.dll" Alias "GetVersion" (ByVal pHandle As Integer) As Integer
    Declare Function hidGetVendorName Lib "mcHID.dll" Alias "GetVendorName" (ByVal pHandle As Integer, ByVal pText As String, ByVal pLen As Integer) As Integer
    Declare Function hidGetProductName Lib "mcHID.dll" Alias "GetProductName" (ByVal pHandle As Integer, ByVal pText As String, ByVal pLen As Integer) As Integer
    Declare Function hidGetSerialNumber Lib "mcHID.dll" Alias "GetSerialNumber" (ByVal pHandle As Integer, ByVal pText As String, ByVal pLen As Integer) As Integer
    Declare Function hidGetInputReportLength Lib "mcHID.dll" Alias "GetInputReportLength" (ByVal pHandle As Integer) As Integer
    Declare Function hidGetOutputReportLength Lib "mcHID.dll" Alias "GetOutputReportLength" (ByVal pHandle As Integer) As Integer
    Declare Sub hidSetReadNotify Lib "mcHID.dll" Alias "SetReadNotify" (ByVal pHandle As Integer, ByVal pValue As Boolean)
    Declare Function hidIsReadNotifyEnabled Lib "mcHID.dll" Alias "IsReadNotifyEnabled" (ByVal pHandle As Integer) As Boolean
    Declare Function hidIsAvailable Lib "mcHID.dll" Alias "IsAvailable" (ByVal pVendorID As Integer, ByVal pProductID As Integer) As Boolean

    ' windows API declarations - used to set up messaging...

    Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Integer, ByVal hwnd As Integer, ByVal Msg As Integer, ByVal wParam As Integer, ByVal lParam As Integer) As Integer
    Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
                                          (ByVal hwnd As Integer, ByVal nIndex As Integer, ByVal dwNewLong As Integer) As Integer

    Delegate Function SubClassProcDelegate(ByVal hwnd As Integer, ByVal msg As Integer, ByVal wParam As Integer, ByVal lParam As Integer) As Integer
    Public Declare Function DelegateSetWindowLong Lib "USER32.DLL" Alias "SetWindowLongA" _
                                           (ByVal hwnd As Integer, ByVal attr As Integer, ByVal lval As SubClassProcDelegate) As Integer


    ' windows API Constants
    Public Const WM_APP As Integer = 32768
    Public Const GWL_WNDPROC As Short = -4

    ' HID message constants
    Private Const WM_HID_EVENT As Decimal = WM_APP + 200
    Private Const NOTIFY_PLUGGED As Short = 1
    Private Const NOTIFY_UNPLUGGED As Short = 2
    Private Const NOTIFY_CHANGED As Short = 3
    Private Const NOTIFY_READ As Short = 4

    ' local variables
    Private FPrevWinProc As Integer ' Handle to previous window procedure
    Private FWinHandle As Integer ' Handle to message window
    Private Ref_WinProc As New SubClassProcDelegate(AddressOf WinProc)
    Private HostForm As Object

    ' Set up a windows hook to receive notification
    ' messages from the HID controller DLL - then connect
    ' to the controller
    Public Function ConnectToHID(ByRef targetForm As Form) As Boolean
        Dim pHostWin As Integer = targetForm.Handle.ToInt32
        FWinHandle = pHostWin
        pHostWin = hidConnect(FWinHandle)
        FPrevWinProc = DelegateSetWindowLong(FWinHandle, GWL_WNDPROC, Ref_WinProc)
        HostForm = targetForm
    End Function

    ' Unhook from the HID controller and disconnect...
    Public Function DisconnectFromHID() As Boolean
        DisconnectFromHID = hidDisconnect
        SetWindowLong(FWinHandle, GWL_WNDPROC, FPrevWinProc)
    End Function


    ' This is the procedure that intercepts the HID controller messages...

    Private Function WinProc(ByVal pHWnd As Integer, ByVal pMsg As Integer, ByVal wParam As Integer, ByVal lParam As Integer) As Integer
        If pMsg = WM_HID_EVENT Then
            Select Case wParam

                ' HID device has been plugged message...
                Case Is = NOTIFY_PLUGGED
                    HostForm.OnPlugged(lParam)

                    ' HID device has been unplugged
                Case Is = NOTIFY_UNPLUGGED
                    HostForm.OnUnplugged(lParam)

                    ' controller has changed...
                Case Is = NOTIFY_CHANGED
                    HostForm.OnChanged()

                    ' read event...
                Case Is = NOTIFY_READ
                    HostForm.OnRead(lParam)
            End Select

        End If

        ' next...
        WinProc = CallWindowProc(FPrevWinProc, pHWnd, pMsg, wParam, lParam)

    End Function
End Module

Answer 1

You have a coupling problem in your design. To deal with this problem, I would recommend the following:

• Turn HIDDLLInterface into a class that takes an IntPtr in the constructor. In the constructor, call hidConnect.
• Make the class implement IDisposable. The VB IDE gives a decent default implementation. Because you are dealing with unmanaged resources, you should probably also uncomment the finalizer it adds.
• Instead of calling form methods from the dll interface, raise events when the corresponding messages come in.
• Check your PInvoke signatures. If an argument has "handle" in the name, or is declared in the native dll as HWND or Hsomething, you should use IntPtr instead of Integer to more closely match the meaning of the argument.
• You may also consider providing additional method on the new class and completely encapsulate all of the "Declare" functions in the class, but that would be beyond the scope of this question.

After that, the class should look something like this:

Public Class HIDController
    Implements IDisposable

#Region "Constructor"
    Public Sub New(handle As IntPtr)
        If Not hidConnect(handle) Then
            'consider a custom exception type here.  You may also get
            'more info about the failure from GetLastError.
            Throw New Exception("Connection failed")
        End If
        _handle = handle
        _prevWinProc = DelegateSetWindowLong(handle, GWL_WNDPROC, AddressOf Me.WinProc)
    End Sub
#End Region
#Region "IDisposable Support"
    Private disposedValue As Boolean 
    Protected Overridable Sub Dispose(disposing As Boolean)
        If Not Me.disposedValue Then
            If disposing Then
                ' TODO: dispose managed state (managed objects).
            End If

            ' TODO: free unmanaged resources (unmanaged objects) and override Finalize() below.
            DisconnectFromHID()
        End If
        Me.disposedValue = True
    End Sub

    Protected Overrides Sub Finalize()
        Dispose(False)
        MyBase.Finalize()
    End Sub

    Public Sub Dispose() Implements IDisposable.Dispose
        Dispose(True)
        GC.SuppressFinalize(Me)
    End Sub
#End Region

    Private _handle As IntPtr
    Private ReadOnly _prevWinProc As IntPtr

    'on one hand, you are not supposed to throw from Dispose/Finalize, but
    'on the other hand, I don't know what you would do instead to signal failure.
    Private Sub DisconnectFromHID()
        'do not disconnect if you did not connect
        If _handle = IntPtr.Zero Then Exit Sub

        If Not hidDisconnect() Then
            'see above about custom exception type
            Throw New Exception("Disconnect failed")
        End If
        SetWindowLong(_handle, GWL_WNDPROC, _prevWinProc)
        _handle = IntPtr.Zero
    End Sub

    Private Function WinProc(ByVal pHWnd As IntPtr, ByVal pMsg As Integer, ByVal wParam As IntPtr, ByVal lParam As IntPtr) As Integer
        If pMsg = WM_HID_EVENT Then
            Select Case wParam.ToInt32()
                Case NOTIFY_PLUGGED
                    OnPlugged(lParam)
                Case NOTIFY_UNPLUGGED
                    OnUnplugged(lParam)
                Case NOTIFY_CHANGED
                    OnChanged()
                Case NOTIFY_READ
                    OnRead(lParam)
            End Select
        End If

        WinProc = CallWindowProc(FPrevWinProc, pHWnd, pMsg, wParam, lParam)
    End Function

#Region "USB events"
    Private Sub OnPlugged(lParam As IntPtr)
        RaiseEvent Plugged(Me, New ParamEventArgs(lParam))
    End Sub
    Public Event Plugged As EventHandler(Of ParamEventArgs)

    Private Sub OnUnplugged(lParam As IntPtr)
        RaiseEvent Unplugged(Me, New ParamEventArgs(lParam))
    End Sub
    Public Event Unplugged As EventHandler(Of ParamEventArgs)

    Private Sub OnChanged()
        RaiseEvent Changed(Me, EventArgs.Empty)
    End Sub
    Public Event Changed As EventHandler

    Private Sub OnRead(lParam As IntPtr)
        RaiseEvent Read(Me, New ParamEventArgs(lParam))
    End Sub
    Public Event Read As EventHandler(Of ParamEventArgs)
#End Region

    'other constants and declarations I did not copy.

End Class

Public Class ParamEventArgs
    Inherits EventArgs

    Public Sub New(param As IntPtr)
        _param = param
    End Sub

    Private _param As IntPtr
    Public ReadOnly Property Param() As IntPtr
        Get
            Return _param
        End Get
    End Property

End Class

From there, you can change your form to create and dispose an instance of this class in the Load/Close events and hook the handlers. You will have to change your form methods to match the event signatures, but this should be straightforward.

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    _controller = new HIDController(Me.Handle)
    AddHandler _controller.Plugged, AddressOf Me.OnPlugged
    'similarly for other events
End Sub

Private Sub Form1_FormClosed(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
    If _controller IsNot Nothing Then _controller.Dispose()
End Sub

Now the class should be simple to use from a C# dll. Simply compile the HIDController into an assembly in VB.NET and then reference that dll from your C# project (and import any needed namespace). Don't forget to copy the native dll as well; the C# compiler will only copy the VB dll automatically. Any class that can provide a window handle can now create the HIDController and handle its events without the controller knowing which class is hosting it.

PS: I would recommend turning on Option Strict when coding in VB. Also, you may want to look into DllImport for importing functions from native libraries into .NET projects, as that is how most examples will be and will make it easier to copy between VB and C#.

Answer 2

Assuming the VB.NET code is CLS compliant, you can simply add a reference to it to your C# project.

At this point, the namespace and all public members in the DLL will be available to your C# code.

Answer 3

Reference the C# dll in the VB project (or just drop the dll into the /bin folder)

As you know, you need to adapt the VB.NET code in the form class to C#.

In Answer to your question instead of a call from VB.NET Form codebehind:

iConnectToHID(Me)

You would use

iConnectToHID(this);