How to create template to match based upon an XSLT

问题:

I'm trying to create a standard-use XSLT that will perform a given task based upon a user-provided XPATH expression as an XSLT parameter.

That is, I need something like this:

<xsl:template match="$paramContainingXPATH">
  <!-- perform the task on the node(s) in the given xpath -->
</xsl:template>

For example, suppose I have some XML:

<xml>
  <nodeA>whatever</nodeA>
  <nodeB>whatever</nodeB>
  <nodeC>whatever</nodeC>
  <nodeD>whatever</nodeD>
  <nodeE>whatever</nodeE>
</xml>

The XSLT needs to transform just a node or nodes matching a provided XPATH expression. So, if the xslt parameter is "/xml/nodeC", it processes nodeC. If the xslt parameter is "*[local-name() = 'nodeC' or local-name() = 'nodeE']", it processes nodeC and nodeE.

This should work for absolutely any XML message. That is, the XSLT cannot have any direct knowledge of the content of the XML. So, it could be a raw XML, or a SOAP Envelope.

I was guessing I might need to grab all the nodes matching the xpath, and then looping over them calling a named template, and using the standard identity template for all other nodes.

All advice is appreciated.

回答1:

You cannot match a template using a parameter - but you can traverse the tree and compare the path of each node with the given path. Here's a simple example:

XSLT 1.0

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:param name="path" select="'/world/America/USA/California'"/>

<xsl:template match="/">
    <root>
        <xsl:apply-templates select="*"/>
    </root>
</xsl:template>

<xsl:template match="*">
    <xsl:variable name="path-to-me">
        <xsl:for-each select="ancestor-or-self::node()">
            <xsl:value-of select="name()" />
            <xsl:if test="position()!=last()">
                <xsl:text>/</xsl:text>
            </xsl:if>
        </xsl:for-each>
    </xsl:variable> 
    <xsl:if test="$path=$path-to-me">
        <xsl:call-template name="action"/>
    </xsl:if>
    <xsl:apply-templates select="*"/>
</xsl:template>

<xsl:template name="action">
    <return>
        <xsl:value-of select="." />
    </return>
</xsl:template>

</xsl:stylesheet>

Applied to a slightly more ambitious test input of:

<world>
    <Europe>
        <Germany>1</Germany>
        <France>2</France>
        <Italy>3</Italy>
    </Europe>
    <America>
        <USA>
            <NewYork>4</NewYork>
            <California>5</California>
        </USA>
        <Canada>6</Canada>
    </America>
</world>

the result will be:

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <return>5</return>
</root>

This could be made more efficient by passing the accumulated path as a parameter of the recursive template, so that each node needs only to add its own name to the chain.

Note:

1. The given path must be absolute;

2. Predicates (including positional predicates) and attributes are not implemented in this. They probably could be, with a bit more effort;

3. Namespaces are ignored (I don't see how you could pass an XPath as a parameter and include namespaces anyway).

If your processor supports an evaluate() extension function, you could forgo the calculated text path and test for intersection instead.

---

Edit:

Here's an example using EXSLT dyn:evaluate() and set:intersection():

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:dyn="http://exslt.org/dynamic"
xmlns:set="http://exslt.org/sets"
extension-element-prefixes="dyn set">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:param name="path" select="'/world/America/USA/California'"/>
<xsl:variable name="path-set" select="dyn:evaluate($path)" />

<xsl:template match="/">
    <root>
        <xsl:apply-templates select="*"/>
    </root>
</xsl:template>

<xsl:template match="*">
    <xsl:if test="set:intersection(. , $path-set)">
        <xsl:call-template name="action"/>
    </xsl:if>
    <xsl:apply-templates select="*"/>
</xsl:template>

<xsl:template name="action">
    <return>
        <xsl:value-of select="." />
    </return>
</xsl:template>

</xsl:stylesheet>

Note that this will also work with with paths like:

/world/America/USA/*[2]

//California

and many others that the text comparison method could not accommodate.

回答2:

If you really need that feature with XSLT 1.0 or 2.0 then I think you should consider writing one stylesheet that takes that string parameter with the XPath expression and then simply generates the code of a second stylesheet where the XPath expression is used as a match pattern and the other needed templates like the identity template are included statically. Dynamic XPath evaluation is only available in XSLT 3.0 or in earlier versions as a proprietary extension mechanism.

回答3:

I'm sending the element name as a param to the XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">
    <xsl:output method="xml"/>
    <xsl:param name="user"/>
    <xsl:template match="/">
        <xsl:call-template name="generic" />
    </xsl:template>
    <xsl:template name="generic">
        <count><xsl:value-of select="count(.//*[local-name()=$user])"/></count>
    </xsl:template>
</xsl:stylesheet>

I hope this could help!