工作中的自动化作业：导入简报子弹文本到Excel工作表(Automating a Job at Wo

我一直在问自动化今天工作的特定任务，占用了大量的我们的时间！下面是什么需要做，我将不胜感激我怎么能如果可能的话我的知识的领域内做到这一点（实施意见），任何帮助。

问题

我有一个PowerPoint演示文档（.PPT）。我想从那里提取文本（文本为圆点格式）。我想插入这些子弹指向到一个Excel的片，每颗子弹点应该是一排。我也希望把在相邻列这个项目符号的文本是取自页面。

所以，基本上是：从PPT提取物 - >插入Excel工作表中的每一行是一个圆点。

提供给我技术

的Perl，PHP和Java。

我宁愿PHP是诚实的，因为这是我的主要语言，但我很乐意考虑别的你们/加仑认为是最好的。二是Perl和那么Java。我不希望编译类和这只是安装JDK！ :)

关键问题

你如何引用子弹呢？
难道我可能只是一个在Excel工作表非结构化文本的负载结束？
是否有从PPT文件中读取任何障碍？

更新

我会考虑MS技术（VB等），如果它使生活更轻松，但我从来没有使用过它，我鄙视MS技术！希望我不要被传道好看的！ :)

Answer 1:

下面是一个使用示例脚本的Win32 :: OLE 。

顺便说一句，一旦你转换的滑入你可以处理的格式，你可以使用电子表格:: WriteExcel非MS系统将输出写入。因此，我建议两个方案：一是改造PowerPoint文档，另一个用来生成Excel文件。

请注意，Microsoft Office应用程序信息的极好来源为对象浏览器。您可以通过工具访问→宏→Visual Basic编辑器。一旦你在编辑器中，点击F2浏览接口，方法，并通过Microsoft Office应用程序提供的属性。

#!/usr/bin/perl

use strict;
use warnings;

use FindBin qw( $Bin );
use File::Spec::Functions qw( catfile );

use Win32::OLE;
use Win32::OLE::Const 'Microsoft PowerPoint';
$Win32::OLE::Warn = 3;

my $ppt = get_ppt();
$ppt->{Visible} = 1;

my $ppt_file = catfile $Bin, 'test.ppt';
my $doc = $ppt->Presentations->open( $ppt_file );
my $slides = $doc->Slides;
my $num_slides = $slides->Count;

for my $slide_idx (1 .. $num_slides) {
    print "=== Begin Slide $slide_idx ===\n";

    my $slide = $doc->Slides->Item( $slide_idx );
    my $shapes = $slide->Shapes;
    my $num_shapes = $shapes->Count;

    for my $shape_idx (1 .. $num_shapes) {
        my $shape = $shapes->Item($shape_idx);
        next unless $shape->HasTextFrame;

        my $pars = $shape->TextFrame->TextRange->Paragraphs;
        my $num_pars = $pars->Count;
        for my $par_idx (1 .. $num_pars) {
            my $par = $pars->Paragraphs($par_idx,1);
            print_par( $par );
        }
    }

    print "=== End Slide $slide_idx ===\n\n";
}

sub print_par {
    my ($par) = @_;
    my @bullets = qw( - * > + = @ );

    my $bullet_format = $par->ParagraphFormat->Bullet;
    my $bullet_type = $bullet_format->Type;

    my $bullet_char = '';

    if ($bullet_type == ppBulletNumbered) {
        $bullet_char = $bullet_format->Number . "\t";
    }
    elsif( $bullet_type == ppBulletUnnumbered ) {
        # Need a Unicode => ASCII mapping if you want to use
        # $bullet_format->Character
        my $indent = $par->IndentLevel % scalar @bullets;
        $bullet_char = $bullets[$indent] . "\t";
    }

    my $text = $par->Text;
    $text =~ s/\s+$//;

    print $bullet_char, $text,"\n";
}

sub get_ppt {
    my $app;
    eval {
        $app = Win32::OLE->GetActiveObject('PowerPoint.Application');
    };

    die "$@\n" if $@;

    unless($app) {
        $app = Win32::OLE->new(
            'PowerPoint.Application', sub { $_[0]->Quit }
        ) or die "Oops, cannot start PowerPoint: ",
                 Win32::OLE->LastError, "\n";
    }
    return $app;
}

Answer 2:

它可以用Perl来完成。相当多的东西，你可以用VBA做可以用Perl通过的Win32 :: OLE来完成。我用的Win32 :: OLE模块，MS-Office文档，无论是提取和创建内容合作。它已经一段时间，但。从这里开始， http://win32.perl.org/wiki/index.php?title=Win32_Perl_Modules关于页面的中间。

在每个对象的VBA文档是有用的参考，发现有什么对象以及它们提供的方法和属性。

Answer 3:

PUH ......你必须在处理使用Perl，PHP或Java的MS Office文件之苦。当我必须为MS Office文件做自动化我最常使用VBA（Visual Basic应用程序）。看看它。对于很多东西，你可以录制宏，看看所产生的代码，并了解事情是如何被引用。然后把生成的代码片段，并创建自己的VBA模块和工具。我能想象，这样的功能可以完全适合作为一个外接的电源点。