WINAPI改变亮度(winapi change brightness)

什么WINAPI的是那里来改变屏幕的亮度？

我一直在试图寻找一个例子或API我可以使用Delphi的，但没有发现任何东西。

从Windows Vista开始，你可以使用GetMonitorBrightness和SetMonitorBrightness功能。

function GetMonitorBrightness(
  hMonitor : THandle;
  var   pdwMinimumBrightness : DWORD;
  var   pdwCurrentBrightness : DWORD;
  var   pdwMaximumBrightness : DWORD
) : BOOL; stdcall ; external 'Dxva2.dll' name 'GetMonitorBrightness';


function SetMonitorBrightness(
  hMonitor : THandle;
  dwNewBrightness : DWORD
): BOOL; stdcall ; external 'Dxva2.dll' name 'SetMonitorBrightness';

另一种选择是使用WmiSetBrightness所述的方法WmiMonitorBrightnessMethods WMI类。

{$APPTYPE CONSOLE}

uses
  SysUtils,
  ActiveX,
  Variants,
  ComObj;

procedure  SetBrightness(Timeout : Integer; Brightness : Byte);
var
  FSWbemLocator : OLEVariant;
  FWMIService   : OLEVariant;
  FWbemObjectSet: OLEVariant;
  FWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer('localhost', 'root\WMI', '', '');
  FWbemObjectSet:= FWMIService.ExecQuery('SELECT * FROM WmiMonitorBrightnessMethods Where Active=True','WQL',$00000020);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  while oEnum.Next(1, FWbemObject, iValue) = 0 do
  begin
    FWbemObject.WmiSetBrightness(Timeout, Brightness);
    FWbemObject:=Unassigned;
  end;
end;


begin
 try
    CoInitialize(nil);
    try
      SetBrightness(5, 100);
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

注意：如果这些功能都支持GetMonitorCapabilities函数返回MC_CAPS_BRIGHTNESS标志。