Split a string with a delimiter and store each val

问题:

I would like to split an XML string with a delimiter(_) and would like to store each value in a variable using XSL. I am using xsl1.0

My xml file

<file>
   <filename>ACT_0815_ERS_V7</filename>
</file>

and XSL

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="filename/text()" name="tokenize">
        <xsl:param name="text" select="."/>
        <xsl:param name="separator" select="'_'"/>
        <xsl:choose>
            <xsl:when test="not(contains($text, $separator))">
                <item>
                    <xsl:value-of select="normalize-space($text)"/>
                </item>
            </xsl:when>
            <xsl:otherwise>

                    <aa><xsl:value-of select="normalize-space(substring-before($text[0], $separator))"/></aa>
                     <bb><xsl:value-of select="normalize-space(substring-before($text[1], $separator))"/></bb>
                     <cc><xsl:value-of select="normalize-space(substring-before($text[2], $separator))"/></cc>
                     <dd><xsl:value-of select="normalize-space(substring-before($text[3], $separator))"/></dd>

                <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="substring-after($text, $separator)"/>

                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

Bugged xml output for the above xsl

<?xml version="1.0" encoding="UTF-8"?>
<file>
   <filename><aa/><bb>ACT</bb><cc/><dd/><aa/><bb>0815</bb><cc/><dd/><aa/><bb>ERS</bb><cc/><dd/><item>V7</item></filename>
</file>

Want to have the output as follows

<?xml version="1.0" encoding="UTF-8"?>
<file>
  <aa>ACT</aa>
  <bb>0815</bb>
  <cc>ERS</cc>
  <dd>V7</dd>
</file>

回答1:

The general idea with recursion is to deal with one token at a time.

The following stylesheet:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="filename" name="tokenize">
    <xsl:param name="text" select="."/>
    <xsl:param name="separator" select="'_'"/>
    <xsl:param name="token-names" select="'aa,bb,cc,dd,ee,ff'"/>
    <xsl:element name="{substring-before($token-names, ',')}">
        <xsl:value-of select="substring-before(concat($text, $separator), $separator)" />
    </xsl:element>
    <xsl:if test="contains($text, $separator)">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="substring-after($text, $separator)"/>
            <xsl:with-param name="token-names" select="substring-after($token-names, ',')"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

will output the requested result. Note however, that the token names are derived from a hard-coded string, which in this example is limited to a maximum of 6 tokens.

---

If the stated limit is a problem, you could do:

<xsl:template match="filename" name="tokenize">
    <xsl:param name="text" select="."/>
    <xsl:param name="separator" select="'_'"/>
    <xsl:param name="i" select="25"/>
    <xsl:variable name="char">
        <xsl:number value="$i" format="a"/>
    </xsl:variable>
    <xsl:element name="{concat($char, $char)}">
        <xsl:value-of select="substring-before(concat($text, $separator), $separator)" />
    </xsl:element>
    <xsl:if test="contains($text, $separator)">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="substring-after($text, $separator)"/>
            <xsl:with-param name="i" select="$i + 1"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

This will produce <aaaa> as the token following <zz> and so on.