我一直在试图给定的名单分成两个不同的列表：独特的和重复的。 例如，如果我们有列表[1, 1, 2, 3, 3, 4, 5]我想要的唯一列表是[2, 4, 5]和式两份， [1, 3] 我不希望所有的1，在列表是在重复列表。 我只需要其中的一个。 该代码我现在所拥有的：
compareL([_|[]], Unique, Dup).
compareL([X3,Y3 | Tail], [X3 | Unique], Dup) :-
X3 =\= Y3,
compareL([Y3 | Tail], Unique, Dup).
compareL([X3,Y3 | Tail], Unique, [X3 | Dup]) :-
X3 = Y3,
skipDups(X3, Tail, Unique, Dup).
skipDups(_, [], Unique, Dup).
skipDups(X3,[Y3 | Tail], Unique, Dup) :-
X3 =\= Y3,
compareL([Y3 | Tail], Unique, Dup).
skipDups(X3,[Y3 | Tail], Unique, Dup) :-
X3 = Y3,
skipDups(X3, Tail, Unique, Dup).
使用如果用完上面给出的实例列表compareL([1, 1, 2, 3, 3, 4, 5], Unique, Dup). 我得到：
Unique = [2, 4|_G1954],
Dup = [1, 3|_G1948].
我想不通为什么对两份名单我得到“结束_G1954 ”和“ _G1948 ”。 任何帮助，将不胜感激。 谢谢。
这里是一个解决方案，关键是采取/ 4消耗所有匹配导致的物品，从而使该列表的简单的测试（ [_|_]至少1个元素的任何列表匹配）
compareL([], [], []).
compareL([X|Xs], U, D) :-
( take(X, Xs, [_|_], Ys)
-> compareL(Ys, U, B), D = [X|B]
; compareL(Xs, A, D), U = [X|A]
).
take(X, [X|Xs], [X|R], Ys) :-
!, take(X, Xs, R, Ys).
take(_, Ys, [], Ys).
我们可以保持合理的纯度通过在建筑if_/3 ， (=)/3 ，和tpartition/4 ！
list_uniqs_dups([],[],[]).
list_uniqs_dups([X|Xs0],Us0,Ds0) :-
tpartition(=(X),Xs0,Es,Xs),
if_(Es=[],
Us0+Ds0=[X|Us]+Ds,
Ds0+Us0=[X|Ds]+Us),
list_uniqs_dups(Xs,Us,Ds).
这里的OP给查询：
?- list_uniqs_dups([1,1,2,3,3,4,5],Us,Ds).
Ds = [1,3], Us = [2,4,5]. % succeeds deterministically
好！ 如何以下相当普遍的疑问？
?- list_uniqs_dups([],Us,Ds).
Ds = [], Us = [].
?- list_uniqs_dups([A],Us,Ds).
Ds = [], Us = [A].
?- list_uniqs_dups([A,B],Us,Ds).
Ds = [B], Us = [] , A=B
; Ds = [] , Us = [A,B], dif(A,B).
?- list_uniqs_dups([A,B,C],Us,Ds).
Ds = [C], Us = [] , A=B , B=C
; Ds = [B], Us = [C] , A=B , dif(B,C)
; Ds = [C], Us = [B] , A=C , dif(B,C)
; Ds = [C], Us = [A] , dif(A,C), B=C
; Ds = [] , Us = [A,B,C], dif(A,B), dif(A,C), dif(B,C).
回答用(=)/3
list_uniqs_alldups(Es,Us,Ds) :
tpartition(list_uniqmember_t(Es),Es,Us,Ds).
list_uniqmember_t(Es,X,T) :-
tfilter(=(X),Es,Xs),
=(Xs,[X],T).
示例查询：
?- list_uniqs_alldups([1,1,2,1,1,3,4,3],Us,Ds).
Us = [2, 4],
Ds = [1, 1, 1, 1, 3, 3].
?- list_uniqs_alldups([1,1,2,3,3,1,1,3,4,3],Us,Ds).
Us = [2, 4],
Ds = [1, 1, 3, 3, 1, 1, 3, 3].
?- list_uniqs_alldups([8,1,1,2,3,3,1,1,3,4,3],Us,Ds).
Us = [8, 2, 4],
Ds = [1, 1, 3, 3, 1, 1, 3, 3].
?- list_uniqs_alldups(X,Us,Ds).
X = Us, Us = Ds, Ds = [] ;
X = Us, Us = [_A], Ds = [] ;
X = Ds, Us = [], Ds = [_A,_A] ;
X = Ds, Us = [], Ds = [_A,_A,_A] ;
...
用于行程长度编码我用splitlistIfAdj/3 。
list_rle(List,Rle) :-
splitlistIfAdj(dif,List,Rle0),
maplist(rle_length,Rle0,Rle).
rle_length([H|T],RleLen) :-
length([H|T],L),
RleLen = L*H.
查询：
?- list_rle([a,a,b,a,a,c,d,c],X).
X = [2*a, 1*b, 2*a, 1*c, 1*d, 1*c].
我不知道如何改变这种做法，它是双向的。
然后，您也这样做：
new_list_uniqs_alldups(List,Us,Ds):-
list_rle(List,Rle),
tpartition(singlelist_t,Rle,Us,Ds).
singlelist_t(L,T) :-
L=N*_,
if_(N=1,T=true,T=false).
样品Q：
?- new_list_uniqs_alldups([1,1,2,1,1,3,4,1,1,7,8],U,D).
U = [1*2, 1*3, 1*4, 1*7, 1*8],
D = [2*1, 2*1, 2*1].
?- new_list_uniqs_alldups([7,7,7,2,1,1,3,4,1,1,7,8],U,D).
U = [1*2, 1*3, 1*4, 1*7, 1*8],
D = [3*7, 2*1, 2*1].
你可以写：
split_seq([], [], []).
split_seq([H | T], L1_out, L2_out) :-
split_seq(T, L1, L2),
( select(H, L1, L1_out)
-> ( member(H, L2)
-> L2_out = L2
; L2_out = [H | L2])
; L1_out = [H | L1],
L2_out = L2).
