与T-SQL插入记录n个(Inserting n number of records with T-

我想在一个表中添加可变数量的记录（天）

我已经看到了这一个整洁的解决方案：

SET @nRecords=DATEDIFF(d,'2009-01-01',getdate())
SET ROWCOUNT @nRecords
INSERT int(identity,0,1) INTO #temp FROM sysobjects a,sysobjects b
SET ROWCOUNT 0

但不幸的是这并不在UDF工作（因为#TEMP和SET ROWCOUNT）。任何想法如何才能实现？

目前我正与一个WHILE和表变量这样做，但在性能方面它不是一个很好的解决方案。

Answer 1:

如果您使用SQL 2005或更高版本，可以使用递归CTE获取日期或编号列表...

with MyCte AS
    (select   MyCounter = 0
     UNION ALL
     SELECT   MyCounter + 1
     FROM     MyCte
     where    MyCounter < DATEDIFF(d,'2009-01-01',getdate()))
select MyCounter, DATEADD(d, MyCounter, '2009-01-01')
from   MyCte 
option (maxrecursion 0)


/* output...
MyCounter   MyDate
----------- -----------------------
0           2009-01-01 00:00:00.000
1           2009-01-02 00:00:00.000
2           2009-01-03 00:00:00.000
3           2009-01-04 00:00:00.000
4           2009-01-05 00:00:00.000
5           2009-01-06 00:00:00.000
....
170         2009-06-20 00:00:00.000
171         2009-06-21 00:00:00.000
172         2009-06-22 00:00:00.000
173         2009-06-23 00:00:00.000
174         2009-06-24 00:00:00.000

(175 row(s) affected)

*/

Answer 2:

您可以使用一个WHILE语句：

declare @i int
declare @rows_to_insert int
set @i = 0
set @rows_to_insert = 1000

while @i < @rows_to_insert
    begin
    INSERT INTO #temp VALUES (@i)
    set @i = @i + 1
    end

Answer 3:

这是我使用的方法和最适合我的目的，并使用SQL 2000年因为在我的情况是UDF里面，我不能使用##或＃临时表，所以我用一个表变量。我正在做：

DECLARE @tblRows TABLE (pos int identity(0,1), num int) 
DECLARE @numRows int,@i int


SET @numRows = DATEDIFF(dd,@start,@end) + 1
SET @i=1

WHILE @i<@numRows
begin
    INSERT @tblRows SELECT TOP 1 1 FROM sysobjects a

    SET @i=@i+1
end

Answer 4:

总体来说要快得多在每次迭代行的数量增加一倍

CREATE TABLE dbo.Numbers(n INT NOT NULL PRIMARY KEY)
GO
DECLARE @i INT;
SET @i = 1;
INSERT INTO dbo.Numbers(n) SELECT 1;
WHILE @i<128000 BEGIN
  INSERT INTO dbo.Numbers(n)
    SELECT n + @i FROM dbo.Numbers;
  SET @i = @i * 2;
END;

我故意没有设置NOCOUNT ON，让你看看它是如何插入1,2,4,8行

Answer 5:

您可以使用交叉联接

select top 100000 row_number() over(order by t1.number)-- here you can change 100000 to a number you want or a variable
from   master.dbo.spt_values t1
       cross join master.dbo.spt_values t2

Answer 6:

当你有一个预先建立的数字表，只需使用：

SELECT *
FROM numbers
WHERE number <= DATEDIFF(d,'2009-01-01',getdate())

有任意数量的建设摆在首位的数字表（使用此技术）技术，但一旦它的建成和索引，你不要再建了。

Answer 7:

你可以做什么PinalDave建议：

INSERT INTO MyTable (FirstCol, SecondCol)
SELECT 'First' ,1
UNION ALL
SELECT 'Second' ,2
UNION ALL
SELECT 'Third' ,3
UNION ALL
SELECT 'Fourth' ,4
UNION ALL
SELECT 'Fifth' ,5
GO

Answer 8:

怎么样：

DECLARE @nRecords INT

SET @nRecords=DATEDIFF(d,'2009-01-01',getdate())

SELECT TOP (@nRecords)
    ROW_NUMBER() OVER (ORDER BY a.object_id, b.object_id) - 1
FROM sys.objects a, sys.objects b

如果你不希望它的零纳入索引，去掉“ - 1 ”

至少需要SQL Server 2005中。

文章来源: Inserting n number of records with T-SQL