如何检查在x86汇编按键的状态？(How to check keys status in x86 a

2019-06-24 07:34发布

站内文章 / 移动开发
50 0 0

我把x86汇编作为一种业余爱好今年一月，所以我可以做游戏会像在PCJ和坦迪1000，但我发现不完全教多少对特定主题的书旧8086供电的计算机上运行。 虽然一些DOS和BIOS中断那种做的工作，他们是远远不够完善。

我的主要问题是阅读按键键盘状态不停止该程序。 我发现了一些方法，但它们是非常有限的。 INT 21H，AH 0CH读取最后的按键，但在文本版时尚。 它不仅在读一次只有一个键，但记事本般的命中检测使得它无法知道过了多久密钥已经举行。 我也看到到端口60H引用在我的谷歌传播到64小时，但它只是，引用。 实际的解释和工作代码几乎是不存在的。 或者，也许我只是不善于使用搜索引擎。

我需要知道的是一键是否被按下与否。 最佳的解决方案将是使所有的键盘键的缓冲器/阵列和读其状态; 1意味着它的下跌，0意味着它不是。 或者只是有机会获得最后的密钥列表已被击中并释放将是很好（有办法明确，当然该缓冲区）。 任何人都可以点我在正确的方向？

编辑：首先，我应该提到，我使用Borland TASM。 现在我编译你的代码，它的伟大工程和所有，即使我几乎羞于承认，我不明白它的一半。 我试图使其与TASM兼容，但它是所有创造的屏幕和冻结垃圾。

以下是我想出了; 

.MODEL TINY
.STACK 256

.DATA
kbdbuf DB 128 DUP (0)

msg1 db "Press and hold ESC", 13, 10, "$"
msg2 db "ESC pressed, release ESC", 13, 10, "$"
msg3 db "ESC released", 13, 10, "$"

.CODE
main PROC
    org 0100h
    mov ax, @data
    mov ds, ax

    xor     ax, ax
    mov     es, ax

    cli                         ; update ISR address w/ ints disabled
    push    word [es:9*4+2]     ; preserve ISR address
    push    word [es:9*4]
    lea si, irq1isr
    mov     word [es:9*4], si   ; requires a register
    mov     [es:9*4+2],cs
    sti

        mov     ah, 9
        lea     dx, msg1
        int     021h                ; print "Press and hold ESC"

    test1:
        mov     al, [kbdbuf + 1]    ; check Escape key state (Esc scan code = 1)
        or      al, al
        jz      test1               ; wait until it's nonzero (pressed/held)

        lea     dx, msg2
        int     021h                ; print "ESC pressed, release ESC"

    test2:
        mov     al, [kbdbuf + 1]    ; check Escape key state (Esc scan code = 1)
        or      al, al
        jnz     test2               ; wait until it's zero (released/not pressed)

        lea     dx, msg3            ; print "ESC released"
        int     021h

    cli                         ; update ISR address w/ ints disabled
    pop     word [es:9*4]       ; restore ISR address
    pop     word [es:9*4+2]
    sti

    ret

    irq1isr:
    push    ax bx

    ; read keyboard scan code
    in      al, 060h

    ; update keyboard state
    xor     bh, bh
    mov     bl, al
    and     bl, 07Fh            ; bx = scan code
    shr     al, 7               ; al = 0 if pressed, 1 if released
    xor     al, 1               ; al = 1 if pressed, 0 if released
    mov     [cs:bx+kbdbuf], al

    ; send EOI to XT keyboard
    in      al, 061h
    mov     ah, al
    or      al, 080h
    out     061h, al
    mov     al, ah
    out     061h, al

    ; send EOI to master PIC
    mov     al, 020h
    out     020h, al

    pop     bx ax
    iret
main ENDP

END main

我不知道如果我连编码中断权利。 而赫克，如果我知道如何端口060h的单元 - 064h工作。

Answer 1:

这里是你如何能做到这一点： 

; compile with NASM: nasm.exe -f bin kbd.asm -o kbd.com

bits 16
org 0x100

    xor     ax, ax
    mov     es, ax

    cli                         ; update ISR address w/ ints disabled
    push    word [es:9*4+2]     ; preserve ISR address
    push    word [es:9*4]
    mov     word [es:9*4], irq1isr
    mov     [es:9*4+2],cs
    sti

    call    test

    cli                         ; update ISR address w/ ints disabled
    pop     word [es:9*4]       ; restore ISR address
    pop     word [es:9*4+2]
    sti

    ret

test:
    mov     ah, 9
    mov     dx, msg1
    int     0x21                ; print "Press and hold ESC"

test1:
    mov     al, [kbdbuf + 1]    ; check Escape key state (Esc scan code = 1)
    or      al, al
    jz      test1               ; wait until it's nonzero (pressed/held)

    mov     dx, msg2
    int     0x21                ; print "ESC pressed, release ESC"

test2:
    mov     al, [kbdbuf + 1]    ; check Escape key state (Esc scan code = 1)
    or      al, al
    jnz     test2               ; wait until it's zero (released/not pressed)

    mov     dx, msg3            ; print "ESC released"
    int     0x21

    ret

irq1isr:
    pusha

    ; read keyboard scan code
    in      al, 0x60

    ; update keyboard state
    xor     bh, bh
    mov     bl, al
    and     bl, 0x7F            ; bx = scan code
    shr     al, 7               ; al = 0 if pressed, 1 if released
    xor     al, 1               ; al = 1 if pressed, 0 if released
    mov     [cs:bx+kbdbuf], al

    ; send EOI to XT keyboard
    in      al, 0x61
    mov     ah, al
    or      al, 0x80
    out     0x61, al
    mov     al, ah
    out     0x61, al

    ; send EOI to master PIC
    mov     al, 0x20
    out     0x20, al

    popa
    iret

kbdbuf:
    times   128 db 0

msg1 db "Press and hold ESC", 13, 10, "$"
msg2 db "ESC pressed, release ESC", 13, 10, "$"
msg3 db "ESC released", 13, 10, "$"

在DOS / Win9x的/ NT / 2K / XP / 32位Vista / 7或DOSBox中运行它。

UPDATE：TASM版本： 

; file: kbdt.asm
; compile with TASM/TLINK:
;   tasm.exe kbdt.asm
;   tlink.exe /t kbdt.obj

.286

code segment use16
assume cs:code, ds:code, ss:code
org 100h

main:
    xor     ax, ax
    mov     es, ax

    cli                         ; update ISR address w/ ints disabled
    push    word ptr es:[9*4+2]     ; preserve ISR address
    push    word ptr es:[9*4]
    mov     word ptr es:[9*4], offset irq1isr
    mov     es:[9*4+2],cs
    sti

    call    test0

    cli                         ; update ISR address w/ ints disabled
    pop     word ptr es:[9*4]   ; restore ISR address
    pop     word ptr es:[9*4+2]
    sti

    ret

test0:
    mov     ah, 9
    mov     dx, offset msg1
    int     21h                 ; print "Press and hold ESC"

test1:
    mov     al, [kbdbuf + 1]    ; check Escape key state (Esc scan code = 1)
    or      al, al
    jz      test1               ; wait until it's nonzero (pressed/held)

    mov     dx, offset msg2
    int     21h                 ; print "ESC pressed, release ESC"

test2:
    mov     al, [kbdbuf + 1]    ; check Escape key state (Esc scan code = 1)
    or      al, al
    jnz     test2               ; wait until it's zero (released/not pressed)

    mov     dx, offset msg3     ; print "ESC released"
    int     21h

    ret

irq1isr:
    pusha

    ; read keyboard scan code
    in      al, 60h

    ; update keyboard state
    xor     bh, bh
    mov     bl, al
    and     bl, 7Fh             ; bx = scan code
    shr     al, 7               ; al = 0 if pressed, 1 if released
    xor     al, 1               ; al = 1 if pressed, 0 if released
    mov     cs:[bx+kbdbuf], al

    ; send EOI to XT keyboard
    in      al, 61h
    mov     ah, al
    or      al, 80h
    out     61h, al
    mov     al, ah
    out     61h, al

    ; send EOI to master PIC
    mov     al, 20h
    out     20h, al

    popa
    iret

kbdbuf      db 128 dup (0)

msg1 db "Press and hold ESC", 13, 10, "$"
msg2 db "ESC pressed, release ESC", 13, 10, "$"
msg3 db "ESC released", 13, 10, "$"

code ends

end main


Answer 2:

通常，对于旧系统这样的人所使用的BIOS有点像一个预先提供的一组库函数，那里的东西像键盘功能，如果他们已经方便只使用。 在你的情况下，BIOS键盘服务都不方便，所以你不使用它们。

相反，你想用自己的键盘中断处理程序来取代BIOS键盘中断处理程序和实现自己的键盘驱动程序。 键盘采用IRQ1，这是中断9.中断向量表开始是0x0000：0×0000，所以你会希望在0x0000处获得的4个字节：9 * 4 = 0×0000：0x0024和它们存储的地方（所以你可以把东西回来正常时你的软件出口），并把地址（offset，则自己的键盘IRQ处理程序的段）有来代替。

写自己的键盘驱动程序，你会希望通过了解有2个硬件的参与开始。 有键盘控制器芯片（或“PS / 2控制器”），其中谈到的计算机（通过。串行通信），以键盘本身内的芯片。

对于键盘控制器芯片上的信息，看到类似http://wiki.osdev.org/%228042%22_PS/2_Controller

对于键盘本身内部的芯片上的信息，看到类似http://wiki.osdev.org/PS/2_Keyboard



Answer 3:

使用端口60H和64H端口轮询键盘的实施例： 

       cli            ; stop software-Interrupts
       mov  al, 2     ; stop IRQ 1
       out  21h, al
       sti
P1:
       in   al, 64h     ; get Status
       test al, 1       ;  is there something in the outputbuffer?
       jz  P1
       test al, 20h     ;  it is a byte from the PS2-Mouse?
       jnz  P1
       in   al, 60h     ; get a key
       cmp  al, 1       ;  Escape-key?
       jz  XRAUS        ; then goto end
;───────────────────────────────────────────────────────────────
       mov  si, OFFSET SONTAB  ; get the offsetaddress of our special-key table
       mov  cl, Extablen       ; lenght
XSUCH: cmp  al, [si]
       jz  XFOUND
       lea  si, [si+1]         ; instead of "inc si"
       dec  cl
       jnz XSUCH
;───────────────────────────────────────────────────────────────
       mov  si, OFFSET TASTTAB  ; get the offsetaddress of our key table
       mov  cx, tablen
       mov  bx, OFFSET TEXTTAB  ; our corresponding ASCII table
SUCH:  cmp  al, [si]
       jz  short FOUND
       lea  si, [si+1]
       dec  cx
       jnz SUCH
       jmp  P1
;───────────────────────────────────────────────────────────────
XRAUS: in   al, 60h ; clear outputbuffer
       cli
       xor  al, al  ; enable IRQ 1
       out  21h, al
       sti
       mov  ah, 1  ; clear buffer in the ram
       int  16h
; ...some more instructions
;───────────────────────────────────────────────────────────────
FOUND:  mov  si, tablen   ; Length
        sub  si, cx
        xor  ecx, ecx
        mov  cl, [bx+si]  ; get the ASCII from our table
;  ...some more instructions
;───────────────────────────────────────────────────────────────
XFOUND:
;  Tab,shift li.,shift re.,HOME,UP,LEFT,RIGHT,END,DOWN
        cmp  cl, 1       ; DOWN-key
        jnz short  ...   ; jump to next
        ....
        ....
        cmp  cl, 9       ; Tab-key
        jnz  P1
;  ...some more instructions
:------------------------Data area----------------------
TASTTAB DB 02h,03h,04h,05h,06h,07h,08h,09h,0Ah,0Bh,0Ch,0Dh
        DB 10h,11h,12h,13h,14h,15h,16h,17h,18h,19h,1Ah,1Bh,1Eh,1Fh
        DB 20h,21h,22h,23h,24h,25h,26h,27h,28h,29h,2Bh,2Ch,2Dh,2Eh,2Fh
        DB 30h,31h,32h,33h,34h,35h,39h
        DB 56h
tablen =  ($-TASTTAB)
TEXTTAB DB "1234567890ß'"     ; with some german letters inside
        DB "qwertzuiopü+as"
        DB "dfghjklöä^#yxcv"
        DB "bnm,.- "
        DB "<"
Textablen  =  ($-TEXTTAB)
;---------------------------------------------------------------------------
;  Tab,shift left.,shift rigth.,HOME,UP,LEFT,RIGHT,END,DOWN
;----------
SONTAB  DB 0Fh,2Ah,36h,47h,48h,4Bh,4Dh,4Fh,50h
Extablen  =  ($-SONTAB)
        DB 0,0,0 ; for data_alignment of following entries


文章来源: How to check keys status in x86 assembly?
标签： assembly input keyboard x86 x86-16
举报

收藏的人(0)

Ta的文章 更多文章
登录 后发表评论
0条评论
还没有人评论过~