ASP格式日期(ASP formatting date)

你好，我试图让ASP的日期以特定的格式（年月日）现身。 这是我到目前为止，但没有运气尝试。 任何帮助表示赞赏。 谢谢

<tr>
    <td><b>Call Date</b></td>
    <% for i = -6 to 0 %>
        <td align=center>
            <a href="20a.asp?cldate=<% response.write(DateTime.Date()+i.ToString("yyyyMMdd")) %>" target="_blank">X</a>
        </td>
    <% Next %>
</tr>

Answer 1:

您可以使用以下功能：

Year(Now) '' Year in 4 digits
Month(Now) '' Month without leading zero
Day(Now) '' Day of the month without leading zero

DateAdd("d", <numofdays>, Now) '' add a number of days to your date

了解更多关于这些（和其他日期函数）的功能在这里 。

如果您需要添加一个前导零：

function addLeadingZero(value)
    addLeadingZero = value
    if value < 10 then
        addLeadingZero = "0" & value
    end if
end function

你的情况的一个例子是：

Dim today, myDate

today = Now

for i = -6 to 0
    myDate = DateAdd("d", i, today)

    response.write "<a href=""20a.asp?cldate=" & Year(myDate) & addLeadingZero(Month(myDate)) & addLeadingZero(Day(myDate)) & """ target=""_blank"">X</a>"
next

Answer 2:

对不起挖这件事，但它可能是帮助一些人。 而不是“如果<10，则添加前导零”的逻辑，我经常用正确的命令，并随时添加一个前导零...

response.write "<a href=""20a.asp?cldate=" & Year(myDate) & Right("0" & Month(myDate), 2) & right("0" & Day(myDate), 2) & """ target=""_blank"">X</a>"

..This方式，你并不需要一个单独的功能，它可以在同一行中完成。 我不能为它的效率说话，但它似乎是合乎逻辑。

Answer 3:

ASP得到从数据库，一个常见的错误的OS不是日期，但它是通过使用解决：

<%
' Date dd/mm/yyyy
Session.lcid=2057 '= UK English
%>

我希望它能帮助人。

Answer 4:

你可以试试。 100％测试！

   <% 
     mm = Month(now())
     dd = Day(now())
     yy = Year(now())
     IF len(mm) = 1 THEN
       mm = "0" & mm
     END IF
     IF len(dd) = 1 THEN
       dd = "0" & dd
     END IF
     response.write(yy & "/" & mm & "/" & dd) 
  %>

Answer 5:

 <%= DatePart("yyyy", Now) & "/" & DatePart("m", Now) & "/" & DatePart("d", Now) %>

另请参阅

http://www.w3schools.com/vbscript/vbscript_ref_functions.asp

http://www.mikesdotnetting.com/Article/22/Date-formatting-in-VBScript

谢谢

迪普

Answer 6:

Mid(date(), 7,4) & "-" & Mid(date(), 4,2) & "-" & Left(date(), 2)

文章来源: ASP formatting date