共享对象发送方法(SharedObject Send Method)

在FMS我想使用共享对象中，因为它的实时聊天应用程序发送消息。我的问题是...你如何使用共享对象发送消息来回用户在现场的聊天应用程序？这会需要服务器端脚本，客户端或两者兼而有之？

您只需要写在服务器端的特定功能，例如安全功能的一些代码（如果不是所有的用户可以例如发送邮件）。

在客户端，您需要：

连接到服务器;
从服务器获取的共享对象。如果当你问它不存在，将创建它;
添加一个侦听它进行SyncEvent 。

从那里，每次客户端添加，更新或使用删除共享对象的属性setProperty()方法中，所有连接的客户端将收到一个SyncEvent 。

package
{
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.IEventDispatcher;
    import flash.events.NetStatusEvent;
    import flash.events.SyncEvent;
    import flash.net.NetConnection;
    import flash.net.SharedObject;

    public class Chat extends EventDispatcher
    {
        public var messages:Array;
        private var connection:NetConnection;
        private var chat_so:SharedObject;

        public function Chat()
        {
            super();
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, onNetStatus);
            messages = [];
        }

        public function connect(uri:String):void
        {
            connection.connect(uri);
        }

        public function addMessage(value:String):void
        {
            chat_so.setProperty(messages.length.toString(), value);
        }

        private function setUpSharedObject():void
        {
            chat_so = SharedObject.getRemote("chat", connection.uri);
            chat_so.addEventListener(SyncEvent.SYNC, onSync);
            chat_so.client = this;
        }

        private function onNetStatus(event:NetStatusEvent):void
        {
            if (event.info.code == "NetConnection.Connect.Success")
            {
                setUpSharedObject();
            }
            else
            {
                trace(event.info.code + ": " + event.info.description);
            }
        }

        private function onSync(event:SyncEvent):void
        {
            for (var i:int = 0; i < event.changeList.length; i++)
            {
                var code:String = event.changeList[i].code;

                switch(code)
                {
                    case "change":
                    case "success":
                    {
                        messages.push();
                        dispatchEvent(new Event(Event.CHANGE));
                        break;
                    }
                    case "clear":
                    {
                        messages = [];
                        break;
                    }
                    case "delete":
                    default:
                    {
                        break;
                    }
                }
            }
        }
    }
}