XSLT 1.0 - 串联知子节点，按未知的父(XSLT 1.0 - Concatenate kn

我想改造

    <entry>
        <parent1>
            <object_id>1580</object_id>
        </parent1>
        <parent1>
            <object_id>1586</object_id>
        </parent1>
        <parent2>
            <object_id>1582</object_id>
        </parent2>
        <parent2>
            <object_id>1592</object_id>
        </parent2>
    </entry>

成

    <entry>
        <parent1>1580-1586</parent1>
        <parent2>1582-1592</parent2>
    </entry>

顶级条目名称是未知的。母公司名称是未知的，父节点的具有相同名称的数量可以改变。子节点被称为“OBJECT_ID”。

所以，我想组未知的父母以抽象的方式，并连接子节点的值，通过分隔“ - ”。

合并XML节点使用XSLT接近回答这个问题，如同集团/合并在XML / XSLT同一节点的孩子的，但他们并不完全符合我的需要。

到目前为止，我有：

    <xsl:key name="groupName" match="*[object_id]" use="."/>
    <xsl:template match="*[generate-id(.) = generate-id(key('groupName', .))]">
        <xsl:copy>
        <xsl:call-template name="join"> 
                <xsl:with-param name="list" select="object_id" /> 
                <xsl:with-param name="separator" select="'-'" />                                             
        </xsl:call-template>
        </xsl:copy> 
    </xsl:template>

    <xsl:template name="join"> 
    <xsl:param name="list" /> 
    <xsl:param name="separator"/>     
    <xsl:for-each select="$list"> 
      <xsl:value-of select="." /> 
      <xsl:if test="position() != last()"> 
        <xsl:value-of select="$separator" />         
      </xsl:if> 
    </xsl:for-each> 
    </xsl:template>

提前致谢！

Answer 1:

这一转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kObjByValAndParent" match="object_id"
  use="name(..)"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/*/*"/>

 <xsl:template priority="2" match=
 "/*/*[generate-id(object_id)
      =
       generate-id(key('kObjByValAndParent',name())[1])
      ]
 ">
   <xsl:copy>
     <xsl:value-of select=
     "concat(object_id, ' - ',
             key('kObjByValAndParent',name())[last()]
            )
     "/>
   </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

当施加在提供的XML文档：

<entry>
    <parent1>
        <object_id>1580</object_id>
    </parent1>
    <parent1>
        <object_id>1586</object_id>
    </parent1>
    <parent2>
        <object_id>1582</object_id>
    </parent2>
    <parent2>
        <object_id>1592</object_id>
    </parent2>
</entry>

产生想要的，正确的结果：

<entry>
   <parent1>1580 - 1586</parent1>
   <parent2>1582 - 1592</parent2>
</entry>

说明：

正确使用和压倒一切的身份统治 。
正确使用的Muenchian分组的方法 。

II。 如果所有的值必须被连接在一起，使用此略作修改的解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kObjByValAndParent" match="object_id"
  use="name(..)"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/*/*"/>

 <xsl:template priority="2" match=
 "/*/*[generate-id(object_id)
      =
       generate-id(key('kObjByValAndParent',name())[1])
      ]
 ">
   <xsl:copy>
     <xsl:for-each select="key('kObjByValAndParent',name())">
      <xsl:if test="not(position()=1)"> - </xsl:if>
      <xsl:value-of select="."/>
     </xsl:for-each>
   </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

Answer 2:

这里有一个稍微不同的解决方案，开发之前，我注意到Dimitre的帖子。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*" />  

<xsl:key name="kParents" match="*[object_id]" use="local-name()" />

<xsl:template match="@*|node()">
 <xsl:copy>
   <xsl:apply-templates select="@*|node()" />
 </xsl:copy>
</xsl:template>

<xsl:template match="*[*/object_id]">
  <xsl:variable name="grandparent-id" select="generate-id()" /> 
 <xsl:copy>
   <xsl:apply-templates select="@* | node()[not(object_id)] |
    *[generate-id()=
      generate-id(
        key('kParents',local-name())[generate-id(..)=$grandparent-id][1])]"
      mode="group-head" />
 </xsl:copy>
</xsl:template>

<xsl:template match="*[object_id]" mode="group-head">
 <xsl:variable name="grandparent-id" select="generate-id(..)" /> 
 <xsl:copy>
   <xsl:apply-templates select="@* | node()[not(self::object_id)]" />
   <xsl:for-each select="key('kParents',local-name())[generate-id(..)=$grandparent-id]/object_id">
     <xsl:value-of select="." />
     <xsl:if test="position() != last()"> - </xsl:if>  
   </xsl:for-each>  
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>