E-Mail body is lost when sending (outlook vba)

问题:

I'm trying to write a macro that sends an automatic notification to specific addresses before sending the original email. (Like a cc, without actually using cc.)

The content of the original formatted email, (including text, tables, and pictures,) should be copied and pasted into a new email which is then automatically sent. Everything works when I just display the message, but not when actually sending the email.

Here is my code:

Dim objMsg As Outlook.MailItem
Dim activeMailMessage As Outlook.MailItem
Dim BodyText As Object

' Create the message.
Set objMsg = Application.CreateItem(olMailItem)

'copy body of current item
Set activeMailMessage = ActiveInspector.CurrentItem
activeMailMessage.GetInspector().WordEditor.Range.FormattedText.Copy

'paste body into new email
Set BodyText = objMsg.GetInspector.WordEditor.Range
BodyText.Paste

'set up and send notification email
With objMsg
    .To = "[e-mail]"
    .Subject = "text" 
    .Send
End With

The text should be pasted into the body like this, but it won't paste:

With objMsg
    .To = "[e-mail]"
    .Subject = "test" 
    .body = bodytext.paste 
    .Send
End With

When I use .display the correct content is displayed. But when I send it directly (without first using .display), all of all information is lost and an empty email is sent. What can I do?

I could add a bcc in the original email to achieve the same result, but the original email does not always send, whereas this notification should be.

回答1:

Your code is never actually setting the Body of the e-mail in the objMsg object. It is working when you have objMsg displayed because your interacting with the 'Inspector'.

If you directly set either the HTMLBody (if you want to retain formatting), or the Body property on objMsg then it will work as in the below example.

With objMsg
    .HTMLBody = activeMailMessage.HTMLBody
    .To = "[e-mail]"
    .Subject = "text" 
    .Send
End With

Bob, regarding your question on images that are embedded within the e-mail being lost with the above approach. An alternate solution could be to use the MailItem's Copy method to create your new MailItem exactly as the original Item. This will also retain who the e-mail is being sent to you need to clear this to make sure only the intended recipients receive it.

Dim objMsg As Outlook.MailItem
Dim activeMailMessage As Outlook.MailItem

' Create the new message.
Set objMsg = Application.CreateItem(olMailItem)

' Assign the current item to activeMailMessage
Set activeMailMessage = ActiveInspector.CurrentItem

' Copy the current item to create a new message
Set objMsg = activeMailMessage.Copy

' Clear any existing recipients of the e-mail, as these will be retained in the Copy
While objMsg.Recipients.Count > 0
    objMsg.Recipients.Remove 1
Wend

'set up and send notification email
With objMsg
    .To = "[e-mail]"
    .Subject = "text" 
    .Send
End With

This should retain your images and other attachments as they were in the original e-mail.

回答2:

Try to call the Save method after calling the Paste method.