CMD/FTP to create folder using to today date & con

问题:

I'm new to this cmd/FTP command. I would like to create a new folder at my local directory using today's date and connect to FTP to download the specific file to the newly created folder. If I manually type in command one by one at cmd, it has no issue. But when I use a batch file to run, my command stopped at FTP.

setlocal enableextensions
set name=%date:~-10,2%"-"%date:~7,2%"-"%date:~-4,4"_"job%
mkdir C:\%name%
cd C:\%name%
ftp
open 192.168.31.93
*user*
*password*
binary
cd *directory*
mget -i *.*

I did try to separate my command to two batches; 1. folder creation 2. FTP download but the file downloaded didn't go into the folder I created. the downloaded file went to C:\Document & Settings.

main batch file

@echo off
call rename.bat
ftp -i -s:ftp.txt

rename.bat

setlocal enableextensions
set name=%date:~-10,2%"-"%date:~7,2%"-"%date:~-4,4%"_job"
mkdir c:\%name%
cd c:\%name%

ftp.txt

open 192.168.31.93
*user*
*password*
binary
cd *directory*
mget *.*
close

Another method I try is using '!' when in FTP environment, then create a folder then exit back to FTP environment. This method again doesn't work with the batch file. Please help

回答1:

It seems that with command extensions enabled, the working directory set by a child batch file is lost, then the batch file exits.

I'm not sure how to solve it, but you actually do not need the rename.bat file to be a separate file. This "main batch file" should work:

@echo off
setlocal enableextensions
set name=%date:~-10,2%"-"%date:~7,2%"-"%date:~-4,4%"_job"
mkdir c:\%name%
cd /d c:\%name%
ftp -i "-s:%~dp0\ftp.txt"

Also note the /d added to cd. Without that your batch will not work when started from another drive. You also have to use %~dp0 to refer to the batch file folder for the ftp.txt. As at the time ftp is called, you have changed to the target directory.

---

You possibly do not even need the command extensions to be enabled. So simply removing the setlocal enableextensions might solve the problem too. Though you still need the %~dp0 and /d.

回答2:

I've decided to post this, although similar to the answer given, there are a couple of differences.

• It creates the text file, then deletes it, (this keeps everything more portable).
• I have corrected your directory name, (because of a typo).

@Echo Off
Set "Name=%DATE%"
Set "Name=%Name:~-10,2%-%Name:~-7,2%-%Name:~-4%_job"
MD "C:\%Name%" 2>Nul
CD /D "C:\%Name%" || Exit /B
(   Echo open 192.168.31.93
    Echo *user*
    Echo *password*
    Echo binary
    Echo cd *directory*
    Echo mget *.*
    Echo close
)>"ftp.txt"
FTP -i -s:ftp.txt
Del "ftp.txt" 2>Nul
Exit /B