Function modules to update table bsid (field: cess

For a certain program I need to update table bsid. The field cession_kz needs to be updated. I've looked for many function modules but none of them fit my needs. Does someone know a best practice to solve this problem?

BSID is a secondary index for BSEG customer items, so updating it directly will lead to database inconsistencies and any update must go via BSEG.

You can use a function module like FI_ITEMS_MASS_CHANGE. This FM updates BSEG by running a BDC for transaction FB02 (Change Document). When a relevant (customer) item is changed in BSEG, the corresponding BSID record is changed as well.

See example code below:

DATA: ls_bseg   TYPE bseg,
      lt_errdoc TYPE tpit_t_errdoc,
      lt_fname  TYPE tpit_t_fname,
      lt_buztab TYPE tpit_t_buztab.

* Field name to be changed
APPEND 'CESSION_KZ' TO lt_fname.

* New field value
ls_bseg-cession_kz = 'AB'.

* Selection of items to be changed
* Only select customer items to avoid problems in batch input
SELECT bukrs belnr gjahr buzei koart umskz bschl mwart mwskz
  FROM bseg
  INTO CORRESPONDING FIELDS OF TABLE lt_buztab
  WHERE belnr = '1400000000' AND
        bukrs = '1000' AND
        koart = 'D'. "Customers

CALL FUNCTION 'FI_ITEMS_MASS_CHANGE'
  EXPORTING
    s_bseg     = ls_bseg
  IMPORTING
    errtab     = lt_errdoc[]
  TABLES
    it_buztab  = lt_buztab
    it_fldtab  = lt_fname
  EXCEPTIONS
    bdc_errors = 1
    OTHERS     = 2.
IF sy-subrc <> 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
  WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

Make sure you allow changes in maintenance view V_TBAER with transaction SM30 or through customizing:
Financial Accounting → Financial Accounting Global Settings → Document → Line Item → Document Change Rules, Line Item.

Note:
Pledging indicators should be defined for all company codes passed to the FM:

Financial Accounting → Accouts Receivable and Accounts Payable → Customer Account → Master Data → Preperation for creating master data → Define Accounts Receivable Pledging Indicator.

If not, the field will not be available for the batch input and the FM will result in an error.