获得德尔福IE版本 - 注册表解决方案不工作(Get IE version on Delphi -

我用这个功能来获得IE版本。但在某些情况下，它无法找到此键，返回0是否有不依赖于注册表另一种方式？

function GetIEVersion: string;
var
   Reg: TRegistry;
   S: string;
   i : integer;
begin
   Reg := TRegistry.Create;
   with Reg do
      begin
         RootKey := HKEY_LOCAL_MACHINE;
         OpenKey('Software\Microsoft\Internet Explorer', False);
         if ValueExists('Version') then
          begin
            S := ReadString('Version');
          end
         else
         begin
            S := '0';
         CloseKey;
        end;
         Free;
      end;
    result := s;
end;

Answer 1:

TRegistry.OpenKey()使用TRegistry.Access财产知道打开键时哪些权限要求。默认情况下， TRegistry.Access设置为KEY_ALL_ACCESS ，这仅限于adminstrators。使用TRegistry.OpenKeyReadOnly()来代替。此外，良好的措施，你可以摆脱的ValueExists()检查，如ReadString()如果该值不存在，返回一个空字符串。

尝试这个：

function GetIEVersion: string; 
var 
  Reg: TRegistry; 
begin 
  Result := '';
  Reg := TRegistry.Create; 
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE; 
    if Reg.OpenKeyReadOnly('Software\Microsoft\Internet Explorer') then
    try
      Result := Reg.ReadString('Version'); 
    finally
      Reg.CloseKey; 
    end; 
  finally
    Reg.Free; 
  end;
  if Result = '' then
    Result := '0'; 
end;

Answer 2:

您可以使用获取文件版本信息的方法。首先，我们会得到iexplore.exe路径。

function GetIEPath: string;
var
  Reg: TRegistry;
  Len: Integer;
begin
  Result := '';
  Reg := TRegistry.Create;

  with Reg do
  begin
    try
      RootKey := HKEY_CLASSES_ROOT;
      OpenKeyReadOnly('CLSID\{0002DF01-0000-0000-C000-000000000046}\LocalServer32');
      try
        Result := ReadString('');
      finally
        CloseKey;
        Len := Length(Result);

        if Len >= 2 then
        begin
          if(Result[Len] = '"') then
            Delete(Result, Len, 1);

          if(Result[1] = '"') then
            Delete(Result, 1, 1);
        end
        else
        begin
          Result := '';
        end;
      end;
    finally
      Free;
    end;
  end;
end;

{0002DF01-0000-0000-C000-000000000046}是Internet Explorer的CLSID。默认键值LocalServer32是iexplore.exe路径。

然后，我们使用一些API调用，由西蒙Grossenbacher作为证明，在这个环节，获取文件版本信息。修改他的功能，我们得到这样的：

function GetIEVersion: string;
var
  IEPath: string;
  VerInfoSize: DWORD;
  VerInfo: Pointer;
  VerValueSize: DWORD;
  VerValue: PVSFixedFileInfo;
  Dummy: DWORD;
begin
  Result := '0';

  IEPath := GetIEPath;
  if IEPath = '' then
    Exit;

  VerInfoSize := GetFileVersionInfoSize(PChar(IEPath), Dummy);
  if VerInfoSize = 0 then
    Exit;

  GetMem(VerInfo, VerInfoSize);
  GetFileVersionInfo(PChar(IEPath), 0, VerInfoSize, VerInfo);
  VerQueryValue(VerInfo, '\', Pointer(VerValue), VerValueSize);

  with VerValue^ do
  begin
    Result := IntToStr(dwFileVersionMS shr 16);
    Result := Result + '.' + IntToStr(dwFileVersionMS and $FFFF);
    Result := Result + '.' + IntToStr(dwFileVersionLS shr 16);
    Result := Result + '.' + IntToStr(dwFileVersionLS and $FFFF);
  end;
  FreeMem(VerInfo, VerInfoSize);
end;

然后，你只需要使用，例如，这样的：