Is it better to specify source files with GLOB or

问题:

CMake offers several ways to specify the source files for a target. One is to use globbing (documentation), for example:

FILE (GLOB dir/*)

Another one is to specify each file individually.

Which way is to prefer? Globbing seems easy, but I heard it has some downsides.

回答1:

Full disclosure: I originally preferred the globbing approach for its simplicity, but over the years I have come to recognise that explicitly listing the files is less error-prone for large, multi-developer projects.

Original answer:

---

The advantages to globbing are:

• It\'s easy to add new files as they are only listed in one place: on disk. Not globbing creates duplication.

• Your CMakeLists.txt file will be shorter. This is a big plus if you have lots of files. Not globbing causes you to lose the CMake logic amongst huge lists of files.

The advantages of using hardcoded file lists are:

• CMake will track the dependencies of a new file on disk correctly - if we use glob then files not globbed first time round when you ran CMake will not get picked up

• You ensure that only files you want are added. Globbing may pick up stray files that you do not want.

In order to work around the first issue, you can simply \"touch\" the CMakeLists.txt that does the glob, either by using the touch command or by writing the file with no changes. This will force cmake to re-run and pick up the new file.

To fix the second problem you can organize your code carefully into directories, which is what you probably do anyway. In the worst case, you can use the list(REMOVE_ITEM) command to clean up the globbed list of files:

file(GLOB to_remove file_to_remove.cpp)
list(REMOVE_ITEM list ${to_remove})

The only real situation where this can bite you is if you are using something like git-bisect to try older versions of your code in the same build directory. In that case, you may have to clean and compile more than necessary to ensure you get the right files in the list. This is such a corner case, and one where you already are on your toes, that it isn\'t really an issue.

回答2:

The best way to specify sourcefiles in CMake is by listing them explicitly.

The creators of CMake themselves advise not to use globbing.

See: http://www.cmake.org/cmake/help/v3.3/command/file.html?highlight=glob#file

(We do not recommend using GLOB to collect a list of source files from your source tree. If no CMakeLists.txt file changes when a source is added or removed then the generated build system cannot know when to ask CMake to regenerate.)

Of course, you might want to know what the downsides are - read on!

---

When Globbing Fails:

The big disadvantage to globbing is that creating/deleting files won\'t automatically update the build-system.

If you are the person adding the files, this may seem an acceptable trade-off, however this causes problems for other people building your code, they update the project from version-control, run build, then contact you, complaining that
\"the build\'s broken\".

To make matters worse, the failure typically gives some linking error which doesn\'t give any hints to the cause of the problem and time is lost troubleshooting it.

In a project I worked on we started off globbing but got so many complaints when new files were added, that it was enough reason to explicitly list files instead of globbing.

This also breaks common git work-flows
(git bisect and switching between feature branches).

So I couldn\'t recommend this, the problems it causes far outweigh the convenience, when someone can\'t build your software because of this, they may loose a lot of time to track down the issue or just give up.

And another note, Just remembering to touch CMakeLists.txt isn\'t always enough, with automated builds that use globbing, I had to run cmake before every build since files might have been added/removed since last building *.

Exceptions to the rule:

There are times where globbing is preferable:

• For setting up a CMakeLists.txt files for existing projects that don\'t use CMake.
  Its a fast way to get all the source referenced (once the build system\'s running - replace globbing with explicit file-lists).
• When CMake isn\'t used as the primary build-system, if for example you\'re using a project who aren\'t using CMake, and you would like to maintain your own build-system for it.
• For any situation where the file list changes so often that it becomes impractical to maintain. In this case it could be useful, but then you have to accept running cmake to generate build-files every time to get a reliable/correct build (which goes against the intention of CMake - the ability to split configuration from building).

---

* Yes, I could have written a code to compare the tree of files on disk before and after an update, but this is not such a nice workaround and something better left up to the build-system.

回答3:

You can safely glob (and probably should) at the cost of an additional file to hold the dependencies.

Add functions like these somewhere:

# Compare the new contents with the existing file, if it exists and is the 
# same we don\'t want to trigger a make by changing its timestamp.
function(update_file path content)
    set(old_content \"\")
    if(EXISTS \"${path}\")
        file(READ \"${path}\" old_content)
    endif()
    if(NOT old_content STREQUAL content)
        file(WRITE \"${path}\" \"${content}\")
    endif()
endfunction(update_file)

# Creates a file called CMakeDeps.cmake next to your CMakeLists.txt with
# the list of dependencies in it - this file should be treated as part of 
# CMakeLists.txt (source controlled, etc.).
function(update_deps_file deps)
    set(deps_file \"CMakeDeps.cmake\")
    # Normalize the list so it\'s the same on every machine
    list(REMOVE_DUPLICATES deps)
    foreach(dep IN LISTS deps)
        file(RELATIVE_PATH rel_dep ${CMAKE_CURRENT_SOURCE_DIR} ${dep})
        list(APPEND rel_deps ${rel_dep})
    endforeach(dep)
    list(SORT rel_deps)
    # Update the deps file
    set(content \"# generated by make process\\nset(sources ${rel_deps})\\n\")
    update_file(${deps_file} \"${content}\")
    # Include the file so it\'s tracked as a generation dependency we don\'t
    # need the content.
    include(${deps_file})
endfunction(update_deps_file)

And then go globbing:

file(GLOB_RECURSE sources LIST_DIRECTORIES false *.h *.cpp)
update_deps_file(\"${sources}\")
add_executable(test ${sources})

You\'re still carting around the explicit dependencies (and triggering all the automated builds!) like before, only it\'s in two files instead of one.

The only change in procedure is after you\'ve created a new file. If you don\'t glob the workflow is to modify CMakeLists.txt from inside Visual Studio and rebuild, if you do glob you run cmake explicitly - or just touch CMakeLists.txt.

回答4:

Specify each file individually!

I use a conventional CMakeLists.txt and a python script to update it. I run the python script manually after adding files.

See my answer here: https://stackoverflow.com/a/48318388/3929196