在XSL动态多个过滤器(dynamic multiple filters in xsl)

<list>
<field ows_ID="1081" Program="106;#Virginia" ProgramCategory="United States"/>
<field ows_ID="1082" Program="110;#NewYork" ProgramCategory="United States" />
<field ows_ID="1083" Program="106;#Texas;#112;#Virginia;#118;#Mass" ProgramCategory="United States" />
<field ows_ID="1084" Program="111;#Florida;#180;#Texas" ProgramCategory="United States" />
<field ows_ID="1085" Program="" ProgramCategory="Australia" />
<field ows_ID="1086" Program="122;#Sydney;#Melbourne" ProgramCategory="Australia" />
<field ows_ID="1087" Program="121;#Melbourne" ProgramCategory="Australia" />
<field ows_ID="1088" Program="118;#Mass" ProgramCategory="United States" />
<field ows_ID="1088" Program="123;#Brisbane" ProgramCategory="Australia" />


</list>

我有一些XML外面我需要找到计数，其中ProgramCategory等于某些国家和方案应该不等于一些国家对此我动态地从一些其他的XML得到。从其他XML我正在与各相关ProgramCategory计划，然后我需要过滤上面的XML与条件

foreach(list/field[@ProgramCategory=$Country][not(contain(@Program,$State1][not(contain(@Program,$State2][not(contain(@Program,$State3][not(contain(@Program,$State4])

问题是，我可以得到N无。国家的这些，我对其他XML的环打通。

所以说，如果我从各国与美国相关的另一个XML得到的都是弗吉尼亚州，得克萨斯州和佛罗里达州则美国数为2，如果我说美国与澳大利亚相关联的墨尔本，悉尼和布里斯班再算上为1。我使用XSL 1.0。

问的好，+ 1。

我认为这是不计算结果为通缉计数一个XPath 1.0表达式 。

下面是一个XSLT 1.0溶液 ：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pFilteredStates">
  <state>Virginia</state>
  <state>Texas</state>
  <state>Florida</state>
 </xsl:param>

 <xsl:param name="pCountry" select="'United States'"/>

 <xsl:variable name="vFiltered" select=
  "document('')/*/xsl:param[@name='pFilteredStates']/*
  "/>

 <xsl:template match="/">
  <xsl:variable name="vCount">
    <xsl:apply-templates select="*"/>
  </xsl:variable>

  <xsl:value-of select="string-length($vCount)"/>
 </xsl:template>

 <xsl:template match="field">
  <xsl:if test=
  "@ProgramCategory = $pCountry
  and
   not($vFiltered[contains(current()/@Program,
                           .
                           )
                 ]
      )
  ">
   <xsl:text>1</xsl:text>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当这种转化应用所提供的XML文档 ：

<list>
    <field ows_ID="1081" Program="106;#Virginia" ProgramCategory="United States"/>
    <field ows_ID="1082" Program="110;#NewYork" ProgramCategory="United States" />
    <field ows_ID="1083" Program="106;#Texas;#112;#Virginia;#118;#Mass" ProgramCategory="United States" />
    <field ows_ID="1084" Program="111;#Florida;#180;#Texas" ProgramCategory="United States" />
    <field ows_ID="1085" Program="" ProgramCategory="Australia" />
    <field ows_ID="1086" Program="122;#Sydney;#Melbourne" ProgramCategory="Australia" />
    <field ows_ID="1087" Program="121;#Melbourne" ProgramCategory="Australia" />
    <field ows_ID="1088" Program="118;#Mass" ProgramCategory="United States" />
    <field ows_ID="1088" Program="123;#Brisbane" ProgramCategory="Australia" />
</list>

在想，正确的结果产生 ：

II。 XPath 2.0中的解决方案 ：

以下单的XPath 2.0表达式：

count(
   for $f in /*/*,
       $w in $f
             [@ProgramCategory eq $pCountry
            and
              not($pFilteredStates/*
                           [contains($f/@Program, .)]
                  )
             ]
     return $w
      )

当在相同的XML文档（以上），产生想要的，正确的结果进行评价：