从字符串中删除号码(Delete numbers from a String)

我想知道我怎么可以从一个字符串删除号码。 我尝试使用StringReplace，我不知道该怎么告诉我要更换号码的功能。

下面是我的尝试：

StringReplace(mString, [0..9], '', [rfReplaceAll, rfIgnoreCase]);

Answer 1:

简单而有效。 可以优化，但你需要的启动应该让你：

function RemoveNumbers(const aString: string): string;
var
  C: Char;
begin
  Result := '';
  for C in aString do begin
      if not CharInSet(C, ['0'..'9']) then
      begin
        Result := Result + C;
      end;
    end;
end;

Answer 2:

相当快就地版本。

procedure RemoveDigits(var s: string);
var
  i, j: Integer;
  pc: PChar;
begin
  j := 0;
  pc := PChar(@s[1]);
  for i := 0 to Length(s) - 1 do
    if pc[i] in ['0'..'9'] then 
               //if CharInSet(pc[i], ['0'..'9']) for Unicode version
      Inc(j)
    else
      pc[i - j] := pc[i];
  SetLength(s, Length(s) - j);
end;

Answer 3:

这样做的输出尼克的版本相同，但是这是超过3倍的速度与短字符串。 该文本越长，差异越大。

function RemoveNumbers2(const aString: string): string;
var
  C:Char; Index:Integer;
begin
  Result := '';
  SetLength(Result, Length(aString));
  Index := 1;
  for C in aString do
    if not CharInSet(C, ['0' .. '9']) then
    begin
      Result[Index] := C;
      Inc(Index);
    end;
  SetLength(Result, Index-1);
end;

不要浪费宝贵的CPU周期，如果你不就得了。

Answer 4:

嗯，我厌倦了寻找已建立功能所以我创造我自己的：

   function RemoveNumbers(const AValue: string): string;
   var
      iCar : Integer;
      mBuffer : string;
   begin
      mBuffer := AValue;

      for iCar := Length(mBuffer) downto 1 do
      begin
         if (mBuffer[iCar] in ['0'..'9']) then
            Delete(mBuffer,iCar,1);
      end;
      Result := mBuffer;
   end;

Answer 5:

用这个

function RemoveNonAlpha(srcStr : string) : string;
const
CHARS = ['0'..'9'];
var i : integer;
begin
result:='';
for i:=0 to length(srcStr) do
if  (srcstr[i] in CHARS) then
result:=result+srcStr[i];
end   ;

你可以这样调用

edit2.text：= RemoveNonAlpha（edit1.text）;

Answer 6:

StringReplace不接受一组作为第二个参数。 也许有人会有更合适的方法，但这个工程：

StringReplace(mString, '0', '', [rfReplaceAll, rfIgnoreCase]);
StringReplace(mString, '1', '', [rfReplaceAll, rfIgnoreCase]);    
StringReplace(mString, '2', '', [rfReplaceAll, rfIgnoreCase]);

等等

文章来源: Delete numbers from a String