How do you write a fun that's recursive in Erl

问题:

I'm trying to write a recursive fun in an Erlang shell, but I keep getting an unbound variable exception:

1> Foo = fun(X) -> Foo(X) end.
* 1: variable 'Foo' is unbound

This probably goes without saying, but I'm not trying to create an infinite loop! This is just a simple example of the error I'm getting.

回答1:

You can do it with a little argument trick:

1> Foo = fun(F, X) -> F(F, X) end.
#Fun<erl_eval.12.113037538>
2> Foo(Foo, a).
<...infinite loop!>

The trick here is to send in the function as an argument to itself to allow recursion.

Alternative way to make it in one shoot:

1> Foo = fun(X) -> Fun = fun(F,Y) -> F(F,Y) end, Fun(Fun,X) end.
#Fun<erl_eval.6.13229925>
2> Foo(a).

For example:

1> Foo = fun(Max) ->
1>     Fun = fun(F, X) when X > Max -> [];
1>              (F, X) -> [X | F(F, X+1)]
1>           end,
1>     Fun(Fun, 0)
1> end.
#Fun<erl_eval.6.13229925>
2> Foo(10).
[0,1,2,3,4,5,6,7,8,9,10]

Since OTP 17.0 there are named funs which makes the task a lot easier:

1> Perms = fun F([]) -> [[]]; F(L) -> [[H|T] || H <- L, T <- F(L--[H])] end.    
#Fun<erl_eval.30.54118792>
2> Perms([a,b,c]).
[[a,b,c],[a,c,b],[b,a,c],[b,c,a],[c,a,b],[c,b,a]]

回答2:

After Erlang 17, you can also use the "Funs with names" variant:

Foo = fun F(X) -> F(X) end.

In this way it is easier to understand that F is the function itself within the definition. Also, Foo and F can be the same variable.

回答3:

Alternatively, you can use the Y combinator. Y Combinator in Erlang explains.

回答4:

I had a need to quickly send some packets over UDP for testing and here is how I have done it using the samples above:

Sendtimes = fun F(0,Socket) -> ok;
        F(Times,Socket) -> gen_udp:send(Socket, {127,0,0,1}, 5555, ["Message #:" ++ [Times]]),
        F(Times-1,Socket) end.

回答5:

Obviously, Foo gets assigned only after the fun is defined, so it may not be accessed from within it.

I don't think that Erlang allows to call the anonymous function from itself. Just make it a named one.