在GLSL高效的双三次过滤代码？(Efficient Bicubic filtering code

我想知道如果任何人有完整，有效，高效的代码做双三次纹理过滤在GLSL。 有是这样的：

http://www.codeproject.com/Articles/236394/Bi-Cubic-and-Bi-Linear-Interpolation-with-GLSL或https://github.com/visionworkbench/visionworkbench/blob/master/src/vw/ GPU /着色器/口译/插值bicubic.glsl

但无论做16个纹理读取其中只有4是必要的：

https://groups.google.com/forum/#!topic/comp.graphics.api.opengl/kqrujgJfTxo

但是上面的方法使用缺少“立方（）”函数，我不知道什么是应该做的，还需要一个莫名其妙的“texscale”参数。

还有NVidia的版本：

http://http.developer.nvidia.com/GPUGems2/gpugems2_chapter20.html

但我相信这使用CUDA，它是专门针对Nvidia的显卡。 我需要GLSL。

我大概口NVIDIA版本GLSL，但想我会先问清楚，看是否有人已经有一个完整的，工作GLSL双三次着色器。

Answer 1:

我决定花一分钟来挖我的老Perforce的活动，发现失踪立方（）函数; 请享用！ :)

vec4 cubic(float v)
{
    vec4 n = vec4(1.0, 2.0, 3.0, 4.0) - v;
    vec4 s = n * n * n;
    float x = s.x;
    float y = s.y - 4.0 * s.x;
    float z = s.z - 4.0 * s.y + 6.0 * s.x;
    float w = 6.0 - x - y - z;
    return vec4(x, y, z, w);
}

Answer 2:

我发现这个实施），它可以被用作下拉更换纹理（（从http://www.java-gaming.org/index.php?topic=35123.0 （一个错字固定））：

// from http://www.java-gaming.org/index.php?topic=35123.0
vec4 cubic(float v){
    vec4 n = vec4(1.0, 2.0, 3.0, 4.0) - v;
    vec4 s = n * n * n;
    float x = s.x;
    float y = s.y - 4.0 * s.x;
    float z = s.z - 4.0 * s.y + 6.0 * s.x;
    float w = 6.0 - x - y - z;
    return vec4(x, y, z, w) * (1.0/6.0);
}

vec4 textureBicubic(sampler2D sampler, vec2 texCoords){

   vec2 texSize = textureSize(sampler, 0);
   vec2 invTexSize = 1.0 / texSize;

   texCoords = texCoords * texSize - 0.5;


    vec2 fxy = fract(texCoords);
    texCoords -= fxy;

    vec4 xcubic = cubic(fxy.x);
    vec4 ycubic = cubic(fxy.y);

    vec4 c = texCoords.xxyy + vec2 (-0.5, +1.5).xyxy;

    vec4 s = vec4(xcubic.xz + xcubic.yw, ycubic.xz + ycubic.yw);
    vec4 offset = c + vec4 (xcubic.yw, ycubic.yw) / s;

    offset *= invTexSize.xxyy;

    vec4 sample0 = texture(sampler, offset.xz);
    vec4 sample1 = texture(sampler, offset.yz);
    vec4 sample2 = texture(sampler, offset.xw);
    vec4 sample3 = texture(sampler, offset.yw);

    float sx = s.x / (s.x + s.y);
    float sy = s.z / (s.z + s.w);

    return mix(
       mix(sample3, sample2, sx), mix(sample1, sample0, sx)
    , sy);
}

例如：最近，双线性，双三次：

这个形象的图象 - 是

{{{0.698039, 0.996078, 0.262745}, {0., 0.266667, 1.}, {0.00392157, 
   0.25098, 0.996078}, {1., 0.65098, 0.}}, {{0.996078, 0.823529, 
   0.}, {0.498039, 0., 0.00392157}, {0.831373, 0.00392157, 
   0.00392157}, {0.956863, 0.972549, 0.00784314}}, {{0.909804, 
   0.00784314, 0.}, {0.87451, 0.996078, 0.0862745}, {0.196078, 
   0.992157, 0.760784}, {0.00392157, 0.00392157, 0.498039}}, {{1., 
   0.878431, 0.}, {0.588235, 0.00392157, 0.00392157}, {0.00392157, 
   0.0666667, 0.996078}, {0.996078, 0.517647, 0.}}}

我试图重现这个（许多其他插值技术）

但他们已经夹紧填充，虽然我已经重复（包装）的边界。 因此，这是不完全一样的。

看来这双三次企业是不是一个适当的插值算法 ，即它不会对在那里的数据定义点的原始值取。

Answer 3:

缺少的功能cubic()在JAre的回答看起来是这样的：

vec4 cubic(float x)
{
    float x2 = x * x;
    float x3 = x2 * x;
    vec4 w;
    w.x =   -x3 + 3*x2 - 3*x + 1;
    w.y =  3*x3 - 6*x2       + 4;
    w.z = -3*x3 + 3*x2 + 3*x + 1;
    w.w =  x3;
    return w / 6.f;
}

它返回三次B样条的四个权重。

这是在所有解释的NVidia宝石 。

Answer 4:

哇。 我承认以上（我无法瓦特/声望<50的评论），因为我在2011年初与它来了，我试图解决的问题是有关老IBM T42的代码（遗憾的确切型号我想不起来了），笔记本电脑和这是ATI图形堆栈。 我公司开发的NV卡上的代码，原来我用16分纹理取。 这是有点慢，但速度不够快，我的目的。 当有人报告说，它并没有在他的笔记本电脑工作，很明显，他们不支持每个片段质地够取。 我不得不工程师变通办法，我能想出是有质感的数量做取入该会的工作是最好的。

我想过这个问题是这样的：好，所以如果我处理每四（2×2）与线性滤波器剩余的问题是可以的行和列分享的权重？ 那是在我心中唯一的问题，当我着手工艺的代码。 当然，他们可以共享; 权重是相同的每个列和行; 完善！

现在，我有四个样本。 剩下的问题是如何正确地结合起来的样本。 这是要克服的最大障碍。 它拿着铅笔和纸约10分钟。 用颤抖的手我键入的代码和它的工作，美观大方。 然后我上传的二进制文件谁答应看看他的T42（？）的家伙，他报告它的工作。 结束。 :)

我可以保证方程检出并单独地计算所述样本得到数学相同的结果。 FYI：与CPU它的速度更快单独做水平和垂直扫描。 随着GPU多遍是不是好主意，尤其是当它可能不是可行反正在典型使用情况。

深思：它是可以使用纹理查找的立方（）函数。 这是更快依赖于GPU，但总体上说，取样是在ALU方面只是在做算术将平衡东西出来的光。 因人而异。

Answer 5:

（编辑）

• 立方（）是一个三次样条函数

  例：

• Texscale为采样窗口的尺寸系数。 你可以用1.0的值开始。

---

vec4 filter(sampler2D texture, vec2 texcoord, vec2 texscale)
{
    float fx = fract(texcoord.x);
    float fy = fract(texcoord.y);
    texcoord.x -= fx;
    texcoord.y -= fy;

    vec4 xcubic = cubic(fx);
    vec4 ycubic = cubic(fy);

    vec4 c = vec4(texcoord.x - 0.5, texcoord.x + 1.5, texcoord.y -
0.5, texcoord.y + 1.5);
    vec4 s = vec4(xcubic.x + xcubic.y, xcubic.z + xcubic.w, ycubic.x +
ycubic.y, ycubic.z + ycubic.w);
    vec4 offset = c + vec4(xcubic.y, xcubic.w, ycubic.y, ycubic.w) /
s;

    vec4 sample0 = texture2D(texture, vec2(offset.x, offset.z) *
texscale);
    vec4 sample1 = texture2D(texture, vec2(offset.y, offset.z) *
texscale);
    vec4 sample2 = texture2D(texture, vec2(offset.x, offset.w) *
texscale);
    vec4 sample3 = texture2D(texture, vec2(offset.y, offset.w) *
texscale);

    float sx = s.x / (s.x + s.y);
    float sy = s.z / (s.z + s.w);

    return mix(
        mix(sample3, sample2, sx),
        mix(sample1, sample0, sx), sy);
}

资源

Answer 6:

对任何人感兴趣的GLSL代码做三 -cubic插值，光线投射使用三次插值代码可以在实施例中/ glCubicRayCast文件夹中找到在： http://www.dannyruijters.nl/cubicinterpolation/CI.zip

编辑：立方插值代码已经在GitHub上可供选择： CUDA版本的WebGL版本，和GLSL样品。

Answer 7:

我一直在使用@Maf的三次样条食谱一年多了，我推荐它，如果三次B样条满足您的需求。

不过，我最近意识到，我的具体应用，是很重要的强度在采样点完全匹配。 所以我切换到使用的Catmull-Rom样条，其采用了略有不同的配方，如下所示：

// Catmull-Rom spline actually passes through control points
vec4 cubic(float x) // cubic_catmullrom(float x)
{
    const float s = 0.5; // potentially adjustable parameter
    float x2 = x * x;
    float x3 = x2 * x;
    vec4 w;
    w.x =    -s*x3 +     2*s*x2 - s*x + 0;
    w.y = (2-s)*x3 +   (s-3)*x2       + 1;
    w.z = (s-2)*x3 + (3-2*s)*x2 + s*x + 0;
    w.w =     s*x3 -       s*x2       + 0;
    return w;
}

我发现这些系数，再加上那些为多家三次样条的其他口味的，在讲义： http://www.cs.cmu.edu/afs/cs/academic/class/15462-s10/www/lec -slides / lec06.pdf

Answer 8:

我认为这是可能的的Catmull版本可以与通过（a）排列所输入的纹理像保存为阳性和阴性作为备用时隙的棋盘上，和（b）textureBicubic的相关联的变形例4分纹理查找来完成。 这将依赖于捐助/ WX权/ WW始终为负，和WY / WZ始终是积极的贡献。 我还没有仔细核对，如果这是真的，或者究竟是如何修改的textureBicubic看起来。

......我已经验证了W¯¯贡献做满足雾化+ ve -ve规则。

文章来源: Efficient Bicubic filtering code in GLSL?