How do I sum the values in an array of maps in jq?

问题:

Given a JSON stream of the following form:

{ "a": 10, "b": 11 } { "a": 20, "b": 21 } { "a": 30, "b": 31 }

I would like to sum the values in each of the objects and output a single object, namely:

{ "a": 60, "b": 63 }

I'm guessing this will probably require flattening the above list of objects into a an array of [name, value] pairs and then summing the values using reduce but the documentation of the syntax for using reduce is woeful.

回答1:

Unless your jq has inputs, you will have to slurp the objects up using the -s flag. Then you'll have to do a fair amount of manipulation:

1. Each of the objects needs to be mapped out to key/value pairs
2. Flatten the pairs to a single array
3. Group up the pairs by key
4. Map out each group accumulating the values to a single key/value pair
5. Map the pairs back to an object

map(to_entries)
    | add
    | group_by(.key)
    | map({
          key: .[0].key,
          value: map(.value) | add
      })
    | from_entries

---

With jq 1.5, this could be greatly improved: You can do away with slurping and just read the inputs directly.

$ jq -n '
reduce (inputs | to_entries[]) as {$key,$value} ({}; .[$key] += $value)
' input.json

Since we're simply accumulating all the values in each of the objects, it'll be easier to just run through the key/value pairs of all the inputs, and add them all up.

回答2:

Another approach, which illustrates the power of jq quite nicely, is to use a filter named "sum" defined as follows:

def sum(f): reduce .[] as $row (0; . + ($row|f) );

To solve the particular problem at hand, one could then use the -s (--slurp) option as mentioned above, together with the expression:

{"a": sum(.a), "b": sum(.b) }  # (2)

The expression labeled (2) only computes the two specified sums, but it is easy to generalize, e.g. as follows:

# Produce an object with the same keys as the first object in the 
# input array, but with values equal to the sum of the corresponding
# values in all the objects.
def sumByKey:
  . as $in
  | reduce (.[0] | keys)[] as $key
    ( {}; . + {($key): ($in | sum(.[$key]))})
;