从其他XML文件XSLT-复制节点，基于匹配节点值(XSLT- Copy node from oth

您好，我有两个不同的XML，我想将它们合并复制从目标XML的一个节点，基于匹配源和目标XML节点值

第一个XML这样的：

<PRODUCTS>
  <PRODUCT>
    <NAME>PRODUCT 1</NAME>
    <MAINCATID>38</MAINCATID>
    <SUBCATID>39</SUBCATID>
  </PRODUCT>
</PRODUCTS>

第二XML是这样的

 <CATEGORIES>
  <MAINCATEGORY>
   <MAINCATID>38</MAINCATID>
   <MAINCATNAME>CATEGORY 1</MAINCATNAME>
  </MAINCATEGORY>
  <MAINCATEGORY>
   <MAINCATID>37</MAINCATID>
   <MAINCATNAME>CATEGORY 2</MAINCATNAME>
  </MAINCATEGORY>
  <SUBCATEGORY>
   <SUBCATID>39</SUBCATID>
   <SUBCATNAME>SUB CATEGORY 1</SUBCATNAME>
  </SUBCATEGORY>
  <SUBCATEGORY>
   <SUBCATID>40</SUBCATID>
   <SUBCATNAME>SUB CATEGORY 2</SUBCATNAME>
  </SUBCATEGORY>
</CATEGORIES>

我的结果XML应该是这样的

<PRODUCTS>
  <PRODUCT>
    <NAME>PRODUCT 1</NAME>
    <MAINCATID>38</MAINCATID>
    <MAINCATNAME>CATEGORY 1</MAINCATNAME>
    <SUBCATID>39</SUBCATID>
    <SUBCATNAME>SUB CATEGORY 1</SUBCATNAME>
  </PRODUCT>
</PRODUCTS>

有很多这样的节点。 我想基于主subcagetory IDS从第二XML获得类别名称。

你能帮这个XSLT转换？

Answer 1:

使用键从另一个文件中查找数据在XSLT 1.0有点尴尬，但它仍然是最好的方法，恕我直言，无论是在性能和代码的清晰度方面。 尝试：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="lookup-source" select="document('file2.xml')" />

<xsl:key name="MAINCATID" match="MAINCATNAME" use="../MAINCATID" />
<xsl:key name="SUBCATID" match="SUBCATNAME" use="../SUBCATID" />

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="MAINCATID | SUBCATID">
    <xsl:copy-of select="."/>
    <xsl:variable name="key-name" select="local-name()"/>
    <xsl:variable name="key-value" select="."/>
    <!-- switch context to the other file for the actual lookup -->
    <xsl:for-each select="$lookup-source">
        <xsl:copy-of select="key($key-name, $key-value)" />
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

我们在这里假设你的“第一个XML”的文件是真实正在处理的一个。

Answer 2:

在XSLT使用多个XML文档的关键是document()下面是展示带来一个快速和肮脏的例子categories.xml在处理对模板products.xml （编辑基于@ michael.hor257k的评论和一些调整）：

<?xml version="1.0" encoding="utf-8"?>    
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">    
<xsl:output indent="yes" method="xml" encoding="UTF-8"/>


<xsl:variable name="categories" select="document('categories.xml')" />


<xsl:template match="MAINCATID">
    <xsl:variable name="maincatid" select="." />
    <MAINCATID><xsl:value-of select="$maincatid" /></MAINCATID>
    <MAINCATNAME><xsl:value-of select="$categories//MAINCATEGORY[MAINCATID=$maincatid]/MAINCATNAME" /></MAINCATNAME>
</xsl:template>

<xsl:template match="SUBCATID">
    <xsl:variable name="subcatid" select="." />
    <SUBCATID><xsl:value-of select="$subcatid" /></SUBCATID>
    <SUBCATNAME><xsl:value-of select="$categories//SUBCATEGORY[SUBCATID=$subcatid]/SUBCATNAME" /></SUBCATNAME>
</xsl:template>


<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
</xsl:template>


<xsl:template match="/">
    <xsl:apply-templates />
</xsl:template>

</xsl:stylesheet>

在这个例子中， <xsl:variable name="categories" select="document('categories.xml') /> 。带来的类别现在其他模板可以通过使用浸入的第二XML $categories 。变量这表现同

<xsl:value-of select="$categories//MAINCATEGORY[MAINCATID=$maincatid]/MAINCATNAME" />

通过这个例子运行你的第一个XML（与保存为一个名为“categories.xml”文件第二个XML）产生以下结果：

<PRODUCTS>
  <PRODUCT>
    <NAME>PRODUCT 1</NAME>
    <MAINCATID>38</MAINCATID>
    <MAINCATNAME>CATEGORY 1</MAINCATNAME>
    <SUBCATID>39</SUBCATID>
    <SUBCATNAME>SUB CATEGORY 1</SUBCATNAME>
  </PRODUCT>
<PRODUCTS>

文章来源: XSLT- Copy node from other XML file, based on matching node value