How to convert groups of XML elements to JSON list

问题:

Is it possible to apply a template that only matchings on the unique attributes?

<node name="region">1</node>
<node name="region">2</node>
<node name="region">3</node>
<node name="place">a</node>
<node name="place">b</node>
<node name="title">test</node>

I want to execute a template once for @name="region" and once for @name="place". Can this be done using XSLT/XPath 1.0?

My ultimate goal is JSON output that looks like this:

"container":{
"region":["1","2","3"],
"place":["a","b"],
"title":"test"
}

回答1:

Muenchian Grouping Method

You can use the Muenchian Method to solve your grouping problem.

This input XML,

<container>
  <node name="region">1</node>
  <node name="region">2</node>
  <node name="region">3</node>
  <node name="place">a</node>
  <node name="place">b</node>
  <node name="title">test</node>
</container>

provided to this XSLT,

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="text"/>

  <xsl:key name="nodes-by-name" match="node" use="@name"/>

  <xsl:template match="container">
    <xsl:text>"container": {&#xa;</xsl:text>
      <xsl:for-each select="node[count(. | key('nodes-by-name', @name)[1]) = 1]">
      <xsl:value-of select="concat('&quot;', @name, '&quot;:')"/>
      <xsl:choose>
        <xsl:when test="count(key('nodes-by-name', @name)) = 1">
          <xsl:value-of select="concat('&quot;', ., '&quot;')"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:text>[</xsl:text>
          <xsl:for-each select="key('nodes-by-name', @name)">
            <xsl:value-of select="concat('&quot;', ., '&quot;')"/>
            <xsl:if test="position() != last()">,</xsl:if>
          </xsl:for-each>
          <xsl:text>]</xsl:text>
        </xsl:otherwise>
      </xsl:choose>
      <xsl:if test="position() != last()">,</xsl:if>
      <xsl:text>&#xa;</xsl:text>
    </xsl:for-each>
    <xsl:text>}</xsl:text>
  </xsl:template>

</xsl:stylesheet>

yields this XML output,

"container": {
"region":["1","2","3"],
"place":["a","b"],
"title":"test"
}

as requested.