Wait for Shell to finish, then format cells - sync

问题:

I have an executable that I call using the shell command:

Shell (ThisWorkbook.Path & \"\\ProcessData.exe\")

The executable does some computations, then exports results back to Excel. I want to be able to change the format of the results AFTER they are exported.

In other words, i need the Shell command first to WAIT until the executable finishes its task, exports the data, and THEN do the next commands to format.

I tried the Shellandwait(), but without much luck.

I had:

Sub Test()

ShellandWait (ThisWorkbook.Path & \"\\ProcessData.exe\")

\'Additional lines to format cells as needed

End Sub

Unfortunately, still, formatting takes place first before the executable finishes.

Just for reference, here was my full code using ShellandWait

\' Start the indicated program and wait for it
\' to finish, hiding while we wait.


Private Declare Function CloseHandle Lib \"kernel32.dll\" (ByVal hObject As Long) As Long
Private Declare Function WaitForSingleObject Lib \"kernel32.dll\" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Declare Function OpenProcess Lib \"kernel32.dll\" (ByVal dwDesiredAccessas As Long, ByVal bInheritHandle As Long, ByVal dwProcId As Long) As Long
Private Const INFINITE = &HFFFF


Private Sub ShellAndWait(ByVal program_name As String)
Dim process_id As Long
Dim process_handle As Long

\' Start the program.
On Error GoTo ShellError
process_id = Shell(program_name)
On Error GoTo 0

\' Wait for the program to finish.
\' Get the process handle.
process_handle = OpenProcess(SYNCHRONIZE, 0, process_id)
If process_handle <> 0 Then
WaitForSingleObject process_handle, INFINITE
CloseHandle process_handle
End If

Exit Sub

ShellError:
MsgBox \"Error starting task \" & _
txtProgram.Text & vbCrLf & _
Err.Description, vbOKOnly Or vbExclamation, _
\"Error\"

End Sub

Sub ProcessData()

  ShellAndWait (ThisWorkbook.Path & \"\\Datacleanup.exe\")

  Range(\"A2\").Select
    Range(Selection, Selection.End(xlToRight)).Select
    Range(Selection, Selection.End(xlDown)).Select
    With Selection
        .HorizontalAlignment = xlLeft
        .VerticalAlignment = xlTop
        .WrapText = True
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
    Selection.Borders(xlDiagonalDown).LineStyle = xlNone
    Selection.Borders(xlDiagonalUp).LineStyle = xlNone
End Sub

回答1:

Try the WshShell object instead of the native Shell function.

Dim wsh As Object
Set wsh = VBA.CreateObject(\"WScript.Shell\")
Dim waitOnReturn As Boolean: waitOnReturn = True
Dim windowStyle As Integer: windowStyle = 1
Dim errorCode As Long

errorCode = wsh.Run(\"notepad.exe\", windowStyle, waitOnReturn)

If errorCode = 0 Then
    MsgBox \"Done! No error to report.\"
Else
    MsgBox \"Program exited with error code \" & errorCode & \".\"
End If    

Though note that:

If bWaitOnReturn is set to false (the default), the Run method returns immediately after starting the program, automatically returning 0 (not to be interpreted as an error code).

So to detect whether the program executed successfully, you need waitOnReturn to be set to True as in my example above. Otherwise it will just return zero no matter what.

For early binding (gives access to Autocompletion), set a reference to \"Windows Script Host Object Model\" (Tools > Reference > set checkmark) and declare like this:

Dim wsh As WshShell 
Set wsh = New WshShell

Now to run your process instead of Notepad... I expect your system will balk at paths containing space characters (...\\My Documents\\..., ...\\Program Files\\..., etc.), so you should enclose the path in \"quotes\":

Dim pth as String
pth = \"\"\"\" & ThisWorkbook.Path & \"\\ProcessData.exe\" & \"\"\"\"
errorCode = wsh.Run(pth , windowStyle, waitOnReturn)

回答2:

What you have will work once you add

Private Const SYNCHRONIZE = &H100000

which your missing. (Meaning 0 is being passed as the access right to OpenProcess which is not valid)

Making Option Explicit the top line of all your modules would have raised an error in this case

回答3:

The WScript.Shell object\'s .Run() method as demonstrated in Jean-François Corbett\'s helpful answer is the right choice if you know that the command you invoke will finish in the expected time frame.

Below is SyncShell(), an alternative that allows you to specify a timeout, inspired by the great ShellAndWait() implementation. (The latter is a bit heavy-handed and sometimes a leaner alternative is preferable.)

\' Windows API function declarations.
Private Declare Function OpenProcess Lib \"kernel32.dll\" (ByVal dwDesiredAccessas As Long, ByVal bInheritHandle As Long, ByVal dwProcId As Long) As Long
Private Declare Function CloseHandle Lib \"kernel32.dll\" (ByVal hObject As Long) As Long
Private Declare Function WaitForSingleObject Lib \"kernel32.dll\" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Declare Function GetExitCodeProcess Lib \"kernel32.dll\" (ByVal hProcess As Long, ByRef lpExitCodeOut As Long) As Integer

\' Synchronously executes the specified command and returns its exit code.
\' Waits indefinitely for the command to finish, unless you pass a 
\' timeout value in seconds for `timeoutInSecs`.
Private Function SyncShell(ByVal cmd As String, _
                           Optional ByVal windowStyle As VbAppWinStyle = vbMinimizedFocus, _
                           Optional ByVal timeoutInSecs As Double = -1) As Long

    Dim pid As Long \' PID (process ID) as returned by Shell().
    Dim h As Long \' Process handle
    Dim sts As Long \' WinAPI return value
    Dim timeoutMs As Long \' WINAPI timeout value
    Dim exitCode As Long

    \' Invoke the command (invariably asynchronously) and store the PID returned.
    \' Note that this invocation may raise an error.
    pid = Shell(cmd, windowStyle)

    \' Translate the PIP into a process *handle* with the
    \' SYNCHRONIZE and PROCESS_QUERY_LIMITED_INFORMATION access rights,
    \' so we can wait for the process to terminate and query its exit code.
    \' &H100000 == SYNCHRONIZE, &H1000 == PROCESS_QUERY_LIMITED_INFORMATION
    h = OpenProcess(&H100000 Or &H1000, 0, pid)
    If h = 0 Then
        Err.Raise vbObjectError + 1024, , _
          \"Failed to obtain process handle for process with ID \" & pid & \".\"
    End If

    \' Now wait for the process to terminate.
    If timeoutInSecs = -1 Then
        timeoutMs = &HFFFF \' INFINITE
    Else
        timeoutMs = timeoutInSecs * 1000
    End If
    sts = WaitForSingleObject(h, timeoutMs)
    If sts <> 0 Then
        Err.Raise vbObjectError + 1025, , _
         \"Waiting for process with ID \" & pid & _
         \" to terminate timed out, or an unexpected error occurred.\"
    End If

    \' Obtain the process\'s exit code.
    sts = GetExitCodeProcess(h, exitCode) \' Return value is a BOOL: 1 for true, 0 for false
    If sts <> 1 Then
        Err.Raise vbObjectError + 1026, , _
          \"Failed to obtain exit code for process ID \" & pid & \".\"
    End If

    CloseHandle h

    \' Return the exit code.
    SyncShell = exitCode

End Function

\' Example
Sub Main()

    Dim cmd As String
    Dim exitCode As Long

    cmd = \"Notepad\"

    \' Synchronously invoke the command and wait
    \' at most 5 seconds for it to terminate.
    exitCode = SyncShell(cmd, vbNormalFocus, 5)

    MsgBox \"\'\" & cmd & \"\' finished with exit code \" & exitCode & \".\", vbInformation


End Sub

回答4:

Shell-and-Wait in VBA _{^{(Compact Edition)}}

Sub ShellAndWait(pathFile As String)
    With CreateObject(\"WScript.Shell\")
        .Run pathFile, 1, True
    End With
End Sub

---

Example Usage:

Sub demo_Wait()
    ShellAndWait (\"notepad.exe\")
    Beep \'this won\'t run until Notepad window is closed
    MsgBox \"Done!\"
End Sub

---

Adapted from (and more options at) Chip Pearson\'s site.

回答5:

I would come at this by using the Timer function. Figure out roughly how long you\'d like the macro to pause while the .exe does its thing, and then change the \'10\' in the commented line to whatever time (in seconds) that you\'d like.

Strt = Timer
Shell (ThisWorkbook.Path & \"\\ProcessData.exe\")  
Do While Timer < Strt + 10     \'This line loops the code for 10 seconds
Loop 
UserForm2.Hide 

\'Additional lines to set formatting

This should do the trick, let me know if not.

Cheers, Ben.