获取当前登录的OS用户在Adobe AIR(Get the current logged in OS

我需要登录的用户在我的空气/ Flex应用程序当前的名字。该应用程序将只被部署在Windows机器上。我想我可以通过regexing用户目录实现这一点，但我开放给其他的方式。

Answer 1:

有一对夫妇的小的清理可以使...

package
{
    import flash.filesystem.File;

    public class UserUtil
    {
        public static function get currentOSUser():String
        {
            var userDir:String = File.userDirectory.nativePath;
            var userName:String = userDir.substr(userDir.lastIndexOf(File.separator) + 1);
            return userName;
        }
    }
}

正如凯文建议，用File.separator ，使目录拆分跨平台（只在Windows和Mac OS X测试）。

你并不需要使用resolvePath("")除非你正在寻找一个孩子。

此外，使功能适当的getter允许在没有任何进一步的工作结合。

在上面的例子中，我把它变成一个UserUtil类，现在我可以绑定到UserUtil.currentOSUser ，例如：

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    <mx:Label text="{UserUtil.currentOSUser}"/> 
</mx:WindowedApplication>

Answer 2:

此外，我会尝试：

File.userDirectory.name

但是，我没有安装空调，所以我真的不能测试这个...

Answer 3:

这是不是最漂亮的办法，但如果你知道你的AIR应用程序只能在Windows环境下运行它工作得很好：

public var username:String;

public function getCurrentOSUser():void
{       
   var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo();  
   var file:File = new File("C:/WINDOWS/system32/whoami.exe");
   nativeProcessStartupInfo.executable = file;

   process = new NativeProcess();       
   process.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, onOutputData);
   process.start(nativeProcessStartupInfo);
}

public function onOutputData(event:ProgressEvent):void
{           
   var output:String = process.standardOutput.readUTFBytes(process.standardOutput.bytesAvailable);
   this.username = output.split('\\')[1];
   trace("Got username: ", this.username);
}

Answer 4:

下面是在XP / Vista的有效的解决方案，但绝对是可扩展到OSX，Linux的，我仍然有兴趣在另一种方式。

public static function GetCurrentOSUser():String{
    // XP & Vista only.
    var userDirectory:String = File.userDirectory.resolvePath("").nativePath;
    var startIndex:Number = userDirectory.lastIndexOf("\\") + 1
    var stopIndex:Number = userDirectory.length;
    var user = userDirectory.substring(startIndex, stopIndex);

    return user;
}