sed insert line command OSX

问题:

I'm trying to insert text to the third line in a file using sed, and the syntax I've found on other forums is:

sed -i '' "3i\ text to insert" file

When I use this however, I get an error:

sed: 1: "3i\ text to insert": extra characters after \ at the end of i command

I can't seem to figure out what is causing the problem. I'm using OSX, which is why I have an empty ' ' as my extension.

Thanks!

回答1:

You should put a newline directly after the \:

sed '3i\
text to insert' file

This is actually the behaviour defined by the POSIX specification. The fact that GNU sed allows you to specify the text to be inserted on the same line is an extension.

---

If for some reason you need to use double quotes around the sed command, then you must escape the backslash at the end of the first line:

sed "3i\\
text to insert" file

This is because a double-quoted string is processed first by the shell, and \ followed by a newline is removed:

$ echo "abc\
def"
abcdef

回答2:

On OSX you can use:

sed -i.bak '3i\
text to insert
' file

回答3:

Here's how to do it in one line syntax

sed -i '' -e "2s/^//p; 2s/^.*/text to insert/" file

• duplicate second line: 2s/^//p;

• replace new line with your text: 2s/^.*/text to insert/

回答4:

This works for me

sed -i '' '3i\
text to insert' file 

回答5:

If you want to modify a file of specific file type(.sh in my case) use this command.

sed -i '.sh' '3i\
mymodified text to insert' temp.sh

Make sure you have line break after slash ("\")