How to send user input to cmd application and get

2020-02-13 04:28发布

站内问答 / 前沿技术
955 1 4

I design ".html" file that takes inputs from the user and returns some outputs.

The inputs are Query sequence and Name of database.

I want to put the query sequence in a txt file and execute the local program "cmd application" by type:

blastn -query querySequence.txt -db databaseName -out outputFile.txt

Then, present the output file to the user.

I am using windows 7. I think perl is a solution but I did not know anything about perl and how it is working!

1条回答
forever°为你锁心
2楼-- · 2020-02-13 04:39

Screenshot of CommandLine.hta

Screenshot of CommandLine.hta

So, just copy and paste this code on your notepad or notepad++ and save it as CommandLine.hta and execute it by double clic.

NB : The extension must be .hta and not .html

<html>
<title>Execution of command line with HTA by Hackoo</title>
<head>
<HTA:APPLICATION 
     APPLICATIONNAME="Execution of command line with HTA by Hackoo"
     SCROLL="no"
     SINGLEINSTANCE="yes"
     WINDOWSTATE="maximize"
     ICON="Winver.exe"
/>
</head>
<META HTTP-EQUIV="MSThemeCompatible" CONTENT="YES">
<script language="VBScript">
Option Explicit
Dim Title : Title = "Execution of command line with HTA by Hackoo"
'**********************************************************************************************
Sub Window_OnLoad
    Call Run_Cmd("help")
End Sub
'********************************************************************************************** 
Sub Run_Cmd(strCommand)
On Error Resume Next
    If input.value = "" Then
        MsgBox "ATTENTION ! The text box is empty !"& vbcr &_
        "You forgot to type a command on the text box !",vbExclamation,Title
        input.value = "help"
        Exit Sub
    End if
    Output.value = ""
    btnClick.disabled = True
    document.body.style.cursor = "wait"
    btnClick.style.cursor = "wait"
    Const ForReading = 1
    Const TristateTrue = -1
    Const TemporaryFolder = 2
    Const WshHide = 0
    Dim wsh, fs, ts
    Dim strTempFile,strFile, strData
    Set wsh = CreateObject("Wscript.Shell")
    Set fs = CreateObject("Scripting.FileSystemObject")
    strTempFile = fs.BuildPath(fs.GetSpecialFolder(TemporaryFolder).Path, fs.GetTempName)
    strFile = fs.BuildPath(fs.GetSpecialFolder(TemporaryFolder).Path, "result.txt")
    wsh.Run "cmd.exe /c " & strCommand & " > " & DblQuote(strTempFile) & "2>&1", WshHide, True
    wsh.Run "cmd.exe /u /c Type " & DblQuote(strTempFile) & " > " & DblQuote(strFile) & "", WshHide, True
    Set ts = fs.OpenTextFile(strFile,ForReading,True,TristateTrue)
    strData = ts.ReadAll
    Output.Value = "Microsoft Windows [version 7.1 7631]" & vbcrlf &_
    "Copyright (c) 2009 Microsoft Corporation. All rights reserved." & vbcrlf & vbcrlf &_
    "C:\>"& strCommand & vbcrlf & strData
    ts.Close
    fs.DeleteFile strTempFile
    fs.DeleteFile strFile
    document.body.style.cursor = "default"
    btnClick.style.cursor = "default"
    btnClick.disabled = False   
End Sub
'**********************************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'**********************************************************************************************
Sub OnClickButtonCopy()
    document.parentwindow.clipboardData.SetData "text", Output.Value
    MsgBox "The ouput result is copied to the clipboard !",vbInformation,Title
End Sub
'**********************************************************************************************
</script>
</head>
<body bgcolor="123456" text=Darkorange>
<hr>
<center><FONT SIZE="3"><B><I>Some examples of commands</I></B></FONT><BR>
<select style="background-color:lightblue" name="DropDown">
<option value="Tasklist">Tasklist</option>
<option value="CD %Programfiles%\Mozilla Firefox\ | Start Firefox.exe">CD %Programfiles%\Mozilla Firefox\ | Start Firefox.exe</option>
<option value="Tracert www.google.fr">Tracert www.google.fr</option>
<option value="Start iexplore">Start iexplore</option>
<option value="Start Notepad">Start Notepad</option>
<option value="Start Winword">Start Winword</option>
<option value="Explorer.exe /n,/e,/root,C:\Program Files">Explorer.exe /n,/e,/root,C:\Program Files</option>
<option value="Ipconfig">IpConfig</option>
<option value="Dir">Dir</option>
<option value="Ping www.yahoo.fr">Ping www.yahoo.fr</option>
<option value="Ping www.google.fr">Ping www.google.fr</option>
<option value="Taskkill /im iexplore.exe /f">Taskkill /im iexplore.exe /f</option>
</select>
<input type="button" onClick="Run_Cmd(DropDown.value)" value="Run this command">
<center><hr><B><I>Type your input command here</I></B><br>
<input type="text" Name="input" size="10"style="width:100%" value="Ping www.google.com" style="background-color:lightblue">
<input type="submit" name="btnClick" value="Run the input command line" onclick="Run_Cmd(input.value)"> 
<br><hr><B><I> The output result (readonly)</I></B><hr>
<textarea readonly id="Output" style="width:100%" rows="28" style="background-color:black; color:Darkorange">Microsoft Windows [version 7.1 7631]
Copyright (c) 2009 Microsoft Corporation. All rights reserved.
C:\></textarea><input type="button" name="ButtonCopy" value="Copy the ouput result to the Clipboard" onclick="OnClickButtonCopy">
<hr></center>
</body>
</html>
查看更多
0人赞 添加讨论(0) 举报
登录 后发表回答
相关问题
查看全部
相关文章
查看全部
收藏的人(4)