互联网浏览器COM自动化：转换数字错误代码串(Internet Explorer COM autom

我写这封信从通过一个Perl 5驱动程序Internet Explorer的一些代码Win32::OLE ，和我在寻找各种方法来转换是通过事件（如发送回Perl程序数字状态/错误代码NavigateError ）成稍微更人类可读的形式。

是否有某种库函数是转换即0x800C0005L或-2146697211到"INET_E_RESOURCE_NOT_FOUND"或一些更可读？

我曾尝试Win32::FormatMessage()但似乎只适用于非应用程序特定的错误条件下工作。

更新：这里是澄清一些示例代码。下面的一些测试输出被示出。

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

use Time::HiRes qw(sleep time);
use Win32::OLE qw(EVENTS);
use Win32::OLE::Variant;

$|++;

sub ie_browse {
    my $url = shift;
    my $ie = Win32::OLE->new('InternetExplorer.Application') or die;
    Win32::OLE->WithEvents($ie, 
        sub {
            my ($obj, $event, @args) = @_;
            given ($event) {
                when ('NavigateComplete2') {
                    push @extra, 
                      'url='.($args[1]->As(VT_BSTR));
                    say "$event: @extra";
                }
                when ('NavigateError') {
                    push @extra, 
                      'url='.($args[1]->As(VT_BSTR)),
                      'statuscode='.($args[3]->As(VT_I4));
                    say "$event: @extra";
                }
            }
        }, 'DWebBrowserEvents2');
    Win32::OLE->SpinMessageLoop;
    $ie->{visible} = 1;
    Win32::OLE->SpinMessageLoop;
    $ie->Navigate2($url);
    Win32::OLE->SpinMessageLoop;
    while(1) {
        Win32::OLE->SpinMessageLoop;
        sleep(0.1);
    }
}

ie_browse $ARGV[0];

下面是一些输出两个取尝试。获取堆栈溢出页面是成功的，当然。

C:\Documents and Settings\nobody\Desktop>perl ie.pl http://stackoverflow.com/
NavigateComplete2: url=http://stackoverflow.com/
Terminating on signal SIGINT(2)

但example.invalid不存在。

C:\Documents and Settings\nobody\Desktop>perl ie.pl http://example.invalid/
NavigateError: url=http://example.invalid/ statuscode=-2146697211
NavigateComplete2: url=http://example.invalid/
Terminating on signal SIGINT(2)

我感兴趣的转向已传递回一些有用的数值（-2146697211）。这不是一个OLE错误本身，而是通过Internet浏览器COM对象发出信号的错误条件。

更新：在您的评论来看，我相信你正在寻找微软的文档NavigateError事件：

INET_E_INVALID_URL (0x800C0002L or -2146697214)
INET_E_NO_SESSION (0x800C0003L or -2146697213)
INET_E_CANNOT_CONNECT (0x800C0004L or -2146697212)
...

你可以通过分析该列表创建模块：

package Win32::WebBrowserControl::ErrorMnemonics;

use strict;
use warnings;

my %lookup;

sub import {
    my $class = shift;
    while ( my $x = <DATA> ) {
        my ($mnemonic, $code) = ( $x =~ m{
            ^(INET_E_[A-Z_]+)
            [ ]
            \(
                0x[[:xdigit:]]+L
                [ ] or [ ]
                (-[[:digit:]]+)
            \)
        }x ) or next;
        $lookup{$code} = $mnemonic;
    }
}

sub lookup {
    my $self = shift;
    return $lookup{shift()};
}

1;
__DATA__
INET_E_INVALID_URL (0x800C0002L or -2146697214)
INET_E_NO_SESSION (0x800C0003L or -2146697213)
INET_E_CANNOT_CONNECT (0x800C0004L or -2146697212)
INET_E_RESOURCE_NOT_FOUND (0x800C0005L or -2146697211)
INET_E_OBJECT_NOT_FOUND (0x800C0006L or -2146697210)
INET_E_DATA_NOT_AVAILABLE (0x800C0007L or -2146697209)
INET_E_DOWNLOAD_FAILURE (0x800C0008L or -2146697208)
INET_E_AUTHENTICATION_REQUIRED (0x800C0009L or -2146697207)
INET_E_NO_VALID_MEDIA (0x800C000AL or -2146697206)
INET_E_CONNECTION_TIMEOUT (0x800C000BL or -2146697205)
INET_E_INVALID_REQUEST (0x800C000CL or -2146697204)
INET_E_UNKNOWN_PROTOCOL (0x800C000DL or -2146697203)
INET_E_SECURITY_PROBLEM (0x800C000EL or -2146697202)
INET_E_CANNOT_LOAD_DATA (0x800C000FL or -2146697201)
INET_E_CANNOT_INSTANTIATE_OBJECT (0x800C0010L or -2146697200)
INET_E_REDIRECT_FAILED (0x800C0014L or -2146697196)
INET_E_REDIRECT_TO_DIR (0x800C0015L or -2146697195)
INET_E_CANNOT_LOCK_REQUEST (0x800C0016L or -2146697194)
INET_E_USE_EXTEND_BINDING (0x800C0017L or -2146697193)
INET_E_TERMINATED_BIND (0x800C0018L or -2146697192)
INET_E_INVALID_CERTIFICATE (0x800C0019L or -2146697191)
INET_E_CODE_DOWNLOAD_DECLINED (0x800C0100L or -2146696960)
INET_E_RESULT_DISPATCHED (0x800C0200L or -2146696704)
INET_E_CANNOT_REPLACE_SFP_FILE (0x800C0300L or -2146696448)
INET_E_CODE_INSTALL_BLOCKED_BY_HASH_POLICY (0x800C0500L or -2146695936)
INET_E_CODE_INSTALL_SUPPRESSED (0x800C0400L or -2146696192)

对于OLE有关的错误，看到Win32::OLE文档：

Win32::OLE->LastError()

该LastError()类方法返回的最后记录的OLE错误。这就好比一个双重价值$! 变量：在数值上下文它返回错误数和字符串上下文它返回错误消息。错误号是签名的HRESULT值。请使用HRESULT(ERROR)功能，以无符号十六进制常量转换为有符号HRESULT 。