如何更换“单引号”，以“双单引号”在XSLT如何更换“单引号”，以“双单引号”在XSLT(How t

如何更换一个XML值，例如：

<name>Linda O'Connel</name>

至：

<name>Linda O''Connel</name>

通过XSLT？

我需要这个，因为我有，因为需要“双单引号”逃脱撇号/单引号的PowerShell命令行和其他平台来传递这个值。

Answer 1:

假设一个XSLT 1.0处理器，则需要使用递归命名模板对于这一点，例如：

<xsl:template name="replace">
    <xsl:param name="text"/>
    <xsl:param name="searchString">'</xsl:param>
    <xsl:param name="replaceString">''</xsl:param>
    <xsl:choose>
        <xsl:when test="contains($text,$searchString)">
            <xsl:value-of select="substring-before($text,$searchString)"/>
            <xsl:value-of select="$replaceString"/>
           <!--  recursive call -->
            <xsl:call-template name="replace">
                <xsl:with-param name="text" select="substring-after($text,$searchString)"/>
                <xsl:with-param name="searchString" select="$searchString"/>
                <xsl:with-param name="replaceString" select="$replaceString"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

调用示例：

<xsl:template match="name">
    <xsl:copy>
        <xsl:call-template name="replace">
            <xsl:with-param name="text" select="."/>
        </xsl:call-template>
    </xsl:copy>
</xsl:template>

Answer 2:

你也可以尝试以下。

  <xsl:variable name="temp">'</xsl:variable>
  <name>
    <xsl:value-of select="concat(substring-before(name,$temp),$temp,$temp,substring-after(name,$temp))"/>
  </name>

文章来源: How to replace “single quote” to “double single quote” in XSLT