XSL寻找到祖先节点的相对位置(xsl finding relative position to a

有一些问题，让孩子的位置division相对于section节点。下面是我的XML文件：

<document>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
</document>

这里是我的XSL：

<xsl:template match="/">
   <xsl:for-each select="//section">
       <div class="section">
           <xsl:text>section </xsl:text>
           <xsl:value-of select="position ()"/>
           <xsl:apply-templates/>
       </div>
    </xsl:for-each>
</xsl:template>

<xsl:template match="division">
    <div class="division">
        <xsl:text>division </xsl:text>
        <xsl:value-of select='count(../preceding-sibling::section)+1' /><xsl:text>.</xsl:text>
        <xsl:value-of select="position ()"/>
        <xsl:apply-templates/>
    </div>
</xsl:template>

我想这样的输出，其中的位置取决于对section ：

section 1
division 1.1 
division 1.2
division 1.3
section 2
division 2.1
division 2.2
division 2.3

而没有这一项：

section 1
division 1.2 
division 1.4
division 1.6
section 2
division 2.2
division 2.4
division 2.6

这似乎是类似../section[position()]或../ancestor/position()但它是错的...谢谢！

相反的position()请尝试使用xsl:number来代替。

例：

XML输入

<document>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
</document>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="text()"/>

    <xsl:template match="section|division">
        <xsl:value-of select="concat(name(),' ')"/>
        <xsl:number level="multiple" count="section|division"/>
        <xsl:text>&#xA;</xsl:text>
        <xsl:apply-templates/>
    </xsl:template>

</xsl:stylesheet>

产量

section 1
division 1.1
division 1.2
division 1.3
section 2
division 2.1
division 2.2
division 2.3

编辑：下面是一个更接近于你在你的XSLT是做什么的另一个例子。（I加入<p>元素虽然换行。

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="text()"/>

    <xsl:template match="section|division">
        <div class="{name()}">
            <p>
                <xsl:value-of select="concat(name(),' ')"/>
                <xsl:number level="multiple" count="section|division"/>             
            </p>
            <xsl:apply-templates/>              
        </div>
    </xsl:template>

</xsl:stylesheet>

产量

<div class="section">
   <p>section 1</p>
   <div class="division">
      <p>division 1.1</p>
   </div>
   <div class="division">
      <p>division 1.2</p>
   </div>
   <div class="division">
      <p>division 1.3</p>
   </div>
</div>
<div class="section">
   <p>section 2</p>
   <div class="division">
      <p>division 2.1</p>
   </div>
   <div class="division">
      <p>division 2.2</p>
   </div>
   <div class="division">
      <p>division 2.3</p>
   </div>
</div>