创建一个文件名作为批作业的时间戳创建一个文件名作为批作业的时间戳(Creating a file n

我们有运行每天将文件复制到一个文件夹皮卡批处理作业。 我想也采取文件的副本，并将其与文件名拖放到存档文件夹

 yyyy-MM-dd.log

什么是在Windows批处理作业要做到这一点最简单的方法是什么？

基本上，我在寻找这个Unix命令的等效：

cp source.log `date +%F`.log

Answer 1:

CP source.log %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%.log

但它的环境相关。 我不知道如果%DATE%是局部的，或者依赖于在Windows短日期指定的格式。

这里是一个语言环境无关的方式来提取当前日期这个答案 ，但是这取决于WMIC和FOR /F ：

FOR /F %%A IN ('WMIC OS GET LocalDateTime ^| FINDSTR \.') DO @SET B=%%A
CP source.log %B:~0,4%-%B:~4,2%-%B:~6,2%.log

Answer 2:

这个工作对我来说，是一个文件名，安全的解决方案（虽然它产生一个MM-DD-YYYY格式）：

C:\ set SAVESTAMP=%DATE:/=-%@%TIME::=-%
C:\ set SAVESTAMP=%SAVESTAMP: =%
C:\ set SAVESTAMP=%SAVESTAMP:,=.%.jpg
C:\ echo %SAVESTAMP%
[e-mail]

第一个命令获取日期和替换/与-花费的时间和替代:用-并将它们组合成日期@时间格式。 第二set语句删除任何空格，而第三set取代,与. 并追加.jpg扩展。

上面的代码是在从安全IP摄像机以便进一步处理的图像拉一点点的脚本中使用：

:while
set SAVESTAMP=%DATE:/=-%@%TIME::=-%
set SAVESTAMP=%SAVESTAMP: =%
set SAVESTAMP=%SAVESTAMP:,=.%.jpg
wget-1.10.2.exe --tries=0 -O %SAVESTAMP% http://admin:<password>@<ip address>:<port>/snapshot.cgi
timeout 1
GOTO while

Answer 3:

对于法语语言环境（法国）ONLY，要小心，因为/出现在日期：

echo %DATE%
08/09/2013

对于我们的日志文件的问题，这是我对法语语言环境中唯一建议：

SETLOCAL
set LOGFILE_DATE=%DATE:~6,4%.%DATE:~3,2%.%DATE:~0,2%
set LOGFILE_TIME=%TIME:~0,2%.%TIME:~3,2%
set LOGFILE=log-%LOGFILE_DATE%-%LOGFILE_TIME%.txt
rem log-2014.05.19-22.18.txt
command > %LOGFILE%

Answer 4:

这里是一个区域设置独立的解决方案（复制到一个名为SetDateTimeComponents.cmd文件）：

@echo off
REM This script taken from the following URL:
REM http://www.winnetmag.com/windowsscripting/article/articleid/9177/windowsscripting_9177.html

REM Create the date and time elements.
for /f "tokens=1-7 delims=:/-, " %%i in ('echo exit^|cmd /q /k"prompt $d $t"') do (
   for /f "tokens=2-4 delims=/-,() skip=1" %%a in ('echo.^|date') do (
      set dow=%%i
      set %%a=%%j
      set %%b=%%k
      set %%c=%%l
      set hh=%%m
      set min=%%n
      set ss=%%o
   )
)

REM Let's see the result.
echo %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss%

我把我所有的.CMD脚本放在同一个文件夹（％SCRIPTROOT％）; 需要日期/时间值将调用SetDateTimeComponents.cmd在下面的示例中的任何脚本：

setlocal

@echo Initializing...
set SCRIPTROOT=%~dp0
set ERRLOG=C:\Oopsies.err

:: Log start time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : Start === >> %ERRLOG%

:: Perform some long running action and log errors to ERRLOG.

:: Log end time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : End === >> %ERRLOG%

如示例所示，您可以随时需要更新的日期/时间值调用SetDateTimeComponents.cmd。 隐藏时间在自己的SetDateTimeComponents.cmd文件解析脚本是遮丑细节的好办法，而且，更重要的是，避免错别字。

Answer 5:

这将确保输出是一个2位数的值...你可以通过取消注释诊断节中重新排列输出根据自己的喜好和测试。 请享用！

（我借用其他论坛有很多这...）

:: ------------------ Date and Time Modifier ------------------------

@echo off
setlocal

:: THIS CODE WILL DISPLAY A 2-DIGIT TIMESTAMP FOR USE IN APPENDING FILENAMES

:: CREATE VARIABLE %TIMESTAMP%

for /f "tokens=1-8 delims=.:/-, " %%i in ('echo exit^|cmd /q /k"prompt $D $T"') do (
   for /f "tokens=2-4 skip=1 delims=/-,()" %%a in ('echo.^|date') do (
set dow=%%i
set %%a=%%j
set %%b=%%k
set %%c=%%l
set hh=%%m
set min=%%n
set sec=%%o
set hsec=%%p
)
)

:: ensure that hour is always 2 digits

if %hh%==0 set hh=00
if %hh%==1 set hh=01
if %hh%==2 set hh=02
if %hh%==3 set hh=03
if %hh%==4 set hh=04
if %hh%==5 set hh=05
if %hh%==6 set hh=06
if %hh%==7 set hh=07
if %hh%==8 set hh=08
if %hh%==9 set hh=09


:: --------- TIME STAMP DIAGNOSTICS -------------------------

:: Un-comment these lines to test output

:: echo dayOfWeek = %dow%
:: echo year = %yy%
:: echo month = %mm%
:: echo day = %dd%
:: echo hour = %hh%
:: echo minute = %min%
:: echo second = %sec%
:: echo hundredthsSecond = %hsec%
:: echo.
:: echo Hello! 
:: echo Today is %dow%, %mm%/%dd%. 
:: echo.
:: echo. 
:: echo.
:: echo.
:: pause

:: --------- END TIME STAMP DIAGNOSTICS ----------------------

:: assign timeStamp:
:: Add the date and time parameters as necessary - " yy-mm-dd-dow-min-sec-hsec "

endlocal & set timeStamp=%yy%%mm%%dd%_%hh%-%min%-%sec%
echo %timeStamp%

Answer 6:

我经常用这个，把一切都变成一个单一的复制命令。 下面的副本作为example.txt的和example_YYYYMMDD_HHMMSS.txt当然，你可以修改它以满足您的首选格式。 该报价只必要的，如果有在文件规范的任何空间。 如果你想重新使用完全相同的日期/时间戳记，你需要将其存储在一个变量。

copy "{path}\example.txt" "{path}\_%date:~10,4%%date:~4,2%%date:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.txt"

Answer 7:

由于撕裂的想法%DATE%和%TIME%拆开，捣碎他们重新走到一起，似乎充其量脆弱，这里是一个使用PowerShell的oneliner一种替代方案：

for /f %i in ('powershell -c "get-date -format yyyy-MM-dd--HH-mm-ss"') do @set DATETIME=%i
set LOGFILE=my-script-%DATETIME%.txt

参考了get-date是在这里 ，有两个.NET的风格和UNIX风格的格式选项。

Answer 8:

创建一个与当前日期为文件名的文件（例如：2008-11-08.dat）

echo hello > %date%.dat    

随着当前日期，但没有“ - ”（前20081108.dat）

echo hello > %date:-=%.dat   

Answer 9:

也许这可以帮助：

echo off
@prompt set date=$d$_ set time=$t$h$h$h
echo some log >> %date% %time%.log
exit

要么

echo off
set v=%date%.log
echo some log >> %v%

Answer 10:

我把一个小C程序打印出当前时间戳（语言环境安全，无不良字符...）。 然后，我用FOR命令将结果保存在一个环境变量：

:: Get the timestamp
for /f %%x in ('@timestamp') do set TIMESTAMP=%%x

:: Use it to generate a filename
for /r %%x in (.\processed\*) do move "%%~x" ".\archived\%%~nx-%TIMESTAMP%%%~xx"

这里有一个链接：

https://github.com/HarryPehkonen/dos-timestamp

Answer 11:

你可以简单地检测当前本地格式，并能得到的日期在您的格式，例如：

::for 30.10.2016 dd.MM.yyyy
if %date:~2,1%==. set d=%date:~-4%%date:~3,2%%date:~,2%
::for 10/30/2016 MM/dd/yyyy
if %date:~2,1%==/ set d=%date:~-4%%date:~,2%%date:~3,2%
::for 2016-10-30 yyyy-MM-dd
if %date:~4,1%==- set d=%date:~,4%%date:~5,2%%date:~-2%
::variable %d% have now value: 2016103 (yyyyMMdd)
set t=%time::=%
set t=%t:,=%
::variable %t% have now time without delimiters
cp source.log %d%_%t%.log

Answer 12:

我知道这是旧的文章，但有一个更简单的答案（但也许这只是在新版本的Windows的作品）。 只需使用/ t参数为DATE和TIME DOS命令，只显示日期或时间，而不是提示你设置它，就像这样：

@echo off
echo Starting test batch file > testlog.txt
date /t >> testlog.txt
time /t >> testlog.txt

Answer 13:

1）你可以下载GNU 的coreutils附带GNU日期

2）你可以使用VBScript中 ，这使得日期操作更容易在Windows中：

Set objFS = CreateObject("Scripting.FileSystemObject")
strFolder = "c:\test"
Set objFolder = objFS.GetFolder(strFolder)
current = Now
mth = Month(current)
d = Day(current)
yr = Year(current)
If Len(mth) <2 Then
    mth="0"&mth
End If
If Len(d) < 2 Then
    d = "0"&d
End If
timestamp=yr & "-" & mth &"-"& d
For Each strFile In objFolder.Files
    strFileName = strFile.Name
    If InStr(strFileName,"file_name_here") > 0 Then
        BaseName = objFS.GetBaseName(strFileName)
        Extension = objFS.GetExtensionName(strFileName)
        NewName = BaseName & "-" & timestamp & "." & Extension
        strFile.Name = NewName
    End If
Next

运行该脚本：

c:\test> cscript /nologo myscript.vbs

Answer 14:

我知道这个线程是旧的，但我只是想在这里补充这一点，因为它帮助我很多试图弄清楚这一切了其清洁。 关于这个的好处是，你可以把它放在为始终运行一个批处理文件的循环。 服务器正常运行时间日志什么的。 这就是我用它反正。 我希望这可以帮助别人一天。

@setlocal enableextensions enabledelayedexpansion
@echo off

call :timestamp freshtime freshdate
echo %freshdate% - %freshtime% - Some data >> "%freshdate - Somelog.log"

:timestamp
set hour=%time:~0,2%
if "%hour:~0,1%" == " " set hour=0%hour:~1,1%
set min=%time:~3,2%
if "%min:~0,1%" == " " set min=0%min:~1,1%
set secs=%time:~6,2%
if "%secs:~0,1%" == " " set secs=0%secs:~1,1%
set FreshTime=%hour%:%min%:%secs%

set year=%date:~-4%
set month=%date:~4,2%
if "%month:~0,1%" == " " set month=0%month:~1,1%
set day=%date:~7,2%
if "%day:~0,1%" == " " set day=0%day:~1,1%
set FreshDate=%month%.%day%.%year%

Answer 15:

这与（我）德语区域工作良好，应该可以将其调整到您的需要...

forfiles /p *PATH* /m *filepattern* /c "cmd /c ren @file 
%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%_@file"

Answer 16:

对于部署大zip文件，我用季度小时。 该网页上没有其他人之前就提到这个问题，所以我会在这里把我的小脚本：

set /a "quarter_hours=%time:~0,2%*4 + %time:~3,2% / 15"
set "zip_file=release_%DATE:~-4%.%DATE:~4,2%.%DATE:~7,2%.%quarter_hours%.zip"

它从午夜到凌晨5点不为零垫季度小时还没有，但它仍然使得它让你可以有一个加盖的释放在一天内多次与一些冲突。

希望帮助。

文章来源: Creating a file name as a timestamp in a batch job