具有最大值添加列的索引作为新列(Add the index of the column with t

我的问题很简单。 当数据如下，

var1    var2    var3
10      40      60
15      10      5

我想添加一个新列MaxValueVar返回有中最大值的列的索引var1 ， var2和var3 。 也就是说，我想打一个表如下。

var1    var2    var3    MaxValueVar
10      40      60      3
15      10      5       1

在RI将使用：

apply(vector, 1, which.max)

我怎样才能做到这一点使用SAS？

Answer 1:

根据您在此处提供样品供您参考的解决方案。 你没有提到如何处理的关系。 这里的关系，第一个出现的牵强。

data test;
input var1 var2 var3;
datalines;
10      40      60
15      10      5
run;

data test;
 set test;
 maxvalue=max(of var1-var3);
 maxvaluevar=0;
  array vars (*) var1-var3;
    do i=1 to dim(vars);
     if maxvaluevar=0 then maxvaluevar=i*(maxvalue=vars(i))+maxvaluevar;
    end;
 drop i maxvalue;
run;

Answer 2:

这是一个类似的解决方案，罗比的的。 它使用vname()函数除数组中的索引以获得所述第一最大值的变量名。

data maxarr (drop=i);
input var1 var2 var3;
 array vars(*) var1-var3;
 max=max(of vars(*));
   do i=1 to dim(vars);
     if vars(i)=max then do;
          MaxValueIndx=i;
          MaxValueVar=vname(vars(i));
          leave;
     end;
   end;
datalines;
10      40      60
15      10      5
;
run;

proc print data=maxarr noobs;run;

Answer 3:

下面的代码应该工作打算，以及在那里是关系的实例创建更多的列。 我知道你说不要打扰，但它是窃听我！

输入测试数据：

data test;
    input var1 var2 var3;
    cards;
10 40 60
15 10 5
7 8 9
13 13 10
5 7 6
10 11 12
10 10 10
1 3 2
3 3 1
;
run;

代码来检查最大值：

data test (drop = i howmanymax);
    set test;
    retain howmanymax;

    howmanymax=0;

    array varlist[*] var1--var3;
    array maxnum[3];

    do i = 1 to DIM(varlist);
        if varlist[i] = max(of var1--var3)
            then do;
                howmanymax+1;
                maxnum[howmanymax] = i;
            end;
    end;

run;

输出如下：

  var1  var2  var3  nummax1 nummax2 nummax3
    10    40    60        3       .       .
    15    10     5        1       .       .
     7     8     9        3       .       .
    13    13    10        1       2       .
     5     7     6        2       .       .
    10    11    12        3       .       .
    10    10    10        1       2       3
     1     3     2        2       .       .
     3     3     1        1       2       .

文章来源: Add the index of the column with the maximum value as a new column