How to handle Case insensitive xml variables in xs

问题:

Input XML:

<root>
<data>
    <Data>
      <rt>ArgoElectrnicsShop</rt>
      <report>
            <row>
                <tn>new tv</tn>
                <value>Samsung</value>
            </row>
            <row>
                <tn>new radio</tn>
                <value>Sony</value>
            </row>
            <row>
                <tn>new WashingMachine</tn>
                <value>Whirlpool</value>
            </row>
        </report>
    </Data>
</data>
</root>

XSL:

<xsl:output method="xml" indent="yes"/>
<xsl:template match="@* | node()"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/">
    <xsl:element name="DataModel">
        <xsl:apply-templates select="/root/data/Data/rt"/>
    </xsl:element>
</xsl:template>

<xsl:template match="/root/data/Data/rt[text()='ArgoElectrnicsShop']">
    <xsl:element name="T_New">
        <xsl:apply-templates select="../report" mode="check"/>
    </xsl:element>
</xsl:template>

<xsl:template match="report" mode="check">
    <xsl:variable name="lowercase" select="'abcdefghijklmnopqrstuvwxyz:"/>
    <xsl:variable name="uppercase" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
    <xsl:variable name="EntireValue">
            <xsl:value-of select="row[substring-after(tn, ' ')]/tn"/>
        </xsl:variable>
        <xsl:variable name="Field">
            <xsl:value-of select="row[substring-after($EntireValue, ' ')]"/>
        </xsl:variable>
        <xsl:call-template name="sample">
            <xsl:with-param name="tn" select="translate($EntireValue,$lowercase,$uppercase)"/>
            <xsl:with-param name="value" select="row[substring-after(tn, ' ')=$Field]/value"/>
        </xsl:call-template>
</xsl:template>

<xsl:template name="sample">
    <xsl:param name="tn"/>
    <xsl:param name="value"/>
    <xsl:choose>
        <xsl:when test="substring-after($tn, ' ')='TV'">
            <xsl:element name="tv">
                <xsl:value-of select="$value"/>
            </xsl:element>
        </xsl:when>
        <xsl:when test="substring-after($tn, ' ')='RADIO'">
            <xsl:element name="radio">
                <xsl:value-of select="$value"/>
            </xsl:element>
        </xsl:when>
        <xsl:when test="substring-after($tn, ' ')='WASHINGMACHINE'">
            <xsl:element name="washingmachine">
                <xsl:value-of select="$value"/>
            </xsl:element>
        </xsl:when>
    </xsl:choose>
</xsl:template>

**Output XML:**
<DataModel>
    <T_New>
        <tv>Samsung</tv>
    </T_New>
</DataModel>

**Expected Output XML by running through all rows:**
<DataModel>
    <T_New>
        <tv>Samsung</tv>
        <radio>Sony</radio>
        <washingmachine>Whirlpool</washingmachine>
    </T_New>
</DataModel>

1. I want to run the loop for all the rows to get the values. The values inside the tn may be of any case, so i have taken the value from the tn of a row and translated it to uppercase and compared the value in the template sample and written the correct values in the output xml.
2. I could not run through all the rows in the xml. Could anyone help me to solve this.

回答1:

As I wrote in the comments, your question is not entirely clear. The expected output can be produced quite easily by applying the following stylesheet:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:variable name="lowercase">abcdefghijklmnopqrstuvwxyz</xsl:variable>
<xsl:variable name="uppercase">ABCDEFGHIJKLMNOPQRSTUVWXYZ</xsl:variable>

<xsl:template match="/root">
    <DataModel>
        <xsl:apply-templates select="data/Data[rt='ArgoElectrnicsShop']"/>
    </DataModel>
</xsl:template>

<xsl:template match="Data">
    <T_New>
        <xsl:apply-templates select="report/row"/>
    </T_New>
</xsl:template>

<xsl:template match="row">
    <xsl:element name="{translate(substring-after(tn, ' '), $uppercase, $lowercase)}">
        <xsl:value-of select="value"/>
    </xsl:element>   
</xsl:template>

</xsl:stylesheet>

However, this assumes a number of things - most importantly that the string following the space in the value of tn is a valid XML element name.