转换字符串“abc”，以$哈希 - > {A} - > {B} - > {C}

我有动态嵌套哈希裁判是这样的：

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } };

我想通过允许用户输入“ABC的东西”来设置C到“东西”的价值。

现在所获得的价值可以做这样的：

my $keys = 'a.b.c'; 
my $v='something';
my $h = $hash;
foreach my $k(split /\./, $keys) {
  $h = $h->{$k};
}
print $h; # "value"

但我怎么设置键的值c至$v ，使

print Dumper $hash;

将反映这一变化？ $h是不是在foreach循环的最后一个引用，因此更改不会反映在更改$hash 。 任何提示如何解决在我的头上的疙瘩？

Answer 1:

事情是这样的：

my $h = $hash;
my @split_key = split /\./, $keys;
my $last_key = pop @split_key;
foreach my $k (@split_key) {
    $h = $h->{$k};
}
$h->{$last_key} = $v;

Answer 2:

sub dive_val :lvalue {
   my $p = \shift;
   $p = \( ($$p)->{$_} ) for @_;
   return $$p;
}

my $data;
my $key = 'a.b.c';
my $val = 'value';

dive_val($data, split /\./, $key) = $val;

此功能的更强大的（并因此稍硬使用）版本是由提供数据::潜水员 。

use Data::Diver qw( DiveVal );

my $data;
my $key = 'a.b.c';
my $val = 'value';

DiveVal($data //= {}, map \$_, split /\./, $key) = $val;

（daxim的用法是稍微偏离。）

Answer 3:

use strictures;
use Data::Diver qw(DiveVal);

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } },
    'a.b.c',
    'something',
);

DiveVal($hash, split /[.]/, $path) = $value;
# { a => { b => { c => 'something' } } }

文章来源: Convert string “a.b.c” to $hash->{a}->{b}->{c} in Perl