XSLT：如何反向输出不受内容排序(XSLT: How to reverse output with

我有一个项目的列表：

<item>a</item>
<item>x</item>
<item>c</item>
<item>z</item>

我想作为输出

z
c
x
a

我有一个文件中没有订单信息，我只是想扭转线。在源文件中的最后一行，应在输出第一线。我该如何解决这个问题，XSLT没有通过的项目的内容，这将使错误的结果排序？

Answer 1:

XML代码：

<?xml version="1.0" encoding="ISO-8859-1"?>
<!-- Edited by XMLSpy® -->
<device>
<element>a</element>
<element>x</element>
<element>c</element>
<element>z</element>
</device>

XSLT CODE：

<?xml version="1.0" encoding="ISO-8859-1"?>
<!-- Edited by XMLSpy® -->
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="//device">
<xsl:for-each select="element">

<xsl:sort select="position()" data-type="number" order="descending"/>

<xsl:text> </xsl:text>
<xsl:value-of select="."/>
<xsl:text> </xsl:text>
</xsl:for-each>
</xsl:template>

注意：如果你使用的数据类型=“数字”，并且任何值不是数字，这些非数字值将在数值之前排序。这意味着，如果你使用的顺序=“升序”，非数值出现第一; 如果你使用顺序=“降”，非数值最后出现。

请注意 ，非数字值排序; 他们只是出现在他们所遇到的顺序输出文件内。

同时，你可能会发现有用的阅读这样的：

http://docstore.mik.ua/orelly/xml/xslt/ch06_01.htm

Answer 2:

我会提出了两种解决方案，XSLT：

一，XSLT 1.0递归 注意，该解决方案适用于任何节点集，不仅在当节点是兄弟姐妹的情况 ：

这一转变 ：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/*">
     <xsl:call-template name="reverse">
       <xsl:with-param name="pList" select="*"/>
     </xsl:call-template>
    </xsl:template>

    <xsl:template name="reverse">
      <xsl:param name="pList"/>

      <xsl:if test="$pList">
        <xsl:value-of
         select="concat($pList[last()], '&#xA;')"/>

        <xsl:call-template name="reverse">
          <xsl:with-param name="pList"
            select="$pList[not(position() = last())]"/>
        </xsl:call-template>
      </xsl:if>
    </xsl:template>
</xsl:stylesheet>

当应用这个XML文档上 ：

<t>
    <item>a</item>
    <item>x</item>
    <item>c</item>
    <item>z</item>
</t>

产生通缉的结果 ：

z
c
x
a

II。 XSLT 2.0溶液 ：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output method="text"/>

  <xsl:template match="/*">
   <xsl:value-of select="reverse(*)/string(.)"
    separator="&#xA;"/>
  </xsl:template>
</xsl:stylesheet>

当在相同的XML文档被应用于这种转变 中， 相同的正确的结果被产生。

Answer 3:

不知道完整的XML看起来像什么，所以我包裹在一个<doc>元素，使其形成良好：

<doc>
<item>a</item>
<item>x</item>
<item>c</item>
<item>z</item>
</doc>

运行针对这个样式表，例如XML：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
   version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" encoding="UTF-8" omit-xml-declaration="yes"/>

    <xsl:template match="/">
        <xsl:call-template name="reverse">
            <xsl:with-param name="item" select="doc/item[position()=last()]" />
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="reverse">
        <xsl:param name="item" />

        <xsl:value-of select="$item" />
        <!--Adds a line feed-->
        <xsl:text>&#10;</xsl:text>

        <!--Move on to the next item, if we aren't at the first-->
        <xsl:if test="$item/preceding-sibling::item">
            <xsl:call-template name="reverse">
                <xsl:with-param name="item" select="$item/preceding-sibling::item[1]" />
            </xsl:call-template>
        </xsl:if>

    </xsl:template>

</xsl:stylesheet>

生产所需的输出：

z
c
x
a

您可能需要调整的XPath，以符合您实际的XML。

Answer 4:

考虑这个XML输入：

<?xml version="1.0" encoding="utf-8" ?>
<items>
  <item>a</item>
  <item>x</item>
  <item>c</item>
  <item>z</item>
</items>

在XSLT：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="text" />

    <xsl:template match="/items[1]">

      <xsl:variable name="items-list" select="." />
      <xsl:variable name="items-count" select="count($items-list/*)" />

      <xsl:for-each select="item">
        <xsl:variable name="index" select="$items-count+1  - position()"/>
        <xsl:value-of select="$items-list/item[$index]"/>
        <xsl:value-of select="'&#x0a;'"/>
      </xsl:for-each>

    </xsl:template>
</xsl:stylesheet>

而结果是：