如何访问在向图的每个点(how to visit each point in directed gr

在Prolog的，我怎么能实现图形算法，以便找到以实现向图旅行商问题的所有路径？

例如：

                                                                         graph
                    expected input     expected output                 X -----> Y
    start X             X  Y               X Z                         Y -----> T
    end   Z             Y  T               X Y Z                       T -----> Z
                        T  Z               X Y T Z                     Y -----> Z
                        Y  Z                                           X -----> Z
                        X  Z

如你所知，在向图，有可能是一个循环。 然而，没有必要通过同一个点两次。

             graph             expected output             
           X ----> Y            
           Y ----> X               X Y Z
           Y ----> Z 

为什么我elimineting这种情况下是因为;

      output :

      X Y X Y ...   Z
              ^^^
              god knows this length ( when program terminates )
              termination is np problem

Answer 1:

我把一些评论解释代码的作用是什么？

% your directed graph
edge(x, y).
edge(y, t).
edge(t, z).
edge(y, z).
edge(x, z).

% get a path from start to end
path(Start, End, Path) :-
    path(Start, End, [Start], Path).

% when target reached, reverse the visited list
path(End, End, RPath, Path) :-
    reverse(RPath, Path).

% take non deterministically an edge, check if already visited before use
path(Start, End, Visited, Path) :-
    edge(Start, Next),
    \+ memberchk(Next, Visited),
    path(Next, End, [Next|Visited], Path).

测试：

?- path(x,z,P).
P = [x, y, t, z] ;
P = [x, y, z] ;
P = [x, z] ;
false.

Answer 2:

让你已经访问节点的列表。 在每一步中，检查如果边缘的端点存在于列表中或没有。

文章来源: how to visit each point in directed graph