如何在一个元素结合两种元素？(How combine two element in one elem

我想合并是相同的，例如要素：

<Root>
    <row>
        <WID>10</WID>
        <word>Bob</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
    <row>
        <WID>5941</WID>
        <word>Jany</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
</Root>

而结果是：

<span>Bob Jany</span>

我写这篇文章，但它是错误的：

<xsl:choose> 
<xsl:when test = "Ah[text()]=Ah[text()]"> 
         <span>
             <xsl:value-of select="./word"/>
         </span>
</xsl:when> 
</xsl:choose>

Answer 1:

一个XSLT 1.0溶液使用Muenchian分组的方法：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kRowByAh" match="row" use="Ah" />
 <xsl:template match="row[generate-id()=generate-id(key('kRowByAh', Ah)[1])]">
  <span>
    <xsl:value-of select="word"/>
    <xsl:for-each select="key('kRowByAh', Ah)[position() > 1]">
     <xsl:value-of select="concat(' ', word)"/>
    </xsl:for-each>
  </span>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

当这种转化应用所提供的XML文档：

<Root>
    <row>
        <WID>10</WID>
        <word>Bob</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
    <row>
        <WID>5941</WID>
        <word>Jany</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
</Root>

在想，正确的结果产生：

<span>Bob Jany</span>

Answer 2:

使用分组，使用XSLT 2.0（由撒克逊9或AltovaXML或XmlPrime运行）它是作为容易

<xsl:stylesheet version="2.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output indent="yes"/>

<xsl:template match="Root">
  <xsl:copy>
    <xsl:for-each-group select="row" group-by="Ah">
      <span><xsl:value-of select="current-group()/word"/></span>
    </xsl:for-each-group>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

当我申请上文撒克逊9.5 HE样式表上的输入采样

<Root>
    <row>
        <WID>10</WID>
        <word>Bob</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
    <row>
        <WID>5941</WID>
        <word>Jany</word>
        <SID>2</SID>
        <Ah>1</Ah>
    </row>
</Root>

我得到的结果

<Root>
   <span>Bob Jany</span>
</Root>

文章来源: How combine two element in one element?