AX2009 Loop through all the controls in the form o

问题:

How is it possible to loop through all the controls in a form when a form is initialized?

I have tried the following in the init and run methods, but it does not work:

for( i = 1 ; i <= element.form().design().controlCount() ; i++ )
{
    control = element.form().design().controlNum(i);

    switch ( control.handle() )
    {
        case classnum(FormBuildButtonControl):
            element.initButton(control);
        break;
        case classnum(FormBuildStaticTextControl):
            element.initStaticText(control);
        break;
    }
}

Is there any way of doing this?

回答1:

The code you have works, but it only iterates through the top level of the design. You need to build a recursive function to iterate through the entire set of controls, and place it in the init method before the super():

void init()
{
    int     i;
    void    processControls(FormBuildControl fbc)
    {
        int     j;
        ;

        if (fbc.isContainer())
        {
            for (j = 1; j < fbc.controlCount(); j++)
            {
                //Process container, if you need to
                processControls(fbc.controlNum(j)); 
            }
        }
        else
        {
            //Control is not a container, process it here.                
        }
    }
    ;

    for (i = 1; i <= element.form().design().controlCount(); i++)
    {
        processControls(element.form().design().controlNum(i);
    }

    super();
}

The super() call will automatically initialize all the controls on the form. Once they are initialized, you won't be able to use FormBuildControl type objects to configure the fields, as they will already be consumed onto the form. If you need to modify the field after initialization, you should refer to the field directly (though I'm unsure of how you could get the field name and reference it via X++).

Instead of conditionally initializing the controls, call super() and simply hide the field conditionally, or use security to hide information you don't want certain people to have access to.

EDIT: Since you are dealing with FormBuildControls, which are pre-initialized designs, you should have the super() call after the initial processControls call. I've changed my example to reflect this.

回答2:

Each control can have child controls and parent controls. You're only going over the first level. Here is a sample job that demonstrates how to use recursion over form controls.

static void recurseOverAllFormControls(Args _args)
{
    Form form = new Form(formstr(SalesTable));

    void recurse(Object _parent, int _depth = 1)
    {
        int     i;
        str     name;
        str     caption;
        str     dashes;
        ;

        // Used for making it pretty
        //-->
        i = _depth;
        while (i)
        {
            dashes += '-';
            i--;
        }
        //<--

        // Used for example of how to use data
        //-->
        if (SysTest::hasMethod(_parent, identifierStr(caption)))
            caption = _parent.caption();

        if (SysTest::hasMethod(_parent, identifierStr(name)))
            name = _parent.name();

        info(strfmt("%1%2[%3](%4)", _depth, dashes, name, caption));
        //<--

        // Escape condition!
        if (_parent.controlCount() == 0)
            return;

        // Recursive statement
        for (i=1; i<=_parent.controlCount(); i++)
            recurse(_parent.controlNum(i), _depth+1);
    }
    ;

    recurse(form.design());
}

Edit: Ah somebody beat me to the answer. Hopefully somebody will appreciate my demo job.

回答3:

I have written a simple code in x++ (and also in d365) but it maybe help someone. In this code all form controls will be save in a table called FormControlsTable.

    public void init()
    {
        super();
        FormControlsTable   _formControlTable;
        int                             i;
        FormBuildControl                _control;

        select count(RecId) from _formControlTable;

        if(_formControlTable.RecId == 0)
        {
            for( i = 1 ; i<= element.form().design().controlCount(); i++)
            {
                 _control = element.form().design().controlNum(i);
                 ttsbegin;
                 _formControlTable.ControlId        =   _control.id();
                 _formControlTable.ControlName      =   _control.name();
                 _formControlTable.insert();
                 ttscommit;
                this.TraverseFormControl(_control);
            }
        }
    }

    private void TraverseFormControl(FormBuildControl _control)
    {
        int i;
        FormControlsTable               _formControlTable;
        FormBuildControl                _childControl;

        for( i = 1 ; i<= _control.controlCount(); i++)
        {
            _childControl   =   _control.controlNum(i);
            if(_childControl != null)
            {
                ttsbegin;
                _formControlTable.ControlId     =   _childControl.id();
                _formControlTable.ControlName   =   _childControl.name();
                _formControlTable.insert();
                ttscommit;
                this.TraverseFormControl(_childControl);
            }
        }
    }