在XSL级联两个领域(concatenation two fields in xsl)

我有一些XML领域我需要连接所有的字段一个字段

<fields>
<field name="first"><value>example</value></field>
<field name="last"><value>hello</value></field>
<field name="age"><value>25</value></field>
<field name="enable"><value>1</value></field>
<fields>

我需要改变如下

<fields>
<field name="all"><value>example hello 25 1</value></field>
</field>

用分隔符使用XSL空间

Answer 1:

这种短期和简单（没有明确的条件指令）XSLT 1.0转换 ：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <fields>
    <field name="all">
      <xsl:variable name="vfieldConcat">
        <xsl:for-each select="field/value">
          <xsl:value-of select="concat(., ' ')"/>
        </xsl:for-each>
      </xsl:variable>
      <value><xsl:value-of select=
         "normalize-space($vfieldConcat)"/></value>
    </field>
  </fields>
 </xsl:template>
</xsl:stylesheet>

当所提供的XML文档应用（校正为良好性）：

<fields>
    <field name="first">
        <value>example</value>
    </field>
    <field name="last">
        <value>hello</value>
    </field>
    <field name="age">
        <value>25</value>
    </field>
    <field name="enable">
        <value>1</value>
    </field>
</fields>

产生想要的，正确的结果：

<fields>
   <field name="all">
      <value>example hello 25 1</value>
   </field>
</fields>

II。 XSLT 2.0溶液

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <fields>
    <field name="all">
      <value><xsl:value-of select="field/value"/></value>
    </field>
  </fields>
 </xsl:template>
</xsl:stylesheet>

当在相同的XML文档（上面）被应用于这种转变中，相同的正确的结果产生：

<fields>
   <field name="all">
      <value>example hello 25 1</value>
   </field>
</fields>

说明：使用的事实，为默认值separator的属性xsl:value-of是一个单一的空间。

Answer 2:

就像是：

...
<fields>
<field name="all">
    <value><xsl:apply-templates select="fields/field"/></value>
</field>
</fields>
...
<xsl:template match="field[value/text()]">
  <xsl:value-of select="value"/>
  <xsl:if test="position() != last()"><xsl:text> </xsl:text></xsl:if>
</xsl:template>
...